CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 13)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.13-pre")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT5 and USE_QT4; if neither is set, Qt5 will be used
  44 option(USE_QT5 "Enable support for Qt5" OFF)
  45 if (USE_QT5) # takes precedence
  46     set(USE_QT4 OFF)
  47 else()
  48     if (NOT USE_QT4)
  49         set(USE_QT5 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_BREEZE "Install Breeze icon theme (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 cmake_dependent_option(WITH_BREEZE_DARK "Install Dark Breeze icon theme (usually shipped with KDE)" OFF "NOT WITH_KDE" OFF)
  75 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon theme (usually shipped with KDE)" OFF "NOT WITH_KDE" OFF)
  76 if (NOT WITH_KDE)
  77     add_feature_info(WITH_BREEZE WITH_BREEZE "Install Breeze icon theme")
  78     add_feature_info(WITH_BREEZE_DARK WITH_BREEZE_DARK "Install Dark Breeze icon theme")
  79     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon theme")
  80 endif()
  81
  82 if (WITH_OXYGEN)
  83     add_definitions(-DWITH_OXYGEN)
  84 endif()
  85 if (WITH_BREEZE)
  86     add_definitions(-DWITH_BREEZE)
  87 endif()
  88 if (WITH_BREEZE_DARK)
  89     add_definitions(-DWITH_BREEZE_DARK)
  90 endif()
  91
  92 # For this, the feature info is added after we know if QtWebkit is installed
  93 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  94
  95 # For this, the feature info is added after we know if QtWebEngine is installed
  96 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  97
  98 if (APPLE)
  99     # Notification Center is only available in > 10.8, which is Darwin v12
 100     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
 101         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
 102         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
 103     endif()
 104     find_library(CARBON_LIBRARY Carbon)
 105     mark_as_advanced(CARBON_LIBRARY)
 106     link_libraries(${CARBON_LIBRARY})
 107 endif()
 108
 109 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
 110 set(EMBED_DEFAULT OFF)
 111 if (STATIC OR WIN32 OR APPLE)
 112     set(EMBED_DEFAULT ON)
 113 endif()
 114 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 115                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 116 if (NOT EMBED_DEFAULT)
 117     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 118 endif()
 119
 120 # The following options are not for end-user consumption, so don't list them in the feature summary
 121 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 122
 123 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 124 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 125
 126 # For static builds, arbitrary extra libs might need to be linked
 127 # Define a comma-separated list here
 128 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 129 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 130 if (LINK_EXTRA)
 131     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 132     link_libraries(${LINK_EXTRA})
 133 endif()
 134
 135
 136 # LDAP Authentication (and other authentication backends).
 137 ####################################################################
 138 option(WITH_LDAP     "Enable LDAP authentication support if present on system"  ON)
 139
 140 # Setup CMake
 141 #####################################################################
 142
 143 if (USE_QT5 AND WITH_KDE)
 144     cmake_minimum_required(VERSION 2.8.12)
 145 else()
 146     cmake_minimum_required(VERSION 2.8.9)
 147 endif()
 148
 149 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 150 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 151 if (POLICY CMP0043)
 152     cmake_policy(SET CMP0043 OLD)
 153 endif()
 154
 155 # Honor visibility settings for all target types
 156 if (POLICY CMP0063)
 157     cmake_policy(SET CMP0063 NEW)
 158 endif()
 159
 160
 161 # Simplify later checks
 162 #####################################################################
 163
 164 if (WANT_MONO OR WANT_QTCLIENT)
 165     set(BUILD_GUI true)
 166 endif()
 167 if (WANT_MONO OR WANT_CORE)
 168     set(BUILD_CORE true)
 169 endif()
 170
 171
 172 # Set up Qt
 173 #####################################################################
 174
 175 # Find package dependencies
 176 #
 177 # Note that you can forcefully disable optional packages
 178 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 179 #####################################################################
 180
 181 if (USE_QT5)
 182     message(STATUS "Building for Qt5...")
 183     set(QT_MIN_VERSION "5.2.0")
 184     add_definitions(-DHAVE_QT5)
 185
 186     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 187     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 188         URL "http://qt.digia.com"
 189         DESCRIPTION "contains core functionality for Qt"
 190     )
 191     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 192     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 193     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 194         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 195     endif()
 196
 197     find_package(Qt5Network QUIET)
 198     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 199         DESCRIPTION "the network module for Qt5"
 200     )
 201
 202     if (BUILD_GUI)
 203         find_package(Qt5Gui QUIET)
 204         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 205             DESCRIPTION "the GUI module for Qt5"
 206         )
 207         find_package(Qt5Widgets QUIET)
 208         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 209             DESCRIPTION "the widgets module for Qt5"
 210         )
 211
 212         if (NOT WIN32)
 213             find_package(Qt5DBus QUIET)
 214             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 215                 URL "http://qt.digia.com"
 216                 DESCRIPTION "D-Bus support for Qt5"
 217                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 218             )
 219             if (Qt5DBus_FOUND)
 220                 find_package(dbusmenu-qt5 QUIET CONFIG)
 221                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 222                     URL "https://launchpad.net/libdbusmenu-qt"
 223                     DESCRIPTION "a library implementing the DBusMenu specification"
 224                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 225                 )
 226             endif()
 227         endif()
 228
 229         find_package(Qt5Multimedia QUIET)
 230         set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 231             URL "http://qt.digia.com"
 232             DESCRIPTION "Multimedia support for Qt5"
 233             PURPOSE     "Required for audio notifications"
 234         )
 235
 236         if (NOT Qt5Multimedia_FOUND)
 237             find_package(Phonon4Qt5 QUIET)
 238             set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 239                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 240                 DESCRIPTION "a multimedia abstraction library"
 241                 PURPOSE     "Required for audio notifications"
 242             )
 243         endif()
 244
 245         find_package(LibsnoreQt5 0.7.0 QUIET)
 246         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 247             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 248             DESCRIPTION "a cross-platform notification framework"
 249             PURPOSE     "Enable support for the snorenotify framework"
 250         )
 251         if(LibsnoreQt5_FOUND)
 252             find_package(LibsnoreSettingsQt5)
 253             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 254                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 255                 DESCRIPTION "a cross-platform notification framework"
 256                 PURPOSE     "Enable support for the snorenotify framework"
 257             )
 258         endif()
 259
 260
 261         if (WITH_WEBKIT)
 262             find_package(Qt5WebKit QUIET)
 263             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 264                 URL "http://qt.digia.com"
 265                 DESCRIPTION "a WebKit implementation for Qt"
 266                 PURPOSE     "Needed for displaying previews for URLs in chat"
 267             )
 268             if (Qt5WebKit_FOUND)
 269                 find_package(Qt5WebKitWidgets QUIET)
 270                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 271                     URL "http://qt.digia.com"
 272                     DESCRIPTION "widgets for Qt's WebKit implementation"
 273                     PURPOSE     "Needed for displaying previews for URLs in chat"
 274                 )
 275             endif()
 276         endif()
 277
 278         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 279             set(HAVE_WEBKIT true)
 280         endif()
 281         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 282
 283         if (WITH_WEBENGINE)
 284             find_package(Qt5WebEngine QUIET)
 285             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 286                 URL "http://qt.digia.com"
 287                 DESCRIPTION "a WebEngine implementation for Qt"
 288                 PURPOSE     "Needed for displaying previews for URLs in chat"
 289             )
 290             if (Qt5WebEngine_FOUND)
 291                 find_package(Qt5WebEngineWidgets QUIET)
 292                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 293                     URL "http://qt.digia.com"
 294                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 295                     PURPOSE     "Needed for displaying previews for URLs in chat"
 296                 )
 297             endif()
 298         endif()
 299
 300         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 301             set(HAVE_WEBENGINE true)
 302         endif()
 303         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 304
 305         # KDE Frameworks
 306         ################
 307
 308         if (WITH_KDE)
 309             set(ecm_find_type "REQUIRED")
 310         else()
 311             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 312             set(ecm_find_type "RECOMMENDED")
 313         endif()
 314
 315         # extra-cmake-modules
 316         find_package(ECM NO_MODULE QUIET)
 317         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 318             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 319             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 320             PURPOSE     "Required to find KDE Frameworks components"
 321         )
 322
 323         if (ECM_FOUND)
 324             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 325             if (WITH_KDE)
 326                 find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 327                 set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 328                     URL "http://www.kde.org"
 329                     DESCRIPTION "KDE Frameworks"
 330                     PURPOSE     "Required for integration into the Plasma desktop"
 331                 )
 332             else()
 333                 find_package(KF5Sonnet QUIET)
 334                 set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 335                     URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 336                     DESCRIPTION "framework for providing spell-checking capabilities"
 337                     PURPOSE "Enables spell-checking support in input widgets"
 338                 )
 339             endif()
 340         endif()
 341
 342     endif()
 343
 344     if (BUILD_CORE)
 345         find_package(Qt5Script QUIET)
 346         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 347             DESCRIPTION "provides scripting support for Qt5"
 348         )
 349         find_package(Qt5Sql QUIET)
 350         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 351             DESCRIPTION "the database support module for Qt5"
 352         )
 353
 354         find_package(QCA2-QT5)
 355         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 356             URL "https://projects.kde.org/projects/kdesupport/qca"
 357             DESCRIPTION "Qt Cryptographic Architecture"
 358             PURPOSE "Required for encryption support"
 359         )
 360
 361     endif()
 362
 363     find_package(Qt5LinguistTools QUIET)
 364     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 365                            DESCRIPTION "contains tools for handling translation files"
 366                            PURPOSE "Required for having translations"
 367     )
 368
 369     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 370     if (Qt5LinguistTools_FOUND)
 371         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 372             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 373             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 374             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 375         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 376             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 377             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 378         endif()
 379
 380         # Compatibility with the Qt4 variables
 381         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 382         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 383         if (Qt5_LCONVERT_EXECUTABLE)
 384             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 385         endif()
 386     endif()
 387
 388 else()
 389     message(STATUS "Building for Qt4...")
 390     set(QT_MIN_VERSION "4.8.0")
 391
 392     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 393
 394     if (BUILD_GUI)
 395         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 396         if (QT_QTDBUS_FOUND)
 397             find_package(dbusmenu-qt QUIET CONFIG)
 398             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 399                 URL "https://launchpad.net/libdbusmenu-qt"
 400                 DESCRIPTION "a library implementing the DBusMenu specification"
 401                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 402             )
 403         endif()
 404
 405         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 406             set(HAVE_WEBKIT true)
 407         endif()
 408         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 409
 410         if (WITH_KDE)
 411             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 412             set(_cflags ${CMAKE_C_FLAGS})
 413             find_package(KDE4 4.4 QUIET)
 414             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 415                 URL "http://www.kde.org"
 416                 DESCRIPTION "a world-class desktop environment"
 417                 PURPOSE "Enables various bits for improving integration with KDE"
 418             )
 419             set(CMAKE_C_FLAGS ${_cflags})
 420
 421         else()
 422             find_package(Phonon QUIET)
 423             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 424                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 425                 DESCRIPTION "a multimedia abstraction library"
 426                 PURPOSE     "Required for audio notifications"
 427             )
 428         endif()
 429
 430         find_package(IndicateQt QUIET)
 431         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 432             URL "https://launchpad.net/libindicate-qt/"
 433             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 434             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 435         )
 436
 437     endif()
 438
 439     if (BUILD_CORE)
 440
 441         find_package(QCA2 QUIET)
 442         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 443             URL "https://projects.kde.org/projects/kdesupport/qca"
 444             DESCRIPTION "Qt Cryptographic Architecture"
 445             PURPOSE     "Required for encryption support"
 446         )
 447
 448
 449     endif()
 450
 451     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 452     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 453     if (QT_LRELEASE_EXECUTABLE)
 454         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 455         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 456     endif()
 457 endif()
 458
 459
 460 # Non-Qt-based packages
 461
 462 # zlib for compression, however we can always fall back to miniz
 463 find_package(ZLIB QUIET)
 464 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 465     URL "http://www.zlib.net"
 466     DESCRIPTION "a popular compression library"
 467     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 468 )
 469
 470
 471 if (NOT WIN32)
 472     # Execinfo is needed for generating backtraces
 473     find_package(ExecInfo QUIET)
 474     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 475         DESCRIPTION "a library for inspecting backtraces"
 476         PURPOSE "Used for generating backtraces in case of a crash"
 477     )
 478 endif()
 479
 480 # Check for SSL support in Qt
 481 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 482 # a small test program checking the defines. This works for both Qt4 and Qt5.
 483 cmake_push_check_state(RESET)
 484 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 485 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 486
 487 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 488     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 489 endif()
 490
 491 check_cxx_source_compiles("
 492     #include \"qglobal.h\"
 493     #if defined QT_NO_SSL
 494     #  error \"No SSL support\"
 495     #endif
 496     int main() {}"
 497     HAVE_SSL)
 498 cmake_pop_check_state()
 499
 500 # Additional compile settings
 501 #####################################################################
 502
 503 # This sets -fPIC and friends if required by the installed Qt5 library
 504 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 505     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 506 endif()
 507
 508 # Needed to compile with mingw without kde
 509 if (MINGW AND NOT KDE4_FOUND)
 510     add_definitions(-D_WIN32_WINNT=0x0500)
 511     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 512     # workaround for bug in mingw gcc 4.0
 513     add_definitions(-U__STRICT_ANSI__)
 514 endif()
 515
 516 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 517 if (CMAKE_COMPILER_IS_GNUCXX)
 518     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 519 endif()
 520
 521 # Setup LDAP Authentication support.
 522 #####################################################################
 523 if(WITH_LDAP)
 524     find_package(Ldap)
 525     if(LDAP_FOUND)
 526         message(STATUS "Enabling LDAP authentication support")
 527         set(HAVE_LDAP true)
 528         if(HAVE_LDAP)
 529             add_definitions(-DHAVE_LDAP)
 530         endif(HAVE_LDAP)
 531     else(LDAP_FOUND)
 532         message(STATUS "Disabling LDAP authentication support")
 533     endif(LDAP_FOUND)
 534 else(WITH_LDAP)
 535     message(STATUS "Not enabling LDAP authentication support")
 536 endif(WITH_LDAP)
 537
 538 # Setup KDE / KDE Frameworks
 539 #####################################################################
 540
 541 # We want to do this up here, so we have the necessary variables and defines set before
 542 # compiling anything
 543
 544 if (KDE4_FOUND)
 545     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 546     set(EMBED_DATA OFF)
 547
 548     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 549     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 550     set(WITH_KDE4 TRUE)
 551 endif()
 552
 553 if (USE_QT5 AND WITH_KDE)
 554     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 555     set(EMBED_DATA OFF)
 556
 557     include(KDEInstallDirs)
 558     include(KDECompilerSettings)
 559     include(KDECMakeSettings)
 560
 561     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 562     set(WITH_KF5 TRUE)
 563 endif()
 564
 565 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 566 include(QuasselInstallDirs)
 567
 568 # Various config-dependent checks and settings
 569 #####################################################################
 570
 571 if (NOT ZLIB_FOUND)
 572     message(STATUS "zlib NOT found, using bundled miniz for compression")
 573     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 574         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 575     endif()
 576 endif()
 577
 578 if (HAVE_SSL)
 579     add_definitions(-DHAVE_SSL)
 580 endif()
 581 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 582
 583 # Check for syslog support
 584 if (NOT WIN32)
 585     check_include_file(syslog.h HAVE_SYSLOG)
 586     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 587 endif()
 588
 589 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 590
 591 if (EMBED_DATA)
 592     message(STATUS "Embedding data files into the binary")
 593 else()
 594     message(STATUS "Installing data files separately")
 595 endif()
 596
 597 if (INDICATEQT_FOUND)
 598     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 599 endif()
 600
 601 if (NOT WIN32)
 602     check_function_exists(umask HAVE_UMASK)
 603     if(HAVE_UMASK)
 604         add_definitions(-DHAVE_UMASK)
 605     endif()
 606 endif()
 607
 608
 609 # Windows-specific stuff
 610 #####################################################################
 611
 612 if (WIN32)
 613     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 614     if (MSVC)
 615         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 616         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 617         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 618         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 619         link_libraries(Version dwmapi shlwapi)
 620         if (USE_QT5)
 621             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 622         endif()
 623     endif()
 624     if(HAVE_SSL AND STATIC)
 625         find_package(OpenSSL REQUIRED)
 626         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 627     endif()
 628 endif()
 629
 630
 631 # Static builds (very much non-portable, so don't use -DSTATIC
 632 # unless you know what you do!)
 633 #####################################################################
 634
 635 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 636     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 637     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 638     if (HAVE_SSL)
 639         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 640     endif()
 641 endif()
 642
 643
 644 # Generate version information from Git
 645 #####################################################################
 646
 647 include(GetGitRevisionDescription)
 648 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 649 git_describe(GIT_DESCRIBE --long)
 650
 651 # If in a Git repo we can get the commit-date from a git command
 652 if (GIT_HEAD)
 653     execute_process(
 654         COMMAND git show -s --format=%ct
 655         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 656         OUTPUT_VARIABLE GIT_COMMIT_DATE
 657         OUTPUT_STRIP_TRAILING_WHITESPACE
 658     )
 659 endif()
 660
 661 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 662 # enviroment
 663 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 664   if (DEFINED ENV{GIT_HEAD})
 665       set(GIT_HEAD $ENV{GIT_HEAD})
 666   endif()
 667   if (DEFINED ENV{GIT_DESCRIBE})
 668      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 669   endif()
 670 endif()
 671
 672 # Sanitize things if we're not in a Git repo
 673 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 674     set(GIT_HEAD "")
 675     set(GIT_DESCRIBE "")
 676     set(GIT_COMMIT_DATE 0)
 677 endif()
 678
 679 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 680
 681 # Prepare the build
 682 #####################################################################
 683
 684 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 685 set(COMMON_DEPS ${RC_WIN32})
 686 set(CORE_DEPS )
 687 set(CLIENT_DEPS )
 688
 689 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 690 add_subdirectory(data)
 691 add_subdirectory(icons)
 692 add_subdirectory(pics)
 693 add_subdirectory(po)
 694
 695
 696 # Set up and display feature summary
 697 #####################################################################
 698
 699 feature_summary(WHAT ALL
 700                 INCLUDE_QUIET_PACKAGES
 701                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 702 )
 703
 704 # Finally, compile the sources
 705 # We want this after displaying the feature summary to avoid ugly
 706 # CMake backtraces in case a required Qt5 module is missing
 707 #####################################################################
 708
 709 add_subdirectory(src)