build/modules/module.pri

   1 # module.pri
   2 # This file is included by module project files.
   3
   4 TEMPLATE = lib
   5 CONFIG += staticlib
   6
   7 SRCPATH = ../../src  # Path to sources relative to this file
   8
   9 # Set paths according to MODULE
  10 # We need to handle MODULE definitions like contrib/foo
  11
  12 MODNAME = $$basename(MODULE)
  13 MODPATH_PREFIX = $$dirname(MODULE)
  14 !isEmpty(MODPATH_PREFIX) {
  15   MODPATH_PREFIX ~= s,[^/]+,..
  16   #sprintf($$MODPATH_PREFIX%1
  17   SRCPATH = $$MODPATH_PREFIX/$$SRCPATH
  18 }
  19
  20 MODPATH = $$SRCPATH/$$MODULE  # Path to the module files
  21
  22 # Define build directories
  23
  24 OBJECTS_DIR = .$$MODNAME
  25 MOC_DIR =     .$$MODNAME
  26 UI_DIR =      .$$MODNAME
  27
  28 # Load module settings (files etc.)
  29
  30 include($$MODPATH/$${MODNAME}.pri)
  31
  32 # Define needed Qt modules
  33
  34 QT -= gui
  35 for(qtmod, QT_MOD) {
  36   QT *= $$qtmod
  37 }
  38
  39 # Set includepath for needed Quassel modules
  40
  41 for(dep, DEPMOD) {
  42   INCLUDEPATH *= $$SRCPATH/$$dep
  43 }
  44 INCLUDEPATH *= $$MODPATH  # and don't forget our own dir
  45
  46 # Now prefix all filenames with the correct dirname
  47
  48 for(src, SRCS) {
  49   SOURCES *= $$MODPATH/$$src
  50 }
  51
  52 for(hdr, HDRS) {
  53   HEADERS *= $$MODPATH/$$hdr
  54 }
  55
  56 for(frm, FRMS) {
  57   FORMS *= $$MODPATH/$$frm
  58 }