Make QuasselTopia run on the Greenphone! \o/
[quassel.git] / build / modules / module.pri
1 # module.pri
2 # This file is included by module project files.
3
4 include(../buildconf.pri)
5
6 TEMPLATE = lib
7 CONFIG += staticlib
8
9 SRCPATH = ../../src  # Path to sources relative to this file
10
11 # Set paths according to MODULE
12 # We need to handle MODULE definitions like contrib/foo
13
14 MODNAME = $$basename(MODULE)
15 MODPATH_PREFIX = $$dirname(MODULE)
16 !isEmpty(MODPATH_PREFIX) {
17   MODPATH_PREFIX ~= s,[^/]+,..
18   SRCPATH = $$MODPATH_PREFIX/$$SRCPATH
19 }
20
21 MODPATH = $$SRCPATH/$$MODULE  # Path to the module files
22
23 # Define build directories
24
25 OBJECTS_DIR = $$MODNAME
26 MOC_DIR =     $$MODNAME
27 UI_DIR =      $$MODNAME
28
29 # Load module settings (files etc.)
30
31 include($$MODPATH/$${MODNAME}.pri)
32
33 # Define needed Qt modules
34
35 QT -= gui
36 for(qtmod, QT_MOD) {
37   QT *= $$qtmod
38 }
39
40 # Include contrib stuff
41
42 include(../contrib/contrib.pri)
43
44 # Set includepath for needed Quassel modules
45
46 for(dep, DEPMOD) {
47   INCLUDEPATH *= $$SRCPATH/$$dep
48 }
49 INCLUDEPATH *= $$MODPATH  # and don't forget our own dir
50
51 # Now prefix all filenames with the correct dirname
52
53 for(src, SRCS) {
54   SOURCES *= $$MODPATH/$$src
55 }
56
57 for(hdr, HDRS) {
58   HEADERS *= $$MODPATH/$$hdr
59 }
60
61 for(frm, FRMS) {
62   FORMS *= $$MODPATH/$$frm
63 }