cmake/QuasselCompileSettings.cmake

   1 # This file contains compile flags and general build configuration for Quassel
   2 #
   3 # (C) 2014-2020 by the Quassel Project <devel@quassel-irc.org>
   4 #
   5 # Redistribution and use is allowed according to the terms of the BSD license.
   6 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
   7
   8 include(QuasselMacros)
   9
  10 # Helper function to check for linker flag support
  11 include(CheckCXXCompilerFlag)
  12 function(check_and_set_linker_flag flag name outvar)
  13     cmake_push_check_state(RESET)
  14     set(CMAKE_REQUIRED_FLAGS "${flag}")
  15     check_cxx_compiler_flag("" LINKER_SUPPORTS_${name})
  16     if (LINKER_SUPPORTS_${name})
  17         set(${outvar} "${${outvar}} ${flag}" PARENT_SCOPE)
  18     endif()
  19     cmake_pop_check_state()
  20 endfunction()
  21
  22 # General compile settings
  23 set(CMAKE_CXX_STANDARD 14)
  24 set(CMAKE_CXX_STANDARD_REQUIRED OFF)    # Rely on compile features if standard is not supported
  25 set(CMAKE_CXX_EXTENSIONS OFF)           # We like to be standard conform
  26
  27 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  28 set(CMAKE_VISIBILITY_INLINES_HIDDEN ON)
  29 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  30
  31 # For GCC and Clang, enable a whole bunch of warnings
  32 if (CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  33     add_compile_options(
  34         -fdiagnostics-color=always
  35         -fexceptions
  36         -fno-common
  37         -Wall
  38         -Wextra
  39         -Wcast-align
  40         -Wformat-security
  41         -Wnon-virtual-dtor
  42         -Woverloaded-virtual
  43         -Wpedantic
  44         -Wundef
  45         -Wvla
  46         -Werror=return-type
  47         "$<$<BOOL:${FATAL_WARNINGS}>:-Werror>"
  48         -Wno-unknown-pragmas
  49         "$<$<NOT:$<CONFIG:Debug>>:-U_FORTIFY_SOURCE;-D_FORTIFY_SOURCE=2>"
  50     )
  51
  52     # ssp is currently very broken on MinGW
  53     if(NOT MINGW)
  54         add_compile_options(-fstack-protector-strong)
  55     endif()
  56
  57     # Check for and set linker flags
  58     check_and_set_linker_flag("-Wl,-z,relro"            RELRO            LINKER_FLAGS)
  59     check_and_set_linker_flag("-Wl,-z,now"              NOW              LINKER_FLAGS)
  60     check_and_set_linker_flag("-Wl,--as-needed"         AS_NEEDED        LINKER_FLAGS)
  61     check_and_set_linker_flag("-Wl,--enable-new-dtags"  ENABLE_NEW_DTAGS LINKER_FLAGS)
  62     check_and_set_linker_flag("-Wl,--no-undefined"      NO_UNDEFINED     LINKER_FLAGS)
  63
  64     set(CMAKE_EXE_LINKER_FLAGS    "${LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
  65     set(CMAKE_MODULE_LINKER_FLAGS "${LINKER_FLAGS} ${CMAKE_MODULE_LINKER_FLAGS}")
  66     set(CMAKE_SHARED_LINKER_FLAGS "${LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
  67
  68 elseif(MSVC)
  69     # Target Windows Vista
  70     add_definitions(-D_WIN32_WINNT=0x0600 -DWINVER=0x0600 -D_WIN32_IE=0x0600)
  71
  72     # Various settings for the Windows API
  73     add_definitions(-DWIN32_LEAN_AND_MEAN -DUNICODE -D_UNICODE -D_USE_MATH_DEFINES -DNOMINMAX)
  74
  75     # Compile options
  76     add_compile_options(
  77         /EHsc
  78         "$<$<BOOL:${FATAL_WARNINGS}>:/WX>"
  79     )
  80
  81     # Increase warning level on MSVC
  82     # CMake puts /W3 in CMAKE_CXX_FLAGS which will be appended later, so we need to replace
  83     string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  84
  85     # Silence annoying/useless warnings
  86     #   C4127: conditional expression is constant
  87     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4127")
  88     #   C4244: 'identifier': conversion from 't1' to 't2', possible loss of data
  89     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4244")
  90     #   C4456: declaration of 'identifier' hides previous local declaration
  91     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4456")
  92     #   C4458: declaration of 'identifier' hides class member
  93     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4458")
  94
  95     # Link against the correct version of the C runtime
  96     set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
  97     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
  98     set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
  99     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/NODEFAULTLIB:libcmtd /DEFAULTLIB:msvcrtd ${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 100
 101 else()
 102     # For other compilers, we rely on default settings (unless someone provides a good set of options; patches welcome!)
 103     message(WARNING "${CMAKE_CXX_COMPILER_ID} is not a supported C++ compiler.")
 104 endif()
 105
 106 # Mac build stuff
 107 if (APPLE)
 108     set(CMAKE_OSX_ARCHITECTURES "x86_64")
 109     add_compile_options(
 110         -mmacosx-version-min=10.9
 111         -stdlib=libc++
 112     )
 113     add_definitions(-DQT_MAC_USE_COCOA -D_DARWIN_C_SOURCE)
 114 endif()
 115
 116 # Optionally, produce clazy warnings
 117 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 118     option(ENABLE_CLAZY "Enable Clazy warnings" OFF)
 119
 120     if(ENABLE_CLAZY)
 121         set(CMAKE_CXX_COMPILE_OBJECT "${CMAKE_CXX_COMPILE_OBJECT} -Xclang -load -Xclang ClangLazy${CMAKE_SHARED_LIBRARY_SUFFIX} -Xclang -add-plugin -Xclang clang-lazy")
 122     endif()
 123 endif()
 124
 125 # Append CMAKE_CXX_FLAGS, so our flags can be overwritten externally.
 126 process_cmake_cxx_flags()