CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)  # You'll need at least 2.8.12 for KDE Frameworks integration
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 12)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.12-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
  38 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
  39 if (CMAKE_MAJOR_VERSION GREATER 2)
  40     cmake_policy(SET CMP0043 OLD)
  41 endif()
  42
  43 # Options and variables that can be set on the command line
  44 #####################################################################
  45
  46 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  47 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  48 if (USE_QT4) # takes precedence
  49     set(USE_QT5 OFF)
  50 else()
  51     if (NOT USE_QT5)
  52         set(USE_QT4 ON)
  53     endif()
  54 endif()
  55
  56 # Select the binaries to build
  57 option(WANT_CORE     "Build the core (server) binary"           ON)
  58 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  59 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  60 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  61 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  62 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  63
  64 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  65 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  66 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  67 # is disabled.
  68 if (USE_QT4)
  69     option(WITH_KDE "KDE4 integration" OFF)
  70     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  71 else()
  72     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  73     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  74 endif()
  75
  76 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  77 if (NOT WITH_KDE)
  78     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  79 endif()
  80
  81 # For this, the feature info is added after we know if QtWebkit is installed
  82 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  83
  84 if (APPLE)
  85     # Notification Center is only available in > 10.8, which is Darwin v12
  86     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  87         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  88         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  89     endif()
  90 endif()
  91
  92 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  93 set(EMBED_DEFAULT OFF)
  94 if (STATIC OR WIN32 OR APPLE)
  95     set(EMBED_DEFAULT ON)
  96 endif()
  97 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  98                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  99 if (NOT EMBED_DEFAULT)
 100     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 101 endif()
 102
 103 # The following options are not for end-user consumption, so don't list them in the feature summary
 104 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 105
 106 # Handle with care
 107 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 108
 109 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 110 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 111
 112 # For static builds, arbitrary extra libs might need to be linked
 113 # Define a comma-separated list here
 114 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 115 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 116 if (LINK_EXTRA)
 117     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 118     link_libraries(${LINK_EXTRA})
 119 endif()
 120
 121
 122 # Simplify later checks
 123 #####################################################################
 124
 125 if (WANT_MONO OR WANT_QTCLIENT)
 126     set(BUILD_GUI true)
 127 endif()
 128 if (WANT_MONO OR WANT_CORE)
 129     set(BUILD_CORE true)
 130 endif()
 131
 132
 133 # Set up Qt
 134 #####################################################################
 135
 136 if (USE_QT5)
 137     message(STATUS "Building for Qt5...")
 138     set(QT_MIN_VERSION "5.2.0")
 139     add_definitions(-DHAVE_QT5)
 140 else()
 141     message(STATUS "Building for Qt4...")
 142     set(QT_MIN_VERSION "4.8.0")
 143
 144     # Select a Qt installation here, if you don't want to use system Qt
 145     if(QT_PATH)
 146         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 147         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 148     endif()
 149 endif()
 150
 151
 152 # Find package dependencies
 153 #
 154 # Note that you can forcefully disable optional packages
 155 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 156 #####################################################################
 157
 158 if (USE_QT5)
 159     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 160     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 161         URL "http://qt.digia.com"
 162         DESCRIPTION "contains core functionality for Qt"
 163     )
 164     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 165     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 166     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 167         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 168     endif()
 169
 170     find_package(Qt5Network QUIET)
 171     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 172         DESCRIPTION "the network module for Qt5"
 173     )
 174
 175     if (BUILD_GUI)
 176         find_package(Qt5Gui QUIET)
 177         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 178             DESCRIPTION "the GUI module for Qt5"
 179         )
 180         find_package(Qt5Widgets QUIET)
 181         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 182             DESCRIPTION "the widgets module for Qt5"
 183         )
 184
 185         find_package(Qt5DBus QUIET)
 186         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 187             URL "http://qt.digia.com"
 188             DESCRIPTION "D-Bus support for Qt5"
 189             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 190         )
 191         if (Qt5DBus_FOUND)
 192             find_package(dbusmenu-qt5 QUIET CONFIG)
 193             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 194                 URL "https://launchpad.net/libdbusmenu-qt"
 195                 DESCRIPTION "a library implementing the DBusMenu specification"
 196                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 197             )
 198         endif()
 199
 200         find_package(Phonon4Qt5 QUIET)
 201         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 202             URL "https://projects.kde.org/projects/kdesupport/phonon"
 203             DESCRIPTION "a multimedia abstraction library"
 204             PURPOSE     "Required for audio notifications"
 205         )
 206
 207         find_package(LibsnoreQt5 QUIET)
 208         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 209             URL "https://github.com/TheOneRing/Snorenotify"
 210             DESCRIPTION "a cross-platform notification framework"
 211             PURPOSE     "Enable support for the snorenotify framework"
 212         )
 213
 214         if (WITH_WEBKIT)
 215             find_package(Qt5WebKit QUIET)
 216             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 217                 URL "http://qt.digia.com"
 218                 DESCRIPTION "a WebKit implementation for Qt"
 219                 PURPOSE     "Needed for displaying previews for URLs in chat"
 220             )
 221             if (Qt5WebKit_FOUND)
 222                 find_package(Qt5WebKitWidgets QUIET)
 223                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 224                     URL "http://qt.digia.com"
 225                     DESCRIPTION "widgets for Qt's WebKit implementation"
 226                     PURPOSE     "Needed for displaying previews for URLs in chat"
 227                 )
 228             endif()
 229         endif()
 230         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 231
 232         # KDE Frameworks
 233         ################
 234
 235         if (WITH_KDE)
 236             set(ecm_find_type "REQUIRED")
 237         else()
 238             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 239             set(ecm_find_type "RECOMMENDED")
 240         endif()
 241
 242         # extra-cmake-modules
 243         find_package(ECM NO_MODULE QUIET)
 244         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 245             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 246             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 247             PURPOSE     "Required to find KDE Frameworks components"
 248         )
 249
 250         if (ECM_FOUND)
 251             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 252         endif()
 253
 254         if (WITH_KDE)
 255             find_package(KF5CoreAddons QUIET)
 256             set_package_properties(KF5CoreAddons PROPERTIES TYPE REQUIRED
 257                 URL "http://inqlude.org/libraries/kcoreaddons.html"
 258                 DESCRIPTION "framework for solving common problems such as caching, randomization, and more"
 259                 PURPOSE     "Required for KDE Frameworks integration"
 260             )
 261
 262             find_package(KF5TextWidgets QUIET)
 263             set_package_properties(KF5TextWidgets PROPERTIES TYPE REQUIRED
 264                 URL "http://inqlude.org/libraries/ktextwidgets.html"
 265                 DESCRIPTION "framework providing an assortment of widgets for displaying and editing text"
 266                 PURPOSE     "Allows to use extra features provided by KDE Frameworks in input widgets"
 267             )
 268
 269         endif()
 270
 271     endif(BUILD_GUI)
 272     if (BUILD_CORE)
 273         find_package(Qt5Script QUIET)
 274         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 275             DESCRIPTION "provides scripting support for Qt5"
 276         )
 277         find_package(Qt5Sql QUIET)
 278         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 279             DESCRIPTION "the database support module for Qt5"
 280         )
 281
 282         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 283         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 284         #find_package(QCA2 QUIET)
 285         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 286         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 287         #    DESCRIPTION "Qt Cryptographic Architecture"
 288         #    PURPOSE "Required for encryption support"
 289         #)
 290
 291     endif(BUILD_CORE)
 292
 293     find_package(Qt5LinguistTools QUIET)
 294     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 295                            DESCRIPTION "contains tools for handling translation files"
 296                            PURPOSE "Required for having translations"
 297     )
 298     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 299     if (Qt5LinguistTools_FOUND)
 300         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 301             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 302             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 303             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 304         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 305             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 306             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 307         endif()
 308
 309         # Compatibility with the Qt4 variables
 310         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 311         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 312         if (Qt5_LCONVERT_EXECUTABLE)
 313             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 314         endif()
 315     endif()
 316
 317 else(USE_QT5)
 318     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 319
 320     if (BUILD_GUI)
 321         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 322         if (QT_QTDBUS_FOUND)
 323             find_package(dbusmenu-qt QUIET CONFIG)
 324             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 325                 URL "https://launchpad.net/libdbusmenu-qt"
 326                 DESCRIPTION "a library implementing the DBusMenu specification"
 327                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 328             )
 329         endif()
 330
 331         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 332             set(HAVE_WEBKIT true)
 333         endif()
 334         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 335
 336         if (WITH_KDE)
 337             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 338             set(_cflags ${CMAKE_C_FLAGS})
 339             find_package(KDE4 4.4 QUIET)
 340             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 341                 URL "http://www.kde.org"
 342                 DESCRIPTION "a world-class desktop environment"
 343                 PURPOSE "Enables various bits for improving integration with KDE"
 344             )
 345             set(CMAKE_C_FLAGS ${_cflags})
 346
 347         else(WITH_KDE)
 348             find_package(Phonon QUIET)
 349             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 350                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 351                 DESCRIPTION "a multimedia abstraction library"
 352                 PURPOSE     "Required for audio notifications"
 353             )
 354
 355             find_package(Libsnore QUIET)
 356             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 357                 URL "https://github.com/TheOneRing/Snorenotify"
 358                 DESCRIPTION "a cross-platform notification framework"
 359                 PURPOSE     "Enable support for the snorenotify framework"
 360             )
 361         endif(WITH_KDE)
 362
 363         find_package(IndicateQt QUIET)
 364         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 365             URL "https://launchpad.net/libindicate-qt/"
 366             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 367             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 368         )
 369
 370     endif(BUILD_GUI)
 371
 372     if (BUILD_CORE)
 373
 374         find_package(QCA2 QUIET)
 375         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 376             URL "https://projects.kde.org/projects/kdesupport/qca"
 377             DESCRIPTION "Qt Cryptographic Architecture"
 378             PURPOSE     "Required for encryption support"
 379         )
 380
 381
 382     endif()
 383
 384     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 385     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 386     if (QT_LRELEASE_EXECUTABLE)
 387         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 388         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 389     endif()
 390 endif()
 391
 392
 393 # Non-Qt-based packages
 394
 395 # zlib for compression, however we can always fall back to miniz
 396 find_package(ZLIB QUIET)
 397 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 398     URL "http://www.zlib.net"
 399     DESCRIPTION "a popular compression library"
 400     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 401 )
 402
 403
 404 if (NOT WIN32)
 405     # Execinfo is needed for generating backtraces
 406     find_package(ExecInfo QUIET)
 407     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 408         DESCRIPTION "a library for inspecting backtraces"
 409         PURPOSE "Used for generating backtraces in case of a crash"
 410     )
 411 endif()
 412
 413
 414 # Additional compile settings
 415 #####################################################################
 416
 417 # This sets -fPIC and friends if required by the installed Qt5 library
 418 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 419     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 420 endif()
 421
 422 # Needed to compile with mingw without kde
 423 if (MINGW AND NOT KDE4_FOUND)
 424     add_definitions(-D_WIN32_WINNT=0x0500)
 425     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 426     # workaround for bug in mingw gcc 4.0
 427     add_definitions(-U__STRICT_ANSI__)
 428 endif()
 429
 430
 431 # Setup KDE / KDE Frameworks
 432 #####################################################################
 433
 434 # We want to do this up here, so we have the necessary variables and defines set before
 435 # compiling anything
 436
 437 if (KDE4_FOUND)
 438     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 439     set(EMBED_DATA OFF)
 440
 441     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 442     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 443     set(WITH_KDE4 TRUE)
 444 endif()
 445
 446 if (USE_QT5 AND WITH_KDE)
 447     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 448     set(EMBED_DATA OFF)
 449
 450     include(KDEInstallDirs)
 451     include(KDECompilerSettings)
 452     include(KDECMakeSettings)
 453
 454     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 455     set(WITH_KF5 TRUE)
 456 endif()
 457
 458 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 459 include(QuasselInstallDirs)
 460
 461 # Various config-dependent checks and settings
 462 #####################################################################
 463
 464 if (NOT ZLIB_FOUND)
 465     message(STATUS "zlib NOT found, using bundled miniz for compression")
 466     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 467         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 468     endif()
 469 endif()
 470
 471 # Check for SSL support in Qt
 472 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 473 # a small test program checking the defines. This works for both Qt4 and Qt5.
 474 cmake_push_check_state(RESET)
 475 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 476 check_cxx_source_compiles("
 477     #include \"qglobal.h\"
 478     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 479     #  error \"No SSL support\"
 480     #endif
 481     int main() {}"
 482     HAVE_SSL)
 483 cmake_pop_check_state()
 484
 485 if (HAVE_SSL)
 486     add_definitions(-DHAVE_SSL)
 487 endif()
 488 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 489
 490 # Check for syslog support
 491 if (NOT WIN32)
 492     check_include_file(syslog.h HAVE_SYSLOG)
 493     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 494 endif()
 495
 496 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 497
 498 if (EMBED_DATA)
 499     message(STATUS "Embedding data files into the binary")
 500 else()
 501     message(STATUS "Installing data files separately")
 502 endif()
 503
 504 if (INDICATEQT_FOUND)
 505     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 506 endif()
 507
 508 if (NOT WIN32)
 509     check_function_exists(umask HAVE_UMASK)
 510     if(HAVE_UMASK)
 511         add_definitions(-DHAVE_UMASK)
 512     endif(HAVE_UMASK)
 513 endif()
 514
 515
 516 # Windows-specific stuff
 517 #####################################################################
 518
 519 if (WIN32)
 520     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 521     if (MSVC)
 522         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 523         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 524         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 525         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 526         link_libraries(Version dwmapi shlwapi)
 527         if (USE_QT5)
 528             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 529         endif()
 530     endif()
 531     if(HAVE_SSL AND STATIC)
 532         find_package(OpenSSL REQUIRED)
 533         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 534     endif()
 535 endif()
 536
 537
 538 # Static builds (very much non-portable, so don't use -DSTATIC
 539 # unless you know what you do!)
 540 #####################################################################
 541
 542 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 543     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 544     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 545     if (HAVE_SSL)
 546         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 547     endif()
 548 endif()
 549
 550
 551 # Generate version information from Git
 552 #####################################################################
 553
 554 include(GetGitRevisionDescription)
 555 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 556 git_describe(GIT_DESCRIBE --long)
 557
 558 # Sanitize things if we're not in a Git repo
 559 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 560     set(GIT_HEAD "")
 561     set(GIT_DESCRIBE "")
 562 endif()
 563
 564 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 565
 566 # Prepare the build
 567 #####################################################################
 568
 569 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 570 set(COMMON_DEPS ${RC_WIN32})
 571 set(CORE_DEPS )
 572 set(CLIENT_DEPS )
 573
 574 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 575 add_subdirectory(data)
 576 add_subdirectory(icons)
 577 add_subdirectory(pics)
 578 add_subdirectory(po)
 579
 580
 581 # Set up and display feature summary
 582 #####################################################################
 583
 584 feature_summary(WHAT ALL
 585                 INCLUDE_QUIET_PACKAGES
 586                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 587 )
 588
 589 # Finally, compile the sources
 590 # We want this after displaying the feature summary to avoid ugly
 591 # CMake backtraces in case a required Qt5 module is missing
 592 #####################################################################
 593
 594 add_subdirectory(src)