build/targets/target.pri

   1 TEMPLATE = app
   2
   3 include(../buildconf.pri)
   4
   5 RESOURCES   *= ../../i18n/i18n.qrc
   6 TRANSLATIONS = quassel_da.ts \
   7                quassel_de.ts
   8
   9 SRCPATH = ../../src
  10 OBJECTS_DIR = .$$TARGET
  11 RCC_DIR     = .$$TARGET
  12
  13 for(mod, MODULES) {
  14   INCLUDEPATH *= $$SRCPATH/$$mod
  15   LIBS *= -L../modules/$$dirname(mod) -l$$basename(mod)
  16   PRE_TARGETDEPS *= ../modules/$$mod
  17 }
  18 PRE_TARGETDEPS *= ../../version.inc
  19
  20 #CONTRIB += libqxt  # not needed
  21 #include(../contrib/contrib.pri)
  22
  23 SOURCES = $$SRCPATH/common/main.cpp
  24
  25 # This is really annoying, but for some reason win32 libs are not included by default.
  26 # Ugly workaround following...
  27
  28 win32 {
  29   CONFIG += embed_manifest_exe
  30   LIBS *= -luser32 -lgdi32 -lkernel32 -lshell32 -lwsock32 -lwinspool -lcomdlg32 -lole32
  31   LIBS *= -ladvapi32 -limm32 -luuid -lwinmm -ldelayimp -lopengl32 -lglu32 -loleaut32 -lws2_32
  32 }
  33