src/CMakeLists.txt

   1 # Builds the three main targets
   2
   3 add_subdirectory(common)
   4 include_directories(BEFORE common)
   5 if(BUILD_CORE)
   6   add_subdirectory(core)
   7   include_directories(BEFORE core)
   8 endif(BUILD_CORE)
   9 if(BUILD_GUI)
  10   add_subdirectory(client)
  11   add_subdirectory(uisupport)
  12   add_subdirectory(qtui)
  13   include_directories(BEFORE client)
  14   include_directories(BEFORE uisupport)
  15   include_directories(BEFORE qtui)
  16
  17   if(STATIC)
  18     link_directories(${QT_PLUGINS_DIR}/imageformats)
  19     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} qjpeg qgif)
  20   endif(STATIC)
  21 endif(BUILD_GUI)
  22
  23 include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}) # for version.gen
  24
  25 # Add resources. Can't be done in other subdirs apparently.
  26 # Note that these variables need to contain paths relative to src/ (this dir)
  27 qt_add_resources(CLIENT_DEPS ${CLIENT_RCS})
  28 qt_add_resources(CORE_DEPS ${CORE_RCS})
  29 qt_add_resources(COMMON_DEPS ${COMMON_RCS})
  30
  31 if(WANT_CORE)
  32   add_executable(quasselcore common/main.cpp ${COMMON_DEPS} ${CORE_DEPS})
  33   qt_use_modules(quasselcore Core Network ${CORE_QT_MODULES})
  34   add_dependencies(quasselcore po)
  35   set_target_properties(quasselcore PROPERTIES
  36                                     COMPILE_FLAGS "-DBUILD_CORE"
  37                                     OUTPUT_NAME ../quasselcore)
  38   target_link_libraries(quasselcore mod_core mod_common ${COMMON_LIBRARIES} ${QUASSEL_SSL_LIBRARIES} ${QT_QTMAIN_LIBRARY})
  39   install(TARGETS quasselcore RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  40 endif(WANT_CORE)
  41
  42 if (KDE4_FOUND)
  43     include_directories(${KDE4_INCLUDES})
  44 endif()
  45
  46 if(WANT_QTCLIENT)
  47   add_executable(quasselclient WIN32 common/main.cpp ${COMMON_DEPS} ${CLIENT_DEPS})
  48   qt_use_modules(quasselclient Core Gui Network ${CLIENT_QT_MODULES})
  49   add_dependencies(quasselclient po)
  50   set_target_properties(quasselclient PROPERTIES
  51                                       COMPILE_FLAGS "-DBUILD_QTUI"
  52                                       OUTPUT_NAME ../quasselclient)
  53   target_link_libraries(quasselclient mod_qtui mod_uisupport mod_client mod_common ${COMMON_LIBRARIES} ${CLIENT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES} ${QT_QTMAIN_LIBRARY})
  54   install(TARGETS quasselclient RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  55 endif(WANT_QTCLIENT)
  56
  57 if(WANT_MONO)
  58   add_executable(quassel WIN32 common/main.cpp qtui/monoapplication.cpp ${COMMON_DEPS} ${CLIENT_DEPS} ${CORE_DEPS})
  59   qt_use_modules(quassel Core Gui Network ${CLIENT_QT_MODULES} ${CORE_QT_MODULES})
  60   add_dependencies(quassel po)
  61   set_target_properties(quassel PROPERTIES
  62                                 COMPILE_FLAGS "-DBUILD_MONO"
  63                                 OUTPUT_NAME ../quassel)
  64   target_link_libraries(quassel mod_qtui mod_uisupport mod_client mod_core mod_common ${COMMON_LIBRARIES} ${CLIENT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES} ${QT_QTMAIN_LIBRARY})
  65   install(TARGETS quassel RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  66 endif(WANT_MONO)
  67
  68 # Build bundles for MacOSX
  69 if(APPLE)
  70   add_custom_command(TARGET quasselclient POST_BUILD
  71                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
  72                              ${CMAKE_SOURCE_DIR} "Quassel Client" ../quasselclient)
  73   add_custom_command(TARGET quassel POST_BUILD
  74                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
  75                              ${CMAKE_SOURCE_DIR} "Quassel" ../quassel)
  76   if(DEPLOY)
  77     add_custom_command(TARGET quasselclient POST_BUILD
  78                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Client ..)
  79     add_custom_command(TARGET quasselcore POST_BUILD
  80                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Core ..)
  81   endif(DEPLOY)
  82 endif(APPLE)