cmake/QuasselCompileSettings.cmake

   1 # This file contains compile flags and general build configuration for Quassel
   2 #
   3 # (C) 2014-2020 by the Quassel Project <devel@quassel-irc.org>
   4 #
   5 # Redistribution and use is allowed according to the terms of the BSD license.
   6 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
   7
   8 include(QuasselMacros)
   9
  10 # Helper function to check for linker flag support
  11 include(CheckCXXCompilerFlag)
  12 function(check_and_set_linker_flag flag name outvar)
  13     cmake_push_check_state(RESET)
  14     set(CMAKE_REQUIRED_FLAGS "${flag}")
  15     check_cxx_compiler_flag("" LINKER_SUPPORTS_${name})
  16     if (LINKER_SUPPORTS_${name})
  17         set(${outvar} "${${outvar}} ${flag}" PARENT_SCOPE)
  18     endif()
  19     cmake_pop_check_state()
  20 endfunction()
  21
  22 # General compile settings
  23 set(CMAKE_CXX_STANDARD 14)
  24 set(CMAKE_CXX_STANDARD_REQUIRED OFF)    # Rely on compile features if standard is not supported
  25 set(CMAKE_CXX_EXTENSIONS OFF)           # We like to be standard conform
  26
  27 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  28 set(CMAKE_VISIBILITY_INLINES_HIDDEN ON)
  29 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  30
  31 # For GCC and Clang, enable a whole bunch of warnings
  32 if (CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  33     add_compile_options(
  34         -fdiagnostics-color=always
  35         -fexceptions
  36         -fno-common
  37         -Wall
  38         -Wextra
  39         -Wcast-align
  40         -Wformat-security
  41         -Wnon-virtual-dtor
  42         -Woverloaded-virtual
  43         -Wpedantic
  44         -Wundef
  45         -Wvla
  46         -Werror=return-type
  47         "$<$<BOOL:${FATAL_WARNINGS}>:-Werror>"
  48         -Wno-error=deprecated-declarations  # Don't break on Qt upgrades
  49         -Wno-unknown-pragmas
  50         "$<$<NOT:$<CONFIG:Debug>>:-U_FORTIFY_SOURCE;-D_FORTIFY_SOURCE=2>"
  51     )
  52
  53     # ssp is currently very broken on MinGW
  54     if(NOT MINGW)
  55         add_compile_options(-fstack-protector-strong)
  56     endif()
  57
  58     # Check for and set linker flags
  59     check_and_set_linker_flag("-Wl,-z,relro"            RELRO            LINKER_FLAGS)
  60     check_and_set_linker_flag("-Wl,-z,now"              NOW              LINKER_FLAGS)
  61     check_and_set_linker_flag("-Wl,--as-needed"         AS_NEEDED        LINKER_FLAGS)
  62     check_and_set_linker_flag("-Wl,--enable-new-dtags"  ENABLE_NEW_DTAGS LINKER_FLAGS)
  63     check_and_set_linker_flag("-Wl,--no-undefined"      NO_UNDEFINED     LINKER_FLAGS)
  64
  65     set(CMAKE_EXE_LINKER_FLAGS    "${LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
  66     set(CMAKE_MODULE_LINKER_FLAGS "${LINKER_FLAGS} ${CMAKE_MODULE_LINKER_FLAGS}")
  67     set(CMAKE_SHARED_LINKER_FLAGS "${LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
  68
  69 elseif(MSVC)
  70     # Target Windows Vista
  71     add_definitions(-D_WIN32_WINNT=0x0600 -DWINVER=0x0600 -D_WIN32_IE=0x0600)
  72
  73     # Various settings for the Windows API
  74     add_definitions(-DWIN32_LEAN_AND_MEAN -DUNICODE -D_UNICODE -D_USE_MATH_DEFINES -DNOMINMAX)
  75
  76     # Compile options
  77     add_compile_options(
  78         /EHsc
  79         "$<$<BOOL:${FATAL_WARNINGS}>:/WX>"
  80     )
  81
  82     # Increase warning level on MSVC
  83     # CMake puts /W3 in CMAKE_CXX_FLAGS which will be appended later, so we need to replace
  84     string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  85
  86     # Silence annoying/useless warnings
  87     #   C4127: conditional expression is constant
  88     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4127")
  89     #   C4244: 'identifier': conversion from 't1' to 't2', possible loss of data
  90     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4244")
  91     #   C4456: declaration of 'identifier' hides previous local declaration
  92     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4456")
  93     #   C4458: declaration of 'identifier' hides class member
  94     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4458")
  95     #   C4996: deprecation warnings
  96     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4996")
  97
  98     # Link against the correct version of the C runtime
  99     set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 100     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
 101     set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
 102     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/NODEFAULTLIB:libcmtd /DEFAULTLIB:msvcrtd ${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 103
 104 else()
 105     # For other compilers, we rely on default settings (unless someone provides a good set of options; patches welcome!)
 106     message(WARNING "${CMAKE_CXX_COMPILER_ID} is not a supported C++ compiler.")
 107 endif()
 108
 109 # Mac build stuff
 110 if (APPLE)
 111     set(CMAKE_OSX_ARCHITECTURES "x86_64")
 112     add_compile_options(
 113         -mmacosx-version-min=10.9
 114         -stdlib=libc++
 115     )
 116     add_definitions(-DQT_MAC_USE_COCOA -D_DARWIN_C_SOURCE)
 117 endif()
 118
 119 # Optionally, produce clazy warnings
 120 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 121     option(ENABLE_CLAZY "Enable Clazy warnings" OFF)
 122
 123     if(ENABLE_CLAZY)
 124         set(CMAKE_CXX_COMPILE_OBJECT "${CMAKE_CXX_COMPILE_OBJECT} -Xclang -load -Xclang ClangLazy${CMAKE_SHARED_LIBRARY_SUFFIX} -Xclang -add-plugin -Xclang clang-lazy")
 125     endif()
 126 endif()
 127
 128 # Append CMAKE_CXX_FLAGS, so our flags can be overwritten externally.
 129 process_cmake_cxx_flags()