src/qtui/CMakeLists.txt

   1 # Builds the qtui module
   2
   3 set(QT_DONT_USE_QTGUI 0)
   4 set(QT_USE_QTNETWORK 1)
   5 include(${QT_USE_FILE})
   6
   7 set(SOURCES
   8     aboutdlg.cpp
   9     bufferwidget.cpp
  10     channellistdlg.cpp
  11     coreconfigwizard.cpp
  12     coreconnectdlg.cpp
  13     debugconsole.cpp
  14     inputwidget.cpp
  15     jumpkeyhandler.cpp
  16     mainwin.cpp
  17     nicklistwidget.cpp
  18     qtui.cpp
  19     qtuisettings.cpp
  20     qtuistyle.cpp
  21     settingsdlg.cpp
  22     settingspagedlg.cpp
  23     titlesetter.cpp
  24     topicbutton.cpp
  25     topicwidget.cpp
  26     verticaldock.cpp)
  27
  28 set(MOC_HDRS
  29     aboutdlg.h
  30     bufferwidget.h
  31     channellistdlg.h
  32     coreconfigwizard.h
  33     coreconnectdlg.h
  34     debugconsole.h
  35     inputwidget.h
  36     jumpkeyhandler.h
  37     mainwin.h
  38     nicklistwidget.h
  39     qtui.h
  40     settingsdlg.h
  41     settingspagedlg.h
  42     titlesetter.h
  43     topicbutton.h
  44     topicwidget.h
  45     verticaldock.h)
  46
  47 set(HEADERS
  48     qtuisettings.h
  49     qtuistyle.h)
  50
  51 if(SPUTDEV)
  52   set(SOURCES ${SOURCES} chatitem.cpp chatline.cpp chatlinemodelitem.cpp
  53                          chatlinemodel.cpp chatscene.cpp chatview.cpp)
  54   set(MOC_HDRS ${MOC_HDRS} chatlinemodel.h chatscene.h chatview.h)
  55   set(HEADERS ${HEADERS} chatitem.h chatline.h chatlinemodelitem.h)
  56 else(SPUTDEV)
  57   set(SOURCES ${SOURCES} chatline-old.cpp chatwidget.cpp)
  58   set(MOC_HDRS ${MOC_HDRS} chatline-old.h chatwidget.h)
  59 endif(SPUTDEV)
  60
  61 set(FORMS
  62     aboutdlg.ui
  63     bufferviewwidget.ui
  64     bufferwidget.ui
  65     channellistdlg.ui
  66     coreaccounteditdlg.ui
  67     coreconfigwizardintropage.ui
  68     coreconfigwizardadminuserpage.ui
  69     coreconfigwizardstorageselectionpage.ui
  70     coreconfigwizardsyncpage.ui
  71     coreconnectdlg.ui
  72     debugconsole.ui
  73     inputwidget.ui
  74     mainwin.ui
  75     nicklistwidget.ui
  76     settingsdlg.ui
  77     settingspagedlg.ui
  78     topicwidget.ui)
  79
  80 foreach(FORM ${FORMS})
  81   set(FORMPATH ${FORMPATH} ui/${FORM})
  82 endforeach(FORM ${FORMS})
  83
  84 # handle settingspages
  85 include(settingspages/settingspages.inc)
  86 foreach(SP ${SETTINGSPAGES})
  87   set(SPSRC ${SPSRC} settingspages/${SP}settingspage.cpp)
  88   set(SPHDR ${SPHDR} settingspages/${SP}settingspage.h)
  89   set(SPFRM ${SPFRM} settingspages/${SP}settingspage.ui)
  90 endforeach(SP ${SETTINGSPAGES})
  91 foreach(SRC ${SP_SOURCES})
  92   set(SPSRC ${SPSRC} settingspages/${SRC})
  93 endforeach(SRC ${SP_SOURCES})
  94 foreach(HDR ${SP_HEADERS})
  95   set(SPHDR ${SPHDR} settingspages/${HDR})
  96 endforeach(HDR ${SP_HEADERS})
  97 foreach(FRM ${SP_FORMS})
  98   set(SPFRM ${SPFRM} settingspages/${FRM})
  99 endforeach(FRM ${SP_FORMS})
 100
 101
 102 qt4_wrap_cpp(MOC ${MOC_HDRS} ${SPHDR})
 103 qt4_wrap_ui(UI ${FORMPATH} ${SPFRM})
 104
 105 include_directories(${CMAKE_SOURCE_DIR}/src/common
 106                     ${CMAKE_SOURCE_DIR}/src/client
 107                     ${CMAKE_SOURCE_DIR}/src/qtui
 108                     ${CMAKE_SOURCE_DIR}/src/uisupport
 109                     ${CMAKE_CURRENT_BINARY_DIR})
 110
 111 add_library(mod_qtui STATIC ${SOURCES} ${SPSRC} ${MOC} ${UI} ${HEADERS})
 112 add_dependencies(mod_qtui mod_common mod_client mod_uisupport)