build/modules/module.pri

   1 # module.pri
   2 # This file is included by module project files.
   3
   4 include(../buildconf.pri)
   5
   6 TEMPLATE = lib
   7 CONFIG += staticlib
   8
   9 SRCPATH = ../../src  # Path to sources relative to this file
  10
  11 # Set paths according to MODULE
  12 # We need to handle MODULE definitions like contrib/foo
  13
  14 MODNAME = $$basename(MODULE)
  15 MODPATH_PREFIX = $$dirname(MODULE)
  16 !isEmpty(MODPATH_PREFIX) {
  17   MODPATH_PREFIX ~= s,[^/]+,..
  18   #sprintf($$MODPATH_PREFIX%1
  19   SRCPATH = $$MODPATH_PREFIX/$$SRCPATH
  20 }
  21
  22 MODPATH = $$SRCPATH/$$MODULE  # Path to the module files
  23
  24 # Define build directories
  25
  26 OBJECTS_DIR = $$MODNAME
  27 MOC_DIR =     $$MODNAME
  28 UI_DIR =      $$MODNAME
  29
  30 # Load module settings (files etc.)
  31
  32 include($$MODPATH/$${MODNAME}.pri)
  33
  34 # Define needed Qt modules
  35
  36 QT -= gui
  37 for(qtmod, QT_MOD) {
  38   QT *= $$qtmod
  39 }
  40
  41 # Set includepath for needed Quassel modules
  42
  43 for(dep, DEPMOD) {
  44   INCLUDEPATH *= $$SRCPATH/$$dep
  45 }
  46 INCLUDEPATH *= $$MODPATH  # and don't forget our own dir
  47
  48 # Now prefix all filenames with the correct dirname
  49
  50 for(src, SRCS) {
  51   SOURCES *= $$MODPATH/$$src
  52 }
  53
  54 for(hdr, HDRS) {
  55   HEADERS *= $$MODPATH/$$hdr
  56 }
  57
  58 for(frm, FRMS) {
  59   FORMS *= $$MODPATH/$$frm
  60 }