cmake/modules/FindPkgConfig.cmake

   1 # - a pkg-config module for CMake
   2 #
   3 # Usage:
   4 #   pkg_check_modules(<PREFIX> [REQUIRED] [QUIET] <MODULE> [<MODULE>]*)
   5 #     checks for all the given modules
   6 #
   7 #   pkg_search_module(<PREFIX> [REQUIRED] [QUIET] <MODULE> [<MODULE>]*)
   8 #     checks for given modules and uses the first working one
   9 #
  10 # When the 'REQUIRED' argument was set, macros will fail with an error
  11 # when module(s) could not be found
  12 #
  13 # When the 'QUIET' argument is set, no status messages will be printed.
  14 #
  15 # It sets the following variables:
  16 #   PKG_CONFIG_FOUND         ... true if pkg-config works on the system
  17 #   PKG_CONFIG_EXECUTABLE    ... pathname of the pkg-config program
  18 #   <PREFIX>_FOUND           ... set to 1 if module(s) exist
  19 #
  20 # For the following variables two sets of values exist; first one is the
  21 # common one and has the given PREFIX. The second set contains flags
  22 # which are given out when pkgconfig was called with the '--static'
  23 # option.
  24 #   <XPREFIX>_LIBRARIES      ... only the libraries (w/o the '-l')
  25 #   <XPREFIX>_LIBRARY_DIRS   ... the paths of the libraries (w/o the '-L')
  26 #   <XPREFIX>_LDFLAGS        ... all required linker flags
  27 #   <XPREFIX>_LDFLAGS_OTHER  ... all other linker flags
  28 #   <XPREFIX>_INCLUDE_DIRS   ... the '-I' preprocessor flags (w/o the '-I')
  29 #   <XPREFIX>_CFLAGS         ... all required cflags
  30 #   <XPREFIX>_CFLAGS_OTHER   ... the other compiler flags
  31 #
  32 #   <XPREFIX> = <PREFIX>        for common case
  33 #   <XPREFIX> = <PREFIX>_STATIC for static linking
  34 #
  35 # There are some special variables whose prefix depends on the count
  36 # of given modules. When there is only one module, <PREFIX> stays
  37 # unchanged. When there are multiple modules, the prefix will be
  38 # changed to <PREFIX>_<MODNAME>:
  39 #   <XPREFIX>_VERSION    ... version of the module
  40 #   <XPREFIX>_PREFIX     ... prefix-directory of the module
  41 #   <XPREFIX>_INCLUDEDIR ... include-dir of the module
  42 #   <XPREFIX>_LIBDIR     ... lib-dir of the module
  43 #
  44 #   <XPREFIX> = <PREFIX>  when |MODULES| == 1, else
  45 #   <XPREFIX> = <PREFIX>_<MODNAME>
  46 #
  47 # A <MODULE> parameter can have the following formats:
  48 #   {MODNAME}            ... matches any version
  49 #   {MODNAME}>={VERSION} ... at least version <VERSION> is required
  50 #   {MODNAME}={VERSION}  ... exactly version <VERSION> is required
  51 #   {MODNAME}<={VERSION} ... modules must not be newer than <VERSION>
  52 #
  53 # Examples
  54 #   pkg_check_modules (GLIB2   glib-2.0)
  55 #
  56 #   pkg_check_modules (GLIB2   glib-2.0>=2.10)
  57 #     requires at least version 2.10 of glib2 and defines e.g.
  58 #       GLIB2_VERSION=2.10.3
  59 #
  60 #   pkg_check_modules (FOO     glib-2.0>=2.10 gtk+-2.0)
  61 #     requires both glib2 and gtk2, and defines e.g.
  62 #       FOO_glib-2.0_VERSION=2.10.3
  63 #       FOO_gtk+-2.0_VERSION=2.8.20
  64 #
  65 #   pkg_check_modules (XRENDER REQUIRED xrender)
  66 #     defines e.g.:
  67 #       XRENDER_LIBRARIES=Xrender;X11
  68 #       XRENDER_STATIC_LIBRARIES=Xrender;X11;pthread;Xau;Xdmcp
  69 #
  70 #   pkg_search_module (BAR     libxml-2.0 libxml2 libxml>=2)
  71
  72
  73 # Copyright (C) 2006 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
  74 #
  75 # Redistribution and use, with or without modification, are permitted
  76 # provided that the following conditions are met:
  77 #
  78 #    1. Redistributions must retain the above copyright notice, this
  79 #       list of conditions and the following disclaimer.
  80 #    2. The name of the author may not be used to endorse or promote
  81 #       products derived from this software without specific prior
  82 #       written permission.
  83 #
  84 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  85 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  86 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  87 # ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  88 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  89 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  90 # GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  91 # INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER
  92 # IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  93 # OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN
  94 # IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  95
  96 # Modified for KDE use from cmake 2.6.2 version, to add QUIET option to
  97 # pkg_check_modules().
  98 # Copyright (c) 2009, David Jarvie <djarvie@kde.org>
  99 #
 100 # Redistribution and use is allowed according to the terms of the BSD license.
 101 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
 102
 103
 104
 105 ### Common stuff ####
 106 set(PKG_CONFIG_VERSION 1)
 107 set(PKG_CONFIG_FOUND   0)
 108
 109 find_program(PKG_CONFIG_EXECUTABLE NAMES pkg-config DOC "pkg-config executable")
 110 mark_as_advanced(PKG_CONFIG_EXECUTABLE)
 111
 112 if(PKG_CONFIG_EXECUTABLE)
 113   set(PKG_CONFIG_FOUND 1)
 114 endif(PKG_CONFIG_EXECUTABLE)
 115
 116
 117 # Unsets the given variables
 118 macro(_pkgconfig_unset var)
 119   set(${var} "" CACHE INTERNAL "")
 120 endmacro(_pkgconfig_unset)
 121
 122 macro(_pkgconfig_set var value)
 123   set(${var} ${value} CACHE INTERNAL "")
 124 endmacro(_pkgconfig_set)
 125
 126 # Invokes pkgconfig, cleans up the result and sets variables
 127 macro(_pkgconfig_invoke _pkglist _prefix _varname _regexp)
 128   set(_pkgconfig_invoke_result)
 129
 130   execute_process(
 131     COMMAND ${PKG_CONFIG_EXECUTABLE} ${ARGN} ${_pkglist}
 132     OUTPUT_VARIABLE _pkgconfig_invoke_result
 133     RESULT_VARIABLE _pkgconfig_failed)
 134
 135   if (_pkgconfig_failed)
 136     set(_pkgconfig_${_varname} "")
 137     _pkgconfig_unset(${_prefix}_${_varname})
 138   else(_pkgconfig_failed)
 139     string(REGEX REPLACE "[\r\n]"                  " " _pkgconfig_invoke_result "${_pkgconfig_invoke_result}")
 140     string(REGEX REPLACE " +$"                     ""  _pkgconfig_invoke_result "${_pkgconfig_invoke_result}")
 141
 142     if (NOT ${_regexp} STREQUAL "")
 143       string(REGEX REPLACE "${_regexp}" " " _pkgconfig_invoke_result "${_pkgconfig_invoke_result}")
 144     endif(NOT ${_regexp} STREQUAL "")
 145
 146     separate_arguments(_pkgconfig_invoke_result)
 147
 148     #message(STATUS "  ${_varname} ... ${_pkgconfig_invoke_result}")
 149     set(_pkgconfig_${_varname} ${_pkgconfig_invoke_result})
 150     _pkgconfig_set(${_prefix}_${_varname} "${_pkgconfig_invoke_result}")
 151   endif(_pkgconfig_failed)
 152 endmacro(_pkgconfig_invoke)
 153
 154 # Invokes pkgconfig two times; once without '--static' and once with
 155 # '--static'
 156 macro(_pkgconfig_invoke_dyn _pkglist _prefix _varname cleanup_regexp)
 157   _pkgconfig_invoke("${_pkglist}" ${_prefix}        ${_varname} "${cleanup_regexp}" ${ARGN})
 158   _pkgconfig_invoke("${_pkglist}" ${_prefix} STATIC_${_varname} "${cleanup_regexp}" --static  ${ARGN})
 159 endmacro(_pkgconfig_invoke_dyn)
 160
 161 # Splits given arguments into options and a package list
 162 macro(_pkgconfig_parse_options _result _is_req _is_silent)
 163   set(${_is_req} 0)
 164   set(${_is_silent} 0)
 165
 166   foreach(_pkg ${ARGN})
 167     if (_pkg STREQUAL "REQUIRED")
 168       set(${_is_req} 1)
 169     endif (_pkg STREQUAL "REQUIRED")
 170     if (_pkg STREQUAL "QUIET")
 171       set(${_is_silent} 1)
 172     endif (_pkg STREQUAL "QUIET")
 173   endforeach(_pkg ${ARGN})
 174
 175   set(${_result} ${ARGN})
 176   list(REMOVE_ITEM ${_result} "REQUIRED")
 177   list(REMOVE_ITEM ${_result} "QUIET")
 178 endmacro(_pkgconfig_parse_options)
 179
 180 ###
 181 macro(_pkg_check_modules_internal _is_required _is_silent _prefix)
 182   _pkgconfig_unset(${_prefix}_FOUND)
 183   _pkgconfig_unset(${_prefix}_VERSION)
 184   _pkgconfig_unset(${_prefix}_PREFIX)
 185   _pkgconfig_unset(${_prefix}_INCLUDEDIR)
 186   _pkgconfig_unset(${_prefix}_LIBDIR)
 187   _pkgconfig_unset(${_prefix}_LIBS)
 188   _pkgconfig_unset(${_prefix}_LIBS_L)
 189   _pkgconfig_unset(${_prefix}_LIBS_PATHS)
 190   _pkgconfig_unset(${_prefix}_LIBS_OTHER)
 191   _pkgconfig_unset(${_prefix}_CFLAGS)
 192   _pkgconfig_unset(${_prefix}_CFLAGS_I)
 193   _pkgconfig_unset(${_prefix}_CFLAGS_OTHER)
 194   _pkgconfig_unset(${_prefix}_STATIC_LIBDIR)
 195   _pkgconfig_unset(${_prefix}_STATIC_LIBS)
 196   _pkgconfig_unset(${_prefix}_STATIC_LIBS_L)
 197   _pkgconfig_unset(${_prefix}_STATIC_LIBS_PATHS)
 198   _pkgconfig_unset(${_prefix}_STATIC_LIBS_OTHER)
 199   _pkgconfig_unset(${_prefix}_STATIC_CFLAGS)
 200   _pkgconfig_unset(${_prefix}_STATIC_CFLAGS_I)
 201   _pkgconfig_unset(${_prefix}_STATIC_CFLAGS_OTHER)
 202
 203   # create a better addressable variable of the modules and calculate its size
 204   set(_pkg_check_modules_list ${ARGN})
 205   list(LENGTH _pkg_check_modules_list _pkg_check_modules_cnt)
 206
 207   if(PKG_CONFIG_EXECUTABLE)
 208     # give out status message telling checked module
 209     if (NOT ${_is_silent})
 210       if (_pkg_check_modules_cnt EQUAL 1)
 211         message(STATUS "checking for module '${_pkg_check_modules_list}'")
 212       else(_pkg_check_modules_cnt EQUAL 1)
 213         message(STATUS "checking for modules '${_pkg_check_modules_list}'")
 214       endif(_pkg_check_modules_cnt EQUAL 1)
 215     endif(NOT ${_is_silent})
 216
 217     set(_pkg_check_modules_packages)
 218     set(_pkg_check_modules_failed)
 219
 220     # iterate through module list and check whether they exist and match the required version
 221     foreach (_pkg_check_modules_pkg ${_pkg_check_modules_list})
 222       set(_pkg_check_modules_exist_query)
 223
 224       # check whether version is given
 225       if (_pkg_check_modules_pkg MATCHES ".*(>=|=|<=).*")
 226         string(REGEX REPLACE "(.*[^><])(>=|=|<=)(.*)" "\\1" _pkg_check_modules_pkg_name "${_pkg_check_modules_pkg}")
 227         string(REGEX REPLACE "(.*[^><])(>=|=|<=)(.*)" "\\2" _pkg_check_modules_pkg_op   "${_pkg_check_modules_pkg}")
 228         string(REGEX REPLACE "(.*[^><])(>=|=|<=)(.*)" "\\3" _pkg_check_modules_pkg_ver  "${_pkg_check_modules_pkg}")
 229       else(_pkg_check_modules_pkg MATCHES ".*(>=|=|<=).*")
 230         set(_pkg_check_modules_pkg_name "${_pkg_check_modules_pkg}")
 231         set(_pkg_check_modules_pkg_op)
 232         set(_pkg_check_modules_pkg_ver)
 233       endif(_pkg_check_modules_pkg MATCHES ".*(>=|=|<=).*")
 234
 235       # handle the operands
 236       if (_pkg_check_modules_pkg_op STREQUAL ">=")
 237         list(APPEND _pkg_check_modules_exist_query --atleast-version)
 238       endif(_pkg_check_modules_pkg_op STREQUAL ">=")
 239
 240       if (_pkg_check_modules_pkg_op STREQUAL "=")
 241         list(APPEND _pkg_check_modules_exist_query --exact-version)
 242       endif(_pkg_check_modules_pkg_op STREQUAL "=")
 243
 244       if (_pkg_check_modules_pkg_op STREQUAL "<=")
 245         list(APPEND _pkg_check_modules_exist_query --max-version)
 246       endif(_pkg_check_modules_pkg_op STREQUAL "<=")
 247
 248       # create the final query which is of the format:
 249       # * --atleast-version <version> <pkg-name>
 250       # * --exact-version <version> <pkg-name>
 251       # * --max-version <version> <pkg-name>
 252       # * --exists <pkg-name>
 253       if (_pkg_check_modules_pkg_op)
 254         list(APPEND _pkg_check_modules_exist_query "${_pkg_check_modules_pkg_ver}")
 255       else(_pkg_check_modules_pkg_op)
 256         list(APPEND _pkg_check_modules_exist_query --exists)
 257       endif(_pkg_check_modules_pkg_op)
 258
 259       _pkgconfig_unset(${_prefix}_${_pkg_check_modules_pkg_name}_VERSION)
 260       _pkgconfig_unset(${_prefix}_${_pkg_check_modules_pkg_name}_PREFIX)
 261       _pkgconfig_unset(${_prefix}_${_pkg_check_modules_pkg_name}_INCLUDEDIR)
 262       _pkgconfig_unset(${_prefix}_${_pkg_check_modules_pkg_name}_LIBDIR)
 263
 264       list(APPEND _pkg_check_modules_exist_query "${_pkg_check_modules_pkg_name}")
 265       list(APPEND _pkg_check_modules_packages    "${_pkg_check_modules_pkg_name}")
 266
 267       # execute the query
 268       execute_process(
 269         COMMAND ${PKG_CONFIG_EXECUTABLE} ${_pkg_check_modules_exist_query}
 270         RESULT_VARIABLE _pkgconfig_retval)
 271
 272       # evaluate result and tell failures
 273       if (_pkgconfig_retval)
 274         if(NOT ${_is_silent})
 275           message(STATUS "  package '${_pkg_check_modules_pkg}' not found")
 276         endif(NOT ${_is_silent})
 277
 278         set(_pkg_check_modules_failed 1)
 279       endif(_pkgconfig_retval)
 280     endforeach(_pkg_check_modules_pkg)
 281
 282     if(_pkg_check_modules_failed)
 283       # fail when requested
 284       if (${_is_required})
 285         message(SEND_ERROR "A required package was not found")
 286       endif (${_is_required})
 287     else(_pkg_check_modules_failed)
 288       # when we are here, we checked whether requested modules
 289       # exist. Now, go through them and set variables
 290
 291       _pkgconfig_set(${_prefix}_FOUND 1)
 292       list(LENGTH _pkg_check_modules_packages pkg_count)
 293
 294       # iterate through all modules again and set individual variables
 295       foreach (_pkg_check_modules_pkg ${_pkg_check_modules_packages})
 296         # handle case when there is only one package required
 297         if (pkg_count EQUAL 1)
 298           set(_pkg_check_prefix "${_prefix}")
 299         else(pkg_count EQUAL 1)
 300           set(_pkg_check_prefix "${_prefix}_${_pkg_check_modules_pkg}")
 301         endif(pkg_count EQUAL 1)
 302
 303         _pkgconfig_invoke(${_pkg_check_modules_pkg} "${_pkg_check_prefix}" VERSION    ""   --modversion )
 304         _pkgconfig_invoke(${_pkg_check_modules_pkg} "${_pkg_check_prefix}" PREFIX     ""   --variable=prefix )
 305         _pkgconfig_invoke(${_pkg_check_modules_pkg} "${_pkg_check_prefix}" INCLUDEDIR ""   --variable=includedir )
 306         _pkgconfig_invoke(${_pkg_check_modules_pkg} "${_pkg_check_prefix}" LIBDIR     ""   --variable=libdir )
 307
 308         if (NOT ${_is_silent})
 309           message(STATUS "  found ${_pkg_check_modules_pkg}, version ${_pkgconfig_VERSION}")
 310         endif (NOT ${_is_silent})
 311       endforeach(_pkg_check_modules_pkg)
 312
 313       # set variables which are combined for multiple modules
 314       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" LIBRARIES           "(^| )-l" --libs-only-l )
 315       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" LIBRARY_DIRS        "(^| )-L" --libs-only-L )
 316       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" LDFLAGS             ""        --libs )
 317       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" LDFLAGS_OTHER       ""        --libs-only-other )
 318
 319       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" INCLUDE_DIRS        "(^| )-I" --cflags-only-I )
 320       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" CFLAGS              ""        --cflags )
 321       _pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" CFLAGS_OTHER        ""        --cflags-only-other )
 322     endif(_pkg_check_modules_failed)
 323   else(PKG_CONFIG_EXECUTABLE)
 324     if (${_is_required})
 325       message(SEND_ERROR "pkg-config tool not found")
 326     endif (${_is_required})
 327   endif(PKG_CONFIG_EXECUTABLE)
 328 endmacro(_pkg_check_modules_internal)
 329
 330 ###
 331 ### User visible macros start here
 332 ###
 333
 334 ###
 335 macro(pkg_check_modules _prefix _module0)
 336   # check cached value
 337   if (NOT DEFINED __pkg_config_checked_${_prefix} OR __pkg_config_checked_${_prefix} LESS ${PKG_CONFIG_VERSION} OR NOT ${_prefix}_FOUND)
 338     _pkgconfig_parse_options   (_pkg_modules _pkg_is_required _pkg_is_silent "${_module0}" ${ARGN})
 339     _pkg_check_modules_internal("${_pkg_is_required}" "${_pkg_is_silent}" "${_prefix}" ${_pkg_modules})
 340
 341     _pkgconfig_set(__pkg_config_checked_${_prefix} ${PKG_CONFIG_VERSION})
 342   endif(NOT DEFINED __pkg_config_checked_${_prefix} OR __pkg_config_checked_${_prefix} LESS ${PKG_CONFIG_VERSION} OR NOT ${_prefix}_FOUND)
 343 endmacro(pkg_check_modules)
 344
 345 ###
 346 macro(pkg_search_module _prefix _module0)
 347   # check cached value
 348   if (NOT DEFINED __pkg_config_checked_${_prefix} OR __pkg_config_checked_${_prefix} LESS ${PKG_CONFIG_VERSION} OR NOT ${_prefix}_FOUND)
 349     set(_pkg_modules_found 0)
 350     _pkgconfig_parse_options(_pkg_modules_alt _pkg_is_required _pkg_is_silent "${_module0}" ${ARGN})
 351
 352     if (NOT ${_pkg_is_silent})
 353       message(STATUS "checking for one of the modules '${_pkg_modules_alt}'")
 354     endif (NOT ${_pkg_is_silent})
 355
 356     # iterate through all modules and stop at the first working one.
 357     foreach(_pkg_alt ${_pkg_modules_alt})
 358       if(NOT _pkg_modules_found)
 359         _pkg_check_modules_internal(0 1 "${_prefix}" "${_pkg_alt}")
 360       endif(NOT _pkg_modules_found)
 361
 362       if (${_prefix}_FOUND)
 363         set(_pkg_modules_found 1)
 364       endif(${_prefix}_FOUND)
 365     endforeach(_pkg_alt)
 366
 367     if (NOT ${_prefix}_FOUND)
 368       if(${_pkg_is_required})
 369         message(SEND_ERROR "None of the required '${_pkg_modules_alt}' found")
 370       endif(${_pkg_is_required})
 371     endif(NOT ${_prefix}_FOUND)
 372
 373     _pkgconfig_set(__pkg_config_checked_${_prefix} ${PKG_CONFIG_VERSION})
 374   endif(NOT DEFINED __pkg_config_checked_${_prefix} OR __pkg_config_checked_${_prefix} LESS ${PKG_CONFIG_VERSION} OR NOT ${_prefix}_FOUND)
 375 endmacro(pkg_search_module)
 376
 377 ### Local Variables:
 378 ### mode: cmake
 379 ### End: