CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 cmake_minimum_required(VERSION 2.8.9)
  29 project(QuasselIRC)
  30
  31 # Versions
  32 set(QUASSEL_MAJOR  0)
  33 set(QUASSEL_MINOR 11)
  34 set(QUASSEL_PATCH  0)
  35 set(QUASSEL_VERSION_STRING "0.11-pre")
  36
  37 # Tell CMake about or own stuff
  38 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  39
  40 set(CMAKE_AUTOMOC ON)
  41
  42 include(CheckFunctionExists)
  43 include(CheckIncludeFile)
  44
  45 include(QuasselCompileSettings)
  46 include(QuasselMacros)
  47
  48 # Various options and variables that can be set on the command line
  49 option(WANT_CORE     "Build the core (server) binary"           ON)
  50 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  51 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  52
  53 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  54 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  55 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  56 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  57 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  58 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  59 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  60 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  61
  62 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  63 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  64 # run on a matching KDE version only.
  65 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  66
  67 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  68 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  69
  70 option(STATIC        "Enable static building (might not be portable)" OFF)
  71
  72 if(APPLE)
  73   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  74   # Notification Center is only available in > 10.8, which is Darwin v12
  75   if(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  76     option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  77   endif(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  78 endif(APPLE)
  79
  80 # Default to embedding data in the static case
  81 if(STATIC OR WIN32)
  82   set(EMBED_DEFAULT ON)
  83 else(STATIC OR WIN32)
  84   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  85 endif(STATIC OR WIN32)
  86
  87 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  88
  89 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  90
  91 # Some settings imply others
  92 if(STATIC)
  93   add_definitions(-DSTATIC)
  94   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  95 endif(STATIC)
  96
  97 if(WIN32)
  98   # We don't support separately installed resources yet on Win32
  99   set(EMBED_DATA ON)
 100 endif(WIN32)
 101
 102 # For static builds, arbitrary extra libs might need to be linked
 103 # Define a comma-separated list here
 104 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 105 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 106 if(LINK_EXTRA)
 107   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 108   link_libraries(${LINK_EXTRA})
 109 endif(LINK_EXTRA)
 110
 111 # Build Types
 112
 113
 114 # Simplify checks
 115 if(WANT_MONO OR WANT_QTCLIENT)
 116   set(BUILD_GUI true)
 117 endif(WANT_MONO OR WANT_QTCLIENT)
 118 if(WANT_MONO OR WANT_CORE)
 119   set(BUILD_CORE true)
 120 endif(WANT_MONO OR WANT_CORE)
 121
 122
 123 # Version checks
 124 ################
 125
 126 if(WITH_QT5)
 127   set(QT_MIN_VERSION "5.0.0")
 128   add_definitions(-DHAVE_QT5)
 129
 130   # Qt5 needs a new enough cmake...
 131   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 132
 133   # ... for automoc
 134   set(CMAKE_AUTOMOC ON)
 135 else(WITH_QT5)
 136
 137   # GUI stuff needs some new features
 138   if(BUILD_GUI)
 139     set(QT_MIN_VERSION "4.6.0")
 140   else(BUILD_GUI)
 141     set(QT_MIN_VERSION "4.4.0")
 142   endif(BUILD_GUI)
 143 endif(WITH_QT5)
 144
 145
 146 # Dependencies
 147 ##############
 148
 149 if(WITH_QT5)
 150   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 151   # We need QtWidgets
 152   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 153
 154   # Setup the i18n-related variables
 155   find_package(Qt5LinguistTools)
 156
 157 else(WITH_QT5)
 158   # Select a Qt installation here, if you don't want to use system Qt
 159   if(QT)
 160     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 161     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 162   endif(QT)
 163
 164   # Now that we have the correct $PATH, lets find Qt!
 165   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 166 endif(WITH_QT5)
 167
 168
 169 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 170 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 171 if(QT_LRELEASE_EXECUTABLE)
 172   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 173   if(WITH_QT5)
 174     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 175   else(WITH_QT5)
 176     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 177   endif(WITH_QT5)
 178 endif(QT_LRELEASE_EXECUTABLE)
 179
 180
 181 # zlib for compression, however we can always fall back to miniz
 182 find_package(ZLIB)
 183 if(ZLIB_FOUND)
 184   message(STATUS "Using system zlib for compression")
 185   add_definitions(-DHAVE_ZLIB)
 186   include_directories(${ZLIB_INCLUDE_DIRS})
 187   set(COMMON_LIBRARIES ${COMMON_LIBRARIES} ${ZLIB_LIBRARIES})
 188 else()
 189   message(STATUS "zlib NOT found, using bundled miniz for compression")
 190   if(${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 191     message(STATUS "WARNING: This may be slow on 32 bit systems!")
 192   endif()
 193 endif()
 194
 195
 196 # Execinfo is needed for generating backtraces
 197 find_package(ExecInfo)
 198 if(EXECINFO_FOUND)
 199   add_definitions(-DHAVE_EXECINFO)
 200   include_directories(${EXECINFO_INCLUDES})
 201   link_libraries(${EXECINFO_LIBRARIES})
 202 endif(EXECINFO_FOUND)
 203
 204
 205 # PkgConfig isn't strictly required.
 206 # However, some optional deps might not be found if it's not present, so warn!
 207 find_package(PkgConfig)
 208 if(NOT PKG_CONFIG_FOUND)
 209   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 210   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 211 endif(NOT PKG_CONFIG_FOUND)
 212
 213
 214 # Setup OpenSSL
 215 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 216 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 217 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 218 if(WITH_OPENSSL)
 219   if(QT_QCONFIG MATCHES "openssl")
 220     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 221     add_definitions(-DHAVE_SSL)
 222     set(HAVE_SSL true)
 223   else(QT_QCONFIG MATCHES "openssl")
 224     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 225     add_definitions(-DQT_NO_OPENSSL)
 226   endif(QT_QCONFIG MATCHES "openssl")
 227 else(WITH_OPENSSL)
 228   message(STATUS "Not enabling OpenSSL support")
 229 endif(WITH_OPENSSL)
 230
 231
 232 # Check for GUI specific stuff
 233 if(BUILD_GUI)
 234
 235   # Setup D-Bus support
 236   if(WITH_DBUS)
 237     if(WITH_QT5)
 238       find_package(Qt5DBus ${QT_MIN_VERSION})
 239       find_package(Qt5DBusTools)
 240     endif(WITH_QT5)
 241
 242     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 243       message(STATUS "Found QtDBus, enabling D-Bus support")
 244       add_definitions(-DHAVE_DBUS)
 245       set(HAVE_DBUS true)
 246       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 247
 248       # check if we have dbusmenu as well
 249       if(NOT WITH_QT5)
 250         find_package(DBusMenuQt)
 251         if(DBUSMENUQT_FOUND)
 252           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 253           add_definitions(-DHAVE_DBUSMENU)
 254           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 255           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 256           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 257         else(DBUSMENUQT_FOUND)
 258           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 259         endif(DBUSMENUQT_FOUND)
 260       endif(NOT WITH_QT5)
 261
 262     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 263       message(STATUS "QtDBus not found, disabling D-Bus support")
 264     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 265   else(WITH_DBUS)
 266     message(STATUS "Not enabling D-Bus support")
 267   endif(WITH_DBUS)
 268
 269   # Setup QtWebkit support
 270   if(WITH_WEBKIT)
 271     if(WITH_QT5)
 272       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 273     endif(WITH_QT5)
 274     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 275       message(STATUS "Found QtWebKit, enabling WebKit support")
 276       add_definitions(-DHAVE_WEBKIT)
 277       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 278       set(HAVE_WEBKIT true)
 279     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 280       message(STATUS "QtWebkit not found, disabling Webkit support")
 281     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 282   else(WITH_WEBKIT)
 283     message(STATUS "Not enabling Webkit support")
 284   endif(WITH_WEBKIT)
 285
 286   # Setup KDE4 support
 287   if(WITH_KDE AND NOT WITH_QT5)
 288     # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 289     set(_cflags ${CMAKE_C_FLAGS})
 290     find_package(KDE4)
 291     if(KDE4_FOUND)
 292       message(STATUS "Enabling KDE4 integration")
 293       include_directories(${KDE4_INCLUDES})
 294       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 295       set(HAVE_KDE 1)
 296       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
 297       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 298       set(EMBED_DATA OFF)
 299       # Restore our old CFLAGS
 300       set(CMAKE_C_FLAGS ${_cflags})
 301     else(KDE4_FOUND)
 302       message(STATUS "KDE4 not found, disabling KDE integration")
 303     endif(KDE4_FOUND)
 304   else(WITH_KDE AND NOT WITH_QT5)
 305     message(STATUS "Not enabling KDE4 integration")
 306   endif(WITH_KDE AND NOT WITH_QT5)
 307
 308   # Setup Phonon support - we only need this if we don't have or want KDE4
 309   if(NOT HAVE_KDE)
 310     if(WITH_PHONON)
 311       if(WITH_QT5)
 312         find_package(Qt5phonon)
 313         if(Qt5phonon_FOUND)
 314           message(STATUS "Enabling Phonon support")
 315           add_definitions(-DHAVE_PHONON)
 316           set(HAVE_PHONON true)
 317           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 318         else(Qt5phonon_FOUND)
 319           message(STATUS "Phonon not found, disabling audio notifications")
 320         endif(Qt5phonon_FOUND)
 321       else(WITH_QT5)
 322         find_package(Phonon)
 323         if(PHONON_FOUND)
 324           message(STATUS "Enabling Phonon support")
 325           add_definitions(-DHAVE_PHONON)
 326           include_directories(${PHONON_INCLUDES})
 327           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 328           set(HAVE_PHONON true)
 329         else(PHONON_FOUND)
 330           message(STATUS "Phonon not found, disabling audio notifications")
 331         endif(PHONON_FOUND)
 332       endif(WITH_QT5)
 333     else(WITH_PHONON)
 334       message(STATUS "Not enabling Phonon support")
 335     endif(WITH_PHONON)
 336
 337     find_package(Libsnore)
 338     if(LIBSNORE_FOUND)
 339         add_definitions(-DHAVE_LIBSNORE)
 340         set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
 341         set(HAVE_SNORENOTIFY true)
 342     endif(LIBSNORE_FOUND)
 343   endif(NOT HAVE_KDE)
 344
 345   # Setup libindicate-qt support
 346   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 347     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 348     if(INDICATEQT_FOUND)
 349       message(STATUS "Enabling Ayatana notification support")
 350       set(HAVE_INDICATEQT true)
 351       add_definitions(-DHAVE_INDICATEQT)
 352       link_directories(${INDICATEQT_LIBRARY_DIRS})
 353       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 354     else(INDICATEQT_FOUND)
 355       message(STATUS "Disabling Ayatana notification support")
 356     endif(INDICATEQT_FOUND)
 357   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 358     message(STATUS "Not enabling Ayatana notification support")
 359     # We don't want to link against it even if another package has found it
 360     set(INDICATEQT_LIBRARIES "")
 361   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 362
 363   # Setup OS X notification center support
 364   if(WITH_NOTIFICATION_CENTER AND APPLE)
 365     set(HAVE_NOTIFICATION_CENTER true)
 366     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 367     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 368       /System/Library/Frameworks/Foundation.framework
 369     )
 370   endif()
 371 endif(BUILD_GUI)
 372
 373 # Core-only deps
 374 if(BUILD_CORE)
 375
 376   # Setup encryption support
 377   if(WITH_CRYPT AND NOT WITH_QT5)
 378     find_package(QCA2)
 379     if(QCA2_FOUND)
 380       message(STATUS "Enabling encryption support")
 381       add_definitions(-DHAVE_QCA2)
 382       set(LINK_QCA2 QCA2)
 383       set(HAVE_QCA2 true)
 384       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 385     else(QCA2_FOUND)
 386       message(STATUS "Disabling encryption support")
 387     endif(QCA2_FOUND)
 388   else(WITH_CRYPT AND NOT WITH_QT5)
 389     message(STATUS "Not enabling encryption support")
 390   endif(WITH_CRYPT AND NOT WITH_QT5)
 391
 392   # Setup syslog support
 393   if(WITH_SYSLOG)
 394     check_include_file(syslog.h HAVE_SYSLOG_H)
 395     if(HAVE_SYSLOG_H)
 396       message(STATUS "Enabling syslog support")
 397       set(HAVE_SYSLOG true)
 398       add_definitions(-DHAVE_SYSLOG)
 399     else(HAVE_SYSLOG_H)
 400       message(STATUS "Disabling syslog support")
 401     endif(HAVE_SYSLOG_H)
 402   else(WITH_SYSLOG)
 403     message(STATUS "Not enabling syslog support")
 404   endif(WITH_SYSLOG)
 405
 406 endif(BUILD_CORE)
 407
 408
 409 # Various settings
 410 ##################
 411
 412 # needed to compile with mingw without kde
 413 if(MINGW AND NOT HAVE_KDE)
 414     add_definitions(-D_WIN32_WINNT=0x0500)
 415     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 416 # workaround for bug in mingw gcc 4.0
 417     add_definitions(-U__STRICT_ANSI__)
 418 endif(MINGW AND NOT HAVE_KDE)
 419
 420 # Now set up install locations; those are set by KDE if integration is enabled
 421 if(NOT HAVE_KDE)
 422   if(WIN32)
 423     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 424     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 425     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 426     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 427   else(WIN32)
 428     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 429     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 430     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 431     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 432   endif(WIN32)
 433 endif(NOT HAVE_KDE)
 434
 435 if(EMBED_DATA)
 436   message(STATUS "Embedding data files into the binary")
 437 else(EMBED_DATA)
 438   message(STATUS "Installing data files separately")
 439 endif(EMBED_DATA)
 440
 441 # RPATH needs to be set correctly
 442 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 443 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 444 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 445
 446 # Set global buildflags
 447 # This is very much non-portable, so don't use -DSTATIC until you know what
 448 # you do.
 449 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 450   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 451   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 452   if(HAVE_SSL)
 453     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 454   endif(HAVE_SSL)
 455 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 456
 457 if(WIN32)
 458   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 459   if(MSVC)
 460     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 461     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 462     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 463     link_libraries(Version dwmapi shlwapi)
 464   endif(MSVC)
 465   if(HAVE_SSL AND STATIC)
 466      find_package(OpenSSL REQUIRED)
 467      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 468   endif(HAVE_SSL AND STATIC)
 469 endif(WIN32)
 470
 471 if(HAVE_INDICATEQT)
 472   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 473 endif(HAVE_INDICATEQT)
 474
 475 if(NOT WIN32)
 476   check_function_exists(umask HAVE_UMASK)
 477   if(HAVE_UMASK)
 478     add_definitions(-DHAVE_UMASK)
 479   endif(HAVE_UMASK)
 480 endif(NOT WIN32)
 481
 482 # Generate version information from Git
 483 include(GetGitRevisionDescription)
 484 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 485 git_describe(GIT_DESCRIBE --long)
 486
 487 # Sanitize things if we're not in a Git repo
 488 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 489     set(GIT_HEAD "")
 490     set(GIT_DESCRIBE "")
 491 endif()
 492
 493 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 494
 495 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 496 set(COMMON_DEPS ${RC_WIN32})
 497 set(CORE_DEPS )
 498 set(CLIENT_DEPS )
 499
 500 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 501 add_subdirectory(data)
 502 add_subdirectory(icons)
 503 add_subdirectory(pics)
 504 add_subdirectory(po)
 505 add_subdirectory(src)