src/qtui/qtui.pri

   1 DEPMOD = uisupport common client
   2 QT_MOD = core gui network
   3
   4 SRCS += bufferwidget.cpp chatline-old.cpp \
   5         chatwidget.cpp coreconnectdlg.cpp configwizard.cpp \
   6         guisettings.cpp identities.cpp mainwin.cpp nicklistwidget.cpp qtui.cpp qtuistyle.cpp serverlist.cpp settingsdlg.cpp \
   7         topicwidget.cpp debugconsole.cpp inputwidget.cpp verticaldock.cpp
   8
   9 HDRS += bufferwidget.h chatline-old.h chatwidget.h configwizard.h \
  10         coreconnectdlg.h guisettings.h identities.h mainwin.h nicklistwidget.h qtui.h qtuistyle.h serverlist.h settingsdlg.h \
  11         topicwidget.h debugconsole.h inputwidget.h verticaldock.h
  12
  13 FORMNAMES = identitiesdlg.ui identitieseditdlg.ui networkeditdlg.ui mainwin.ui nickeditdlg.ui serverlistdlg.ui \
  14             servereditdlg.ui coreaccounteditdlg.ui coreconnectdlg.ui bufferviewwidget.ui bufferwidget.ui nicklistwidget.ui settingsdlg.ui \
  15             topicwidget.ui debugconsole.ui inputwidget.ui
  16
  17 for(ui, FORMNAMES) {
  18   FRMS += ui/$${ui}
  19 }
  20
  21 # Include settingspages
  22 include(settingspages/settingspages.pri)
  23 for(page, SETTINGSPAGES) {
  24   SRCS += settingspages/$${page}settingspage.cpp
  25   HDRS += settingspages/$${page}settingspage.h
  26   FRMS += settingspages/$${page}settingspage.ui
  27 }
  28
  29 # Include additional files
  30 for(src, SP_SRCS) {
  31   SRCS += settingspages/$${src}
  32 }
  33 for(hdr, SP_HDRS) {
  34   HDRS += settingspages/$${hdr}
  35 }
  36 for(frm, SP_FRMS) {
  37   FRMS += settingspages/$${frm}
  38 }