CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 12)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.12-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
  38 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
  39 if (CMAKE_MAJOR_VERSION GREATER 2)
  40     cmake_policy(SET CMP0043 OLD)
  41 endif()
  42
  43 # Options and variables that can be set on the command line
  44 #####################################################################
  45
  46 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  47 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  48 if (USE_QT4) # takes precedence
  49     set(USE_QT5 OFF)
  50 else()
  51     if (NOT USE_QT5)
  52         set(USE_QT4 ON)
  53     endif()
  54 endif()
  55
  56 # Select the binaries to build
  57 option(WANT_CORE     "Build the core (server) binary"           ON)
  58 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  59 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  60 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  61 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  62 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  63
  64 # Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
  65 cmake_dependent_option(WITH_KDE "KDE4 integration" OFF "USE_QT4" OFF)
  66 add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  67
  68 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  69 if (NOT WITH_KDE)
  70     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  71 endif()
  72
  73 # For this, the feature info is added after we know if QtWebkit is installed
  74 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  75
  76 if (APPLE)
  77     # Notification Center is only available in > 10.8, which is Darwin v12
  78     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  79         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  80         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  81     endif()
  82 endif()
  83
  84 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  85 set(EMBED_DEFAULT OFF)
  86 if (STATIC OR WIN32 OR APPLE)
  87     set(EMBED_DEFAULT ON)
  88 endif()
  89 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  90                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  91 if (NOT EMBED_DEFAULT)
  92     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  93 endif()
  94
  95 # The following options are not for end-user consumption, so don't list them in the feature summary
  96 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  97
  98 # Handle with care
  99 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 100
 101 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 102 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 103
 104 # For static builds, arbitrary extra libs might need to be linked
 105 # Define a comma-separated list here
 106 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 107 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 108 if (LINK_EXTRA)
 109     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 110     link_libraries(${LINK_EXTRA})
 111 endif()
 112
 113
 114 # Simplify later checks
 115 #####################################################################
 116
 117 if (WANT_MONO OR WANT_QTCLIENT)
 118     set(BUILD_GUI true)
 119 endif()
 120 if (WANT_MONO OR WANT_CORE)
 121     set(BUILD_CORE true)
 122 endif()
 123
 124
 125 # Set up Qt
 126 #####################################################################
 127
 128 if (USE_QT5)
 129     message(STATUS "Building for Qt5...")
 130     set(QT_MIN_VERSION "5.2.0")
 131     add_definitions(-DHAVE_QT5)
 132 else()
 133     message(STATUS "Building for Qt4...")
 134     if (BUILD_GUI)
 135         set(QT_MIN_VERSION "4.6.0")
 136     else()
 137         set(QT_MIN_VERSION "4.4.0")
 138     endif()
 139
 140     # Select a Qt installation here, if you don't want to use system Qt
 141     if(QT_PATH)
 142         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 143         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 144     endif()
 145 endif()
 146
 147 # Find package dependencies
 148 #
 149 # Note that you can forcefully disable optional packages
 150 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 151 #####################################################################
 152
 153 if (USE_QT5)
 154     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 155     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 156         URL "http://qt.digia.com"
 157         DESCRIPTION "contains core functionality for Qt"
 158     )
 159     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 160     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 161     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 162         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 163     endif()
 164
 165     find_package(Qt5Network QUIET)
 166     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 167         DESCRIPTION "the network module for Qt5"
 168     )
 169
 170     if (BUILD_GUI)
 171         find_package(Qt5Gui QUIET)
 172         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 173             DESCRIPTION "the GUI module for Qt5"
 174         )
 175         find_package(Qt5Widgets QUIET)
 176         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 177             DESCRIPTION "the widgets module for Qt5"
 178         )
 179
 180         find_package(Qt5DBus QUIET)
 181         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 182             URL "http://qt.digia.com"
 183             DESCRIPTION "D-Bus support for Qt5"
 184             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 185         )
 186         if (Qt5DBus_FOUND)
 187             find_package(dbusmenu-qt5 QUIET CONFIG)
 188             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 189                 URL "https://launchpad.net/libdbusmenu-qt"
 190                 DESCRIPTION "a library implementing the DBusMenu specification"
 191                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 192             )
 193         endif()
 194
 195         find_package(Phonon4Qt5 QUIET)
 196         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 197             URL "https://projects.kde.org/projects/kdesupport/phonon"
 198             DESCRIPTION "a multimedia abstraction library"
 199             PURPOSE     "Required for audio notifications"
 200         )
 201
 202         find_package(LibsnoreQt5 QUIET)
 203         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 204             URL "https://github.com/TheOneRing/Snorenotify"
 205             DESCRIPTION "a cross-platform notification framework"
 206             PURPOSE     "Enable support for the snorenotify framework"
 207         )
 208
 209         if (WITH_WEBKIT)
 210             find_package(Qt5WebKit QUIET)
 211             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 212                 URL "http://qt.digia.com"
 213                 DESCRIPTION "a WebKit implementation for Qt"
 214                 PURPOSE     "Needed for displaying previews for URLs in chat"
 215             )
 216             if (Qt5WebKit_FOUND)
 217                 find_package(Qt5WebKitWidgets QUIET)
 218                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 219                     URL "http://qt.digia.com"
 220                     DESCRIPTION "widgets for Qt's WebKit implementation"
 221                     PURPOSE     "Needed for displaying previews for URLs in chat"
 222                 )
 223             endif()
 224         endif()
 225         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 226
 227     endif(BUILD_GUI)
 228     if (BUILD_CORE)
 229         find_package(Qt5Script QUIET)
 230         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 231             DESCRIPTION "provides scripting support for Qt5"
 232         )
 233         find_package(Qt5Sql QUIET)
 234         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 235             DESCRIPTION "the database support module for Qt5"
 236         )
 237
 238         find_package(QCA2-QT5)
 239         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 240             URL "https://projects.kde.org/projects/kdesupport/qca"
 241             DESCRIPTION "Qt Cryptographic Architecture"
 242             PURPOSE "Required for encryption support"
 243         )
 244
 245     endif(BUILD_CORE)
 246
 247     find_package(Qt5LinguistTools QUIET)
 248     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 249                            DESCRIPTION "contains tools for handling translation files"
 250                            PURPOSE "Required for having translations"
 251     )
 252     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 253     if (Qt5LinguistTools_FOUND)
 254         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 255             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 256             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 257             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 258         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 259             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 260             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 261         endif()
 262
 263         # Compatibility with the Qt4 variables
 264         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 265         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 266         if (Qt5_LCONVERT_EXECUTABLE)
 267             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 268         endif()
 269     endif()
 270
 271 else(USE_QT5)
 272     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 273
 274     if (BUILD_GUI)
 275         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 276         if (QT_QTDBUS_FOUND)
 277             find_package(dbusmenu-qt QUIET CONFIG)
 278             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 279                 URL "https://launchpad.net/libdbusmenu-qt"
 280                 DESCRIPTION "a library implementing the DBusMenu specification"
 281                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 282             )
 283         endif()
 284
 285         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 286             set(HAVE_WEBKIT true)
 287         endif()
 288         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 289
 290         if (WITH_KDE)
 291             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 292             set(_cflags ${CMAKE_C_FLAGS})
 293             find_package(KDE4 4.4 QUIET)
 294             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 295                 URL "http://www.kde.org"
 296                 DESCRIPTION "a world-class desktop environment"
 297                 PURPOSE "Enables various bits for improving integration with KDE"
 298             )
 299             set(CMAKE_C_FLAGS ${_cflags})
 300
 301         else(WITH_KDE)
 302             find_package(Phonon QUIET)
 303             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 304                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 305                 DESCRIPTION "a multimedia abstraction library"
 306                 PURPOSE     "Required for audio notifications"
 307             )
 308
 309             find_package(Libsnore QUIET)
 310             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 311                 URL "https://github.com/TheOneRing/Snorenotify"
 312                 DESCRIPTION "a cross-platform notification framework"
 313                 PURPOSE     "Enable support for the snorenotify framework"
 314             )
 315         endif(WITH_KDE)
 316
 317         find_package(IndicateQt QUIET)
 318         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 319             URL "https://launchpad.net/libindicate-qt/"
 320             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 321             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 322         )
 323
 324     endif(BUILD_GUI)
 325     if (BUILD_CORE)
 326
 327         find_package(QCA2 QUIET)
 328         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 329             URL "https://projects.kde.org/projects/kdesupport/qca"
 330             DESCRIPTION "Qt Cryptographic Architecture"
 331             PURPOSE     "Required for encryption support"
 332         )
 333
 334
 335     endif()
 336
 337     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 338     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 339     if (QT_LRELEASE_EXECUTABLE)
 340         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 341         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 342     endif()
 343 endif()
 344
 345
 346 # Non-Qt-based packages
 347
 348 # zlib for compression, however we can always fall back to miniz
 349 find_package(ZLIB QUIET)
 350 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 351     URL "http://www.zlib.net"
 352     DESCRIPTION "a popular compression library"
 353     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 354 )
 355
 356
 357 if (NOT WIN32)
 358     # Execinfo is needed for generating backtraces
 359     find_package(ExecInfo QUIET)
 360     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 361         DESCRIPTION "a library for inspecting backtraces"
 362         PURPOSE "Used for generating backtraces in case of a crash"
 363     )
 364 endif()
 365
 366
 367 # Various checks
 368 #####################################################################
 369
 370 if (NOT ZLIB_FOUND)
 371     message(STATUS "zlib NOT found, using bundled miniz for compression")
 372     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 373         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 374     endif()
 375 endif()
 376
 377 if (KDE4_FOUND)
 378     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 379     set(EMBED_DATA OFF)
 380
 381     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 382     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 383 endif()
 384
 385 # Check for SSL support in Qt
 386 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 387 # a small test program checking the defines. This works for both Qt4 and Qt5.
 388 cmake_push_check_state(RESET)
 389 if (Qt5_POSITION_INDEPENDENT_CODE)
 390     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 391 endif()
 392 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 393 check_cxx_source_compiles("
 394     #include \"qglobal.h\"
 395     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 396     #  error \"No SSL support\"
 397     #endif
 398     int main() {}"
 399     HAVE_SSL)
 400 cmake_pop_check_state()
 401
 402 if (HAVE_SSL)
 403     add_definitions(-DHAVE_SSL)
 404 endif()
 405 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 406
 407 # Check for syslog support
 408 if (NOT WIN32)
 409     check_include_file(syslog.h HAVE_SYSLOG)
 410     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 411 endif()
 412
 413 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 414
 415 # Various settings
 416 ##################
 417
 418 # needed to compile with mingw without kde
 419 if (MINGW AND NOT KDE4_FOUND)
 420     add_definitions(-D_WIN32_WINNT=0x0500)
 421     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 422 # workaround for bug in mingw gcc 4.0
 423     add_definitions(-U__STRICT_ANSI__)
 424 endif()
 425
 426 # Now set up install locations; those are set by KDE if integration is enabled
 427 if(NOT KDE4_FOUND)
 428   if(WIN32)
 429     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 430     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 431     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 432     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 433   else(WIN32)
 434     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 435     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 436     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 437     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 438   endif(WIN32)
 439 endif()
 440
 441 if(EMBED_DATA)
 442   message(STATUS "Embedding data files into the binary")
 443 else(EMBED_DATA)
 444   message(STATUS "Installing data files separately")
 445 endif(EMBED_DATA)
 446
 447 # RPATH needs to be set correctly
 448 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 449 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 450 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 451
 452 # Set global buildflags
 453 # This is very much non-portable, so don't use -DSTATIC until you know what
 454 # you do.
 455 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 456   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 457   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 458   if(HAVE_SSL)
 459     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 460   endif(HAVE_SSL)
 461 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 462
 463 if(WIN32)
 464   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 465   if(MSVC)
 466     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 467     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 468     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 469     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 470     link_libraries(Version dwmapi shlwapi)
 471     if(USE_QT5)
 472       set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 473     endif(USE_QT5)
 474   endif(MSVC)
 475   if(HAVE_SSL AND STATIC)
 476      find_package(OpenSSL REQUIRED)
 477      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 478   endif(HAVE_SSL AND STATIC)
 479 endif(WIN32)
 480
 481 if(INDICATEQT_FOUND)
 482   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 483 endif()
 484
 485 if(NOT WIN32)
 486   check_function_exists(umask HAVE_UMASK)
 487   if(HAVE_UMASK)
 488     add_definitions(-DHAVE_UMASK)
 489   endif(HAVE_UMASK)
 490 endif(NOT WIN32)
 491
 492 # Generate version information from Git
 493 include(GetGitRevisionDescription)
 494 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 495 git_describe(GIT_DESCRIBE --long)
 496
 497 # Sanitize things if we're not in a Git repo
 498 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 499     set(GIT_HEAD "")
 500     set(GIT_DESCRIBE "")
 501 endif()
 502
 503 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 504
 505 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 506 set(COMMON_DEPS ${RC_WIN32})
 507 set(CORE_DEPS )
 508 set(CLIENT_DEPS )
 509
 510 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 511 add_subdirectory(data)
 512 add_subdirectory(icons)
 513 add_subdirectory(pics)
 514 add_subdirectory(po)
 515
 516 # Set up and display feature summary
 517 #####################################################################
 518
 519 feature_summary(WHAT ALL
 520                 INCLUDE_QUIET_PACKAGES
 521                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 522 )
 523
 524 # Finally, compile the sources
 525 # We want this after displaying the feature summary to avoid ugly
 526 # CMake backtraces in case a required Qt5 modules misses
 527 #####################################################################
 528
 529 add_subdirectory(src)