src/qtui/qtui.pri

   1 DEPMOD = uisupport common client
   2 QT_MOD = core gui network
   3
   4 SRCS += aboutdlg.cpp bufferwidget.cpp chatline-old.cpp chatwidget.cpp coreconfigwizard.cpp coreconnectdlg.cpp configwizard.cpp debugconsole.cpp inputwidget.cpp \
   5         mainwin.cpp nicklistwidget.cpp qtui.cpp qtuisettings.cpp qtuistyle.cpp settingsdlg.cpp settingspagedlg.cpp \
   6         topicwidget.cpp verticaldock.cpp jumpkeyhandler.cpp
   7
   8 HDRS += aboutdlg.h bufferwidget.h chatline-old.h chatwidget.h coreconfigwizard.h configwizard.h debugconsole.h inputwidget.h \
   9         coreconnectdlg.h mainwin.h nicklistwidget.h qtui.h qtuisettings.h qtuistyle.h settingsdlg.h settingspagedlg.h \
  10         topicwidget.h verticaldock.h jumpkeyhandler.h
  11
  12 FORMNAMES = aboutdlg.ui mainwin.ui coreaccounteditdlg.ui coreconnectdlg.ui bufferviewwidget.ui bufferwidget.ui nicklistwidget.ui settingsdlg.ui \
  13             settingspagedlg.ui topicwidget.ui debugconsole.ui inputwidget.ui \
  14             coreconfigwizardintropage.ui coreconfigwizardadminuserpage.ui coreconfigwizardstorageselectionpage.ui coreconfigwizardsyncpage.ui
  15
  16 for(ui, FORMNAMES) {
  17   FRMS += ui/$${ui}
  18 }
  19
  20 # Include settingspages
  21 include(settingspages/settingspages.pri)
  22 for(page, SETTINGSPAGES) {
  23   SRCS += settingspages/$${page}settingspage.cpp
  24   HDRS += settingspages/$${page}settingspage.h
  25   FRMS += settingspages/$${page}settingspage.ui
  26 }
  27
  28 # Include additional files
  29 for(src, SP_SRCS) {
  30   SRCS += settingspages/$${src}
  31 }
  32 for(hdr, SP_HDRS) {
  33   HDRS += settingspages/$${hdr}
  34 }
  35 for(frm, SP_FRMS) {
  36   FRMS += settingspages/$${frm}
  37 }