src/qtui/qtui.pri

   1 DEPMOD = uisupport common client
   2 QT_MOD = core gui network
   3
   4 SRCS += bufferwidget.cpp chatline-old.cpp chatwidget.cpp coreconnectdlg.cpp configwizard.cpp debugconsole.cpp inputwidget.cpp \
   5         mainwin.cpp nicklistwidget.cpp qtui.cpp qtuistyle.cpp settingsdlg.cpp settingspagedlg.cpp \
   6         topicwidget.cpp verticaldock.cpp
   7
   8 HDRS += bufferwidget.h chatline-old.h chatwidget.h configwizard.h debugconsole.h inputwidget.h \
   9         coreconnectdlg.h mainwin.h nicklistwidget.h qtui.h qtuistyle.h settingsdlg.h settingspagedlg.h \
  10         topicwidget.h verticaldock.h
  11
  12 FORMNAMES = mainwin.ui coreaccounteditdlg.ui coreconnectdlg.ui bufferviewwidget.ui bufferwidget.ui nicklistwidget.ui settingsdlg.ui \
  13             settingspagedlg.ui topicwidget.ui debugconsole.ui inputwidget.ui
  14
  15 for(ui, FORMNAMES) {
  16   FRMS += ui/$${ui}
  17 }
  18
  19 # Include settingspages
  20 include(settingspages/settingspages.pri)
  21 for(page, SETTINGSPAGES) {
  22   SRCS += settingspages/$${page}settingspage.cpp
  23   HDRS += settingspages/$${page}settingspage.h
  24   FRMS += settingspages/$${page}settingspage.ui
  25 }
  26
  27 # Include additional files
  28 for(src, SP_SRCS) {
  29   SRCS += settingspages/$${src}
  30 }
  31 for(hdr, SP_HDRS) {
  32   HDRS += settingspages/$${hdr}
  33 }
  34 for(frm, SP_FRMS) {
  35   FRMS += settingspages/$${frm}
  36 }