src/CMakeLists.txt

   1 PROJECT(Quassel)
   2
   3 # 2.4.2 had a bug with out-of-source builds and UIC dependencies.
   4 CMAKE_MINIMUM_REQUIRED(VERSION 2.4.3 FATAL_ERROR)
   5
   6 # Select if Quassel should be built in client, server or monolithic mode
   7 SET(BUILD "mono" CACHE STRING "Defines which Quassel parts are to be built. Can contain 'core', 'gui' and/or 'monolithic' (which is the default), or 'all' to build everything.")
   8 SET(BUILD_CORE )
   9 SET(BUILD_QTGUI )
  10 SET(BUILD_MONO )
  11 IF(BUILD MATCHES "core" OR BUILD MATCHES "all")
  12   SET(BUILD_CORE true)
  13   MESSAGE("Building Quassel core.")
  14 ENDIF(BUILD MATCHES "core" OR BUILD MATCHES "all")
  15 IF(BUILD MATCHES "gui" OR BUILD MATCHES "all")
  16   SET(BUILD_QTGUI true)
  17   MESSAGE("Building Quassel GUI for Qt.")
  18 ENDIF(BUILD MATCHES "gui" OR BUILD MATCHES "all")
  19 IF(BUILD MATCHES "mono" OR BUILD MATCHES "all")
  20   SET(BUILD_MONO true)
  21   MESSAGE("Building monolithic Quassel.")
  22 ENDIF(BUILD MATCHES "mono" OR BUILD MATCHES "all")
  23 IF(NOT BUILD_MONO AND NOT BUILD_CORE AND NOT BUILD_QTGUI)
  24   MESSAGE(FATAL_ERROR "\nYou have not selected which parts of Quassel I should build. Aborting.\nRun 'cmake <path> -DBUILD=<part>', where <part> contains one or more of 'core', 'gui' or 'monolithic', or 'all' to build everything.\n")
  25 ENDIF(NOT BUILD_MONO AND NOT BUILD_CORE AND NOT BUILD_QTGUI)
  26
  27 #IF(BUILD_CORE OR BUILD_QTGUI)
  28 #  MESSAGE(FATAL_ERROR "\nBuilding of standalone core or GUI not supported at this time. Please check back later.\n")
  29 #ENDIF(BUILD_CORE OR BUILD_QTGUI)
  30
  31 SET(CMAKE_BUILD_TYPE Debug)
  32
  33 # Define files
  34 SET(quassel_mono_SRCS common/build_mono.cpp)
  35 SET(quassel_core_SRCS common/build_core.cpp)
  36 SET(quassel_qtgui_SRCS common/build_qtgui.cpp)
  37 SET(quassel_RCCS images/icons.qrc)
  38 SET(quassel_DIRS common client core qtgui)
  39
  40 # Build correct absolute paths for subdirs to include
  41 SET(SDIRS "")
  42 FOREACH(dir ${quassel_DIRS})
  43   SET(SDIRS ${SDIRS} "${CMAKE_CURRENT_SOURCE_DIR}/${dir}")
  44 ENDFOREACH(dir)
  45 INCLUDE_DIRECTORIES(${SDIRS} plugins)
  46 INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR}/qtgui) # so that ui files are found
  47
  48 # We need Qt4 support.
  49 SET(QT_MIN_VERSION "4.3.0")  # 4.3 is required for SSL, crypto and some other stuff
  50 FIND_PACKAGE(Qt4 REQUIRED)
  51
  52 # Set needed libraries
  53 SET(QT_USE_QTXML true)
  54 SET(QT_USE_QTSQL true)
  55 SET(QT_USE_QTNETWORK true)
  56 SET(QT_USE_QTUITOOLS true)
  57 SET(QT_DONT_USE_QTGUI true)   # This is added later if GUI is requested
  58 INCLUDE(${QT_USE_FILE})
  59
  60 # Define subdirs. CMake complains if a directory is added twice, so make sure this
  61 # does not happen in any combination of the requested targets.
  62
  63 ADD_SUBDIRECTORY(common)
  64 IF(BUILD_CORE)
  65   ADD_SUBDIRECTORY(core)
  66 ENDIF(BUILD_CORE)
  67 IF(BUILD_MONO AND NOT BUILD_CORE)
  68   ADD_SUBDIRECTORY(core)
  69 ENDIF(BUILD_MONO AND NOT BUILD_CORE)
  70
  71 QT4_ADD_RESOURCES(_RCCS ${quassel_RCCS})
  72
  73 ADD_DEFINITIONS(-Wall -Wextra -ansi)  # may not be portable!
  74
  75 SET(TARGET_LIST )
  76
  77 IF(BUILD_CORE)
  78   ADD_EXECUTABLE(quasselcore ${quassel_core_SRCS} ${_RCCS})
  79   TARGET_LINK_LIBRARIES(quasselcore common core ${QT_LIBRARIES})
  80   SET(TARGET_LIST ${TARGET_LIST} quasselcore)
  81 ENDIF(BUILD_CORE)
  82
  83 IF(BUILD_QTGUI OR BUILD_MONO)  # OK, now we need QtGui!
  84   REMOVE_DEFINITIONS(-DQT_CORE_LIB -DQT_GUI_LIB ${QT_DEFINITIONS})
  85   SET(QT_DONT_USE_QTGUI "")
  86   SET(QT_INCLUDE_DIR "")
  87   SET(QT_LIBRARIES "")
  88   INCLUDE(${QT_USE_FILE})
  89   ADD_SUBDIRECTORY(client)
  90   ADD_SUBDIRECTORY(qtgui)
  91
  92   IF(BUILD_MONO)
  93     ADD_EXECUTABLE(quassel ${quassel_mono_SRCS} ${_RCCS})
  94     TARGET_LINK_LIBRARIES(quassel common client core qtgui ${QT_LIBRARIES})
  95     SET(TARGET_LIST ${TARGET_LIST} quassel)
  96   ENDIF(BUILD_MONO)
  97
  98   IF(BUILD_QTGUI)
  99     ADD_EXECUTABLE(quasselclient ${quassel_qtgui_SRCS} ${_RCCS})
 100     TARGET_LINK_LIBRARIES(quasselclient common client qtgui ${QT_LIBRARIES})
 101     SET(TARGET_LIST ${TARGET_LIST} quasselclient)
 102   ENDIF(BUILD_QTGUI)
 103
 104 ENDIF(BUILD_QTGUI OR BUILD_MONO)
 105
 106 INSTALL(TARGETS ${TARGET_LIST}
 107         RUNTIME DESTINATION bin
 108         LIBRARY DESTINATION lib
 109         ARCHIVE DESTINATION lib/static)