src/CMakeLists.txt

   1 # Builds the three main targets
   2
   3 add_subdirectory(common)
   4 include_directories(BEFORE common)
   5 if(BUILD_CORE)
   6   add_subdirectory(core)
   7   include_directories(BEFORE core)
   8 endif(BUILD_CORE)
   9 if(BUILD_GUI)
  10   add_subdirectory(client)
  11   add_subdirectory(uisupport)
  12   add_subdirectory(qtui)
  13   include_directories(BEFORE client)
  14   include_directories(BEFORE uisupport)
  15   include_directories(BEFORE qtui)
  16
  17   if(STATIC)
  18     link_directories(${QT_PLUGINS_DIR}/imageformats)
  19     set(CLIENT_LIBS ${CLIENT_LIBS} qjpeg qgif)
  20   endif(STATIC)
  21 endif(BUILD_GUI)
  22
  23 include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}) # for version.gen
  24
  25 # Add resources. Can't be done in other subdirs apparently.
  26 # Note that these variables need to contain paths relative to src/ (this dir)
  27 qt4_add_resources(CLIENT_DEPS ${CLIENT_RCS})
  28 qt4_add_resources(CORE_DEPS ${CORE_RCS})
  29 qt4_add_resources(COMMON_DEPS ${COMMON_RCS})
  30
  31 if(HAVE_INDICATEQT)
  32   link_directories(${INDICATEQT_LIBRARY_DIRS})
  33 endif(HAVE_INDICATEQT)
  34
  35 if(WANT_CORE)
  36   setup_qt4_variables(NETWORK SCRIPT SQL)
  37   add_executable(quasselcore common/main.cpp ${COMMON_DEPS} ${CORE_DEPS})
  38   add_dependencies(quasselcore po genversion_run)
  39   set_target_properties(quasselcore PROPERTIES
  40                                     COMPILE_FLAGS "-DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_CORE"
  41                                     OUTPUT_NAME ../quasselcore)
  42   target_link_libraries(quasselcore mod_core mod_common
  43                                     ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
  44   install(TARGETS quasselcore RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  45 endif(WANT_CORE)
  46
  47 if(WANT_QTCLIENT)
  48   setup_qt4_variables(GUI NETWORK ${CLIENT_QT4_VARS})
  49   add_executable(quasselclient WIN32 common/main.cpp ${COMMON_DEPS} ${CLIENT_DEPS})
  50   add_dependencies(quasselclient po genversion_run)
  51   set_target_properties(quasselclient PROPERTIES
  52                                       COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB ${CLIENT_COMPILE_FLAGS} -DBUILD_QTUI"
  53                                       OUTPUT_NAME ../quasselclient)
  54   target_link_libraries(quasselclient ${LINK_KDE} mod_qtui mod_uisupport mod_client mod_common ${CLIENT_LIBS}
  55                                       ${QUASSEL_QT_LIBRARIES} ${QUASSEL_KDE_LIBRARIES} ${QUASSEL_SSL_LIBRARIES} ${PHONON_LIBS} ${INDICATEQT_LIBRARIES})
  56   install(TARGETS quasselclient RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  57 endif(WANT_QTCLIENT)
  58
  59 if(WANT_MONO)
  60   setup_qt4_variables(GUI NETWORK SCRIPT SQL ${CLIENT_QT4_VARS})
  61   qt4_wrap_cpp(MOC qtui/monoapplication.h)
  62   add_executable(quassel WIN32 common/main.cpp qtui/monoapplication.cpp ${MOC} ${COMMON_DEPS} ${CLIENT_DEPS} ${CORE_DEPS})
  63   add_dependencies(quassel po genversion_run)
  64   set_target_properties(quassel PROPERTIES
  65                                 COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB ${CLIENT_COMPILE_FLAGS} -DBUILD_MONO"
  66                                 OUTPUT_NAME ../quassel)
  67   target_link_libraries(quassel mod_qtui mod_uisupport mod_client mod_core mod_common ${CLIENT_LIBS}
  68                                 ${QUASSEL_QT_LIBRARIES} ${QUASSEL_KDE_LIBRARIES} ${QUASSEL_SSL_LIBRARIES} ${PHONON_LIBS} ${INDICATEQT_LIBRARIES})
  69   install(TARGETS quassel RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  70 endif(WANT_MONO)
  71
  72 # Build bundles for MacOSX
  73 if(APPLE)
  74   add_custom_command(TARGET quasselclient POST_BUILD
  75                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
  76                              ${CMAKE_SOURCE_DIR} "Quassel Client" ../quasselclient)
  77   add_custom_command(TARGET quassel POST_BUILD
  78                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
  79                              ${CMAKE_SOURCE_DIR} "Quassel" ../quassel)
  80   if(DEPLOY)
  81     add_custom_command(TARGET quasselclient POST_BUILD
  82                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Client ..)
  83     add_custom_command(TARGET quasselcore POST_BUILD
  84                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Core ..)
  85   endif(DEPLOY)
  86 endif(APPLE)