src/qtui/CMakeLists.txt

   1 quassel_add_module(QtUi EXPORT)
   2
   3 target_sources(${TARGET} PRIVATE
   4     aboutdlg.cpp
   5     awaylogfilter.cpp
   6     awaylogview.cpp
   7     bufferwidget.cpp
   8     channellistdlg.cpp
   9     chatitem.cpp
  10     chatline.cpp
  11     chatlinemodel.cpp
  12     chatlinemodelitem.cpp
  13     chatmonitorfilter.cpp
  14     chatmonitorview.cpp
  15     chatscene.cpp
  16     chatview.cpp
  17     chatviewsearchbar.cpp
  18     chatviewsearchcontroller.cpp
  19     chatviewsettings.cpp
  20     columnhandleitem.cpp
  21     coreconfigwizard.cpp
  22     coreconnectdlg.cpp
  23     coreconnectionstatuswidget.cpp
  24     coreinfodlg.cpp
  25     coresessionwidget.cpp
  26     debugbufferviewoverlay.cpp
  27     debuglogdlg.cpp
  28     debugmessagemodelfilter.cpp
  29     inputwidget.cpp
  30     ircconnectionwizard.cpp
  31     legacysystemtray.cpp
  32     mainpage.cpp
  33     mainwin.cpp
  34     markerlineitem.cpp
  35     msgprocessorstatuswidget.cpp
  36     nicklistwidget.cpp
  37     passwordchangedlg.cpp
  38     qtui.cpp
  39     qtuiapplication.cpp
  40     qtuimessageprocessor.cpp
  41     qtuisettings.cpp
  42     qtuistyle.cpp
  43     receivefiledlg.cpp
  44     resourcetreedlg.cpp
  45     settingsdlg.cpp
  46     settingspagedlg.cpp
  47     simplenetworkeditor.cpp
  48     systemtray.cpp
  49     systrayanimationnotificationbackend.cpp
  50     systraynotificationbackend.cpp
  51     taskbarnotificationbackend.cpp
  52     titlesetter.cpp
  53     topicwidget.cpp
  54     verticaldock.cpp
  55     webpreviewitem.cpp
  56
  57     # UI files
  58     aboutdlg.ui
  59     bufferviewwidget.ui
  60     bufferwidget.ui
  61     channellistdlg.ui
  62     chatviewsearchbar.ui
  63     coreconfigwizardintropage.ui
  64     coreconfigwizardauthenticationselectionpage.ui
  65     coreconfigwizardadminuserpage.ui
  66     coreconfigwizardstorageselectionpage.ui
  67     coreconfigwizardsyncpage.ui
  68     coreconnectauthdlg.ui
  69     coreconnectionstatuswidget.ui
  70     coreinfodlg.ui
  71     coresessionwidget.ui
  72     debugbufferviewoverlay.ui
  73     debuglogdlg.ui
  74     inputwidget.ui
  75     msgprocessorstatuswidget.ui
  76     nicklistwidget.ui
  77     passwordchangedlg.ui
  78     receivefiledlg.ui
  79     resourcetreedlg.ui
  80     settingsdlg.ui
  81     settingspagedlg.ui
  82     simplenetworkeditor.ui
  83     systrayanimationconfigwidget.ui
  84     topicwidget.ui
  85 )
  86
  87 # Handle settingspages
  88 target_include_directories(${TARGET} PRIVATE settingspages)
  89 include(settingspages/settingspages.cmake)
  90 foreach(page ${SETTINGSPAGES})
  91     target_sources(${TARGET} PRIVATE
  92         settingspages/${page}settingspage.cpp
  93         settingspages/${page}settingspage.ui
  94     )
  95 endforeach()
  96 foreach(src ${SP_SOURCES})
  97     target_sources(${TARGET} PRIVATE settingspages/${src})
  98 endforeach()
  99 foreach(form ${SP_FORMS})
 100     target_sources(${TARGET} PRIVATE settingspages/${form})
 101 endforeach()
 102
 103 target_link_libraries(${TARGET}
 104     PUBLIC
 105         Qt5::Core
 106         Qt5::Gui
 107         Qt5::Network
 108         Qt5::Widgets
 109         Quassel::UiSupport
 110         Quassel::Client
 111         Quassel::Common
 112 )
 113
 114 if (WITH_KDE)
 115     target_sources(${TARGET} PRIVATE knotificationbackend.cpp)
 116     target_link_libraries(${TARGET} PUBLIC
 117         KF5::ConfigWidgets
 118         KF5::Notifications
 119         KF5::NotifyConfig
 120         KF5::WidgetsAddons
 121         KF5::XmlGui
 122     )
 123 endif()
 124
 125 if (KF5Sonnet_FOUND)
 126     target_compile_definitions(${TARGET} PRIVATE -DHAVE_SONNET)
 127     target_sources(${TARGET} PRIVATE settingspages/sonnetsettingspage.cpp)
 128     target_link_libraries(${TARGET} PRIVATE KF5::SonnetUi)
 129 endif()
 130
 131 if (Qt5Multimedia_FOUND)
 132     target_compile_definitions(${TARGET} PRIVATE -DHAVE_QTMULTIMEDIA)
 133     target_sources(${TARGET} PRIVATE
 134         qtmultimedianotificationbackend.cpp
 135         qtmultimedianotificationconfigwidget.ui
 136     )
 137     target_link_libraries(${TARGET} PRIVATE Qt5::Multimedia)
 138 endif()
 139
 140 if (Qt5DBus_FOUND)
 141     target_compile_definitions(${TARGET} PRIVATE -DHAVE_DBUS)
 142     target_link_libraries(${TARGET} PRIVATE Qt5::DBus)
 143     if (dbusmenu-qt5_FOUND)
 144         target_compile_definitions(${TARGET} PRIVATE -DHAVE_DBUSMENU)
 145         target_link_libraries(${TARGET} PRIVATE dbusmenu-qt5)
 146     endif()
 147
 148     qt5_add_dbus_interface(DBUS_SOURCES ../../interfaces/org.kde.StatusNotifierWatcher.xml statusnotifierwatcher)
 149     qt5_add_dbus_interface(DBUS_SOURCES ../../interfaces/org.freedesktop.Notifications.xml notificationsclient)
 150     qt5_add_dbus_adaptor  (DBUS_SOURCES ../../interfaces/org.kde.StatusNotifierItem.xml statusnotifieritemdbus.h StatusNotifierItemDBus)
 151
 152     target_sources(${TARGET} PRIVATE
 153         dockmanagernotificationbackend.cpp
 154         statusnotifieritem.cpp
 155         statusnotifieritemdbus.cpp
 156         ${DBUS_SOURCES}
 157     )
 158 endif()
 159
 160 if (HAVE_WEBKIT)
 161     target_compile_definitions(${TARGET} PRIVATE -DHAVE_WEBKIT)
 162     target_link_libraries(${TARGET} PRIVATE
 163         Qt5::WebKit
 164         Qt5::WebKitWidgets
 165     )
 166 endif()
 167
 168 if (HAVE_WEBENGINE)
 169     target_compile_definitions(${TARGET} PRIVATE -DHAVE_WEBENGINE)
 170     target_link_libraries(${TARGET} PRIVATE
 171         Qt5::WebEngine
 172         Qt5::WebEngineWidgets)
 173 endif()
 174
 175 if (HAVE_SSL)
 176     target_sources(${TARGET} PRIVATE
 177         sslinfodlg.cpp
 178         sslinfodlg.ui
 179     )
 180 endif()
 181
 182 if (LibsnoreQt5_FOUND)
 183     target_compile_definitions(${TARGET} PRIVATE -DHAVE_LIBSNORE)
 184     target_sources(${TARGET} PRIVATE
 185         snorenotificationbackend.cpp
 186         snorentificationconfigwidget.ui
 187     )
 188     target_link_libraries(${TARGET} PRIVATE Snore::Libsnore Snore::LibsnoreSettings)
 189 endif()
 190
 191 if (WITH_NOTIFICATION_CENTER)
 192     target_compile_definitions(${TARGET} PRIVATE -DHAVE_NOTIFICATION_CENTER)
 193     target_sources(${TARGET} PRIVATE osxnotificationbackend.mm)
 194     target_link_libraries(${TARGET} PRIVATE "/System/Library/Frameworks/Foundation.framework")
 195 endif()
 196
 197 if (WITH_OXYGEN_ICONS)
 198     set_property(SOURCE qtui.cpp APPEND PROPERTY COMPILE_DEFINITIONS WITH_OXYGEN_ICONS)
 199 endif()