CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 cmake_minimum_required(VERSION 2.8.9)
  29 project(QuasselIRC)
  30
  31 include(CheckFunctionExists)
  32 include(CheckIncludeFile)
  33 include(CheckCXXCompilerFlag)
  34
  35 # Use our own (well, and KDE's) version of some modules
  36 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  37 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  38 include(QuasselMacros)
  39
  40 # Various options and variables that can be set on the command line
  41 option(WANT_CORE     "Build the core (server) binary"           ON)
  42 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  43 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  44
  45 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  46 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  47 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  48 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  49 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  50 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  51 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  52 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  53
  54 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  55 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  56 # run on a matching KDE version only.
  57 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  58
  59 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  60 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  61
  62 option(STATIC        "Enable static building (might not be portable)" OFF)
  63
  64 if(APPLE)
  65   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  66   # Notification Center is only available in > 10.8, which is Darwin v12
  67   if(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  68     option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  69   endif(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  70 endif(APPLE)
  71
  72 # Default to embedding data in the static case
  73 if(STATIC OR WIN32)
  74   set(EMBED_DEFAULT ON)
  75 else(STATIC OR WIN32)
  76   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  77 endif(STATIC OR WIN32)
  78
  79 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  80
  81 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  82
  83 # Some settings imply others
  84 if(STATIC)
  85   add_definitions(-DSTATIC)
  86   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  87 endif(STATIC)
  88
  89 if(WIN32)
  90   # We don't support separately installed resources yet on Win32
  91   set(EMBED_DATA ON)
  92 endif(WIN32)
  93
  94 # For static builds, arbitrary extra libs might need to be linked
  95 # Define a comma-separated list here
  96 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
  97 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
  98 if(LINK_EXTRA)
  99   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 100   link_libraries(${LINK_EXTRA})
 101 endif(LINK_EXTRA)
 102
 103 # Build Types
 104
 105 if(CMAKE_CONFIGURATION_TYPES)
 106    set(CMAKE_CONFIGURATION_TYPES Release RelWithDebInfo Debug Debugfull Profile MinSizeRel)
 107    set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 108      "Reset the configurations to what we need"
 109      FORCE)
 110 endif()
 111
 112 if(NOT CMAKE_BUILD_TYPE)
 113   SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 114      "Choose the type of build, options are: None Debug Release RelWithDebInfo Debug Debugfull Profile MinSizeRel."
 115      FORCE)
 116 endif()
 117
 118 # Qt debug flags
 119 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 120 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUGFULL QT_DEBUG)
 121 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 122 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 123 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_PROFILE QT_NO_DEBUG NDEBUG)
 124 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 125
 126 if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 127   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 128 endif()
 129
 130 # Enable various flags on gcc
 131 if(CMAKE_COMPILER_IS_GNUCXX)
 132   # Let's just hope that all gccs support these options and skip the tests...
 133   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 134   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 135 #  set(CMAKE_CXX_FLAGS_RELEASE          "-O2")   # use CMake default
 136 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-g -O2")  # use CMake default
 137   set(CMAKE_CXX_FLAGS_DEBUG             "-g -ggdb -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 138   set(CMAKE_CXX_FLAGS_DEBUGFULL         "-g3 -ggdb -fno-inline")
 139   set(CMAKE_CXX_FLAGS_PROFILE           "-g3 -ggdb -fno-inline -ftest-coverage -fprofile-arcs")
 140
 141   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -W -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing -Wundef -Wcast-align -Wpointer-arith -Wformat-security -fno-check-new -fno-common")
 142
 143   check_cxx_compiler_flag(-Woverloaded-virtual CXX_W_OVERLOADED_VIRTUAL)
 144   if(CXX_W_OVERLOADED_VIRTUAL)
 145     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Woverloaded-virtual")
 146   endif()
 147
 148   # Just for miniz
 149   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-unused-function -Wno-undef -fno-strict-aliasing")
 150 endif(CMAKE_COMPILER_IS_GNUCXX)
 151
 152 # ... and for Clang
 153 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 154   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor -Wno-long-long -Wundef -Wcast-align -Wchar-subscripts -Wall -W -Wextra -Wpointer-arith -Wformat-security -Woverloaded-virtual -fno-common -Werror=return-type")
 155 #  set(CMAKE_CXX_FLAGS_RELEASE        "-O2 -DNDEBUG -DQT_NO_DEBUG")     # Use CMake default
 156 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g -DNDEBUG -DQT_NO_DEBUG")  # Use CMake default
 157   set(CMAKE_CXX_FLAGS_DEBUG          "-g -O2 -fno-inline")
 158   set(CMAKE_CXX_FLAGS_DEBUGFULL      "-g3 -fno-inline")
 159   set(CMAKE_CXX_FLAGS_PROFILE        "-g3 -fno-inline -ftest-coverage -fprofile-arcs")
 160
 161   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-unused-function -Wno-undef -fno-strict-aliasing")
 162 endif()
 163
 164 # Mac build stuff
 165 if(APPLE AND DEPLOY)
 166   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 167   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 168   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 169   add_definitions(-DMAC_10_6_SDK)
 170 endif(APPLE AND DEPLOY)
 171
 172 # Simplify checks
 173 if(WANT_MONO OR WANT_QTCLIENT)
 174   set(BUILD_GUI true)
 175 endif(WANT_MONO OR WANT_QTCLIENT)
 176 if(WANT_MONO OR WANT_CORE)
 177   set(BUILD_CORE true)
 178 endif(WANT_MONO OR WANT_CORE)
 179
 180
 181 # Version checks
 182 ################
 183
 184 if(WITH_QT5)
 185   set(QT_MIN_VERSION "5.0.0")
 186   add_definitions(-DHAVE_QT5)
 187
 188   # Qt5 needs a new enough cmake...
 189   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 190
 191   # ... for automoc
 192   set(CMAKE_AUTOMOC ON)
 193 else(WITH_QT5)
 194
 195   # GUI stuff needs some new features
 196   if(BUILD_GUI)
 197     set(QT_MIN_VERSION "4.6.0")
 198   else(BUILD_GUI)
 199     set(QT_MIN_VERSION "4.4.0")
 200   endif(BUILD_GUI)
 201 endif(WITH_QT5)
 202
 203
 204 # Dependencies
 205 ##############
 206
 207 if(WITH_QT5)
 208   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 209   # We need QtWidgets
 210   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 211
 212   # Setup the i18n-related variables
 213   find_package(Qt5LinguistTools)
 214
 215 else(WITH_QT5)
 216   # Select a Qt installation here, if you don't want to use system Qt
 217   if(QT)
 218     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 219     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 220   endif(QT)
 221
 222   # Now that we have the correct $PATH, lets find Qt!
 223   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 224 endif(WITH_QT5)
 225
 226
 227 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 228 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 229 if(QT_LRELEASE_EXECUTABLE)
 230   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 231   if(WITH_QT5)
 232     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 233   else(WITH_QT5)
 234     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 235   endif(WITH_QT5)
 236 endif(QT_LRELEASE_EXECUTABLE)
 237
 238
 239 # zlib for compression, however we can always fall back to miniz
 240 find_package(ZLIB)
 241 if(ZLIB_FOUND)
 242   message(STATUS "Using system zlib for compression")
 243   add_definitions(-DHAVE_ZLIB)
 244   include_directories(${ZLIB_INCLUDE_DIRS})
 245   set(COMMON_LIBRARIES ${COMMON_LIBRARIES} ${ZLIB_LIBRARIES})
 246 else()
 247   message(STATUS "zlib NOT found, using bundled miniz for compression")
 248   if(${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 249     message(STATUS "WARNING: This may be slow on 32 bit systems!")
 250   endif()
 251 endif()
 252
 253
 254 # Execinfo is needed for generating backtraces
 255 find_package(ExecInfo)
 256 if(EXECINFO_FOUND)
 257   add_definitions(-DHAVE_EXECINFO)
 258   include_directories(${EXECINFO_INCLUDES})
 259   link_libraries(${EXECINFO_LIBRARIES})
 260 endif(EXECINFO_FOUND)
 261
 262
 263 # PkgConfig isn't strictly required.
 264 # However, some optional deps might not be found if it's not present, so warn!
 265 find_package(PkgConfig)
 266 if(NOT PKG_CONFIG_FOUND)
 267   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 268   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 269 endif(NOT PKG_CONFIG_FOUND)
 270
 271
 272 # Setup OpenSSL
 273 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 274 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 275 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 276 if(WITH_OPENSSL)
 277   if(QT_QCONFIG MATCHES "openssl")
 278     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 279     add_definitions(-DHAVE_SSL)
 280     set(HAVE_SSL true)
 281   else(QT_QCONFIG MATCHES "openssl")
 282     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 283     add_definitions(-DQT_NO_OPENSSL)
 284   endif(QT_QCONFIG MATCHES "openssl")
 285 else(WITH_OPENSSL)
 286   message(STATUS "Not enabling OpenSSL support")
 287 endif(WITH_OPENSSL)
 288
 289
 290 # Check for GUI specific stuff
 291 if(BUILD_GUI)
 292
 293   # Setup D-Bus support
 294   if(WITH_DBUS)
 295     if(WITH_QT5)
 296       find_package(Qt5DBus ${QT_MIN_VERSION})
 297       find_package(Qt5DBusTools)
 298     endif(WITH_QT5)
 299
 300     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 301       message(STATUS "Found QtDBus, enabling D-Bus support")
 302       add_definitions(-DHAVE_DBUS)
 303       set(HAVE_DBUS true)
 304       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 305
 306       # check if we have dbusmenu as well
 307       if(NOT WITH_QT5)
 308         find_package(DBusMenuQt)
 309         if(DBUSMENUQT_FOUND)
 310           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 311           add_definitions(-DHAVE_DBUSMENU)
 312           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 313           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 314           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 315         else(DBUSMENUQT_FOUND)
 316           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 317         endif(DBUSMENUQT_FOUND)
 318       endif(NOT WITH_QT5)
 319
 320     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 321       message(STATUS "QtDBus not found, disabling D-Bus support")
 322     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 323   else(WITH_DBUS)
 324     message(STATUS "Not enabling D-Bus support")
 325   endif(WITH_DBUS)
 326
 327   # Setup QtWebkit support
 328   if(WITH_WEBKIT)
 329     if(WITH_QT5)
 330       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 331     endif(WITH_QT5)
 332     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 333       message(STATUS "Found QtWebKit, enabling WebKit support")
 334       add_definitions(-DHAVE_WEBKIT)
 335       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 336       set(HAVE_WEBKIT true)
 337     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 338       message(STATUS "QtWebkit not found, disabling Webkit support")
 339     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 340   else(WITH_WEBKIT)
 341     message(STATUS "Not enabling Webkit support")
 342   endif(WITH_WEBKIT)
 343
 344   # Setup KDE4 support
 345   if(WITH_KDE AND NOT WITH_QT5)
 346     # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 347     set(_cflags ${CMAKE_C_FLAGS})
 348     find_package(KDE4)
 349     if(KDE4_FOUND)
 350       message(STATUS "Enabling KDE4 integration")
 351       include_directories(${KDE4_INCLUDES})
 352       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 353       set(HAVE_KDE 1)
 354       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
 355       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 356       set(EMBED_DATA OFF)
 357       # Restore our old CFLAGS
 358       set(CMAKE_C_FLAGS ${_cflags})
 359     else(KDE4_FOUND)
 360       message(STATUS "KDE4 not found, disabling KDE integration")
 361     endif(KDE4_FOUND)
 362   else(WITH_KDE AND NOT WITH_QT5)
 363     message(STATUS "Not enabling KDE4 integration")
 364   endif(WITH_KDE AND NOT WITH_QT5)
 365
 366   # Setup Phonon support - we only need this if we don't have or want KDE4
 367   if(NOT HAVE_KDE)
 368     if(WITH_PHONON)
 369       if(WITH_QT5)
 370         find_package(Qt5phonon)
 371         if(Qt5phonon_FOUND)
 372           message(STATUS "Enabling Phonon support")
 373           add_definitions(-DHAVE_PHONON)
 374           set(HAVE_PHONON true)
 375           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 376         else(Qt5phonon_FOUND)
 377           message(STATUS "Phonon not found, disabling audio notifications")
 378         endif(Qt5phonon_FOUND)
 379       else(WITH_QT5)
 380         find_package(Phonon)
 381         if(PHONON_FOUND)
 382           message(STATUS "Enabling Phonon support")
 383           add_definitions(-DHAVE_PHONON)
 384           include_directories(${PHONON_INCLUDES})
 385           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 386           set(HAVE_PHONON true)
 387         else(PHONON_FOUND)
 388           message(STATUS "Phonon not found, disabling audio notifications")
 389         endif(PHONON_FOUND)
 390       endif(WITH_QT5)
 391     else(WITH_PHONON)
 392       message(STATUS "Not enabling Phonon support")
 393     endif(WITH_PHONON)
 394
 395     find_package(Libsnore)
 396     if(LIBSNORE_FOUND)
 397         add_definitions(-DHAVE_LIBSNORE)
 398         set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
 399         set(HAVE_SNORENOTIFY true)
 400     endif(LIBSNORE_FOUND)
 401   endif(NOT HAVE_KDE)
 402
 403   # Setup libindicate-qt support
 404   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 405     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 406     if(INDICATEQT_FOUND)
 407       message(STATUS "Enabling Ayatana notification support")
 408       set(HAVE_INDICATEQT true)
 409       add_definitions(-DHAVE_INDICATEQT)
 410       link_directories(${INDICATEQT_LIBRARY_DIRS})
 411       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 412     else(INDICATEQT_FOUND)
 413       message(STATUS "Disabling Ayatana notification support")
 414     endif(INDICATEQT_FOUND)
 415   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 416     message(STATUS "Not enabling Ayatana notification support")
 417     # We don't want to link against it even if another package has found it
 418     set(INDICATEQT_LIBRARIES "")
 419   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 420
 421   # Setup OS X notification center support
 422   if(WITH_NOTIFICATION_CENTER AND APPLE)
 423     set(HAVE_NOTIFICATION_CENTER true)
 424     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 425     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 426       /System/Library/Frameworks/Foundation.framework
 427     )
 428   endif()
 429 endif(BUILD_GUI)
 430
 431 # Core-only deps
 432 if(BUILD_CORE)
 433
 434   # Setup encryption support
 435   if(WITH_CRYPT AND NOT WITH_QT5)
 436     find_package(QCA2)
 437     if(QCA2_FOUND)
 438       message(STATUS "Enabling encryption support")
 439       add_definitions(-DHAVE_QCA2)
 440       set(LINK_QCA2 QCA2)
 441       set(HAVE_QCA2 true)
 442       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 443     else(QCA2_FOUND)
 444       message(STATUS "Disabling encryption support")
 445     endif(QCA2_FOUND)
 446   else(WITH_CRYPT AND NOT WITH_QT5)
 447     message(STATUS "Not enabling encryption support")
 448   endif(WITH_CRYPT AND NOT WITH_QT5)
 449
 450   # Setup syslog support
 451   if(WITH_SYSLOG)
 452     check_include_file(syslog.h HAVE_SYSLOG_H)
 453     if(HAVE_SYSLOG_H)
 454       message(STATUS "Enabling syslog support")
 455       set(HAVE_SYSLOG true)
 456       add_definitions(-DHAVE_SYSLOG)
 457     else(HAVE_SYSLOG_H)
 458       message(STATUS "Disabling syslog support")
 459     endif(HAVE_SYSLOG_H)
 460   else(WITH_SYSLOG)
 461     message(STATUS "Not enabling syslog support")
 462   endif(WITH_SYSLOG)
 463
 464 endif(BUILD_CORE)
 465
 466
 467 # Various settings
 468 ##################
 469
 470 # needed to compile with mingw without kde
 471 if(MINGW AND NOT HAVE_KDE)
 472     add_definitions(-D_WIN32_WINNT=0x0500)
 473     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 474 # workaround for bug in mingw gcc 4.0
 475     add_definitions(-U__STRICT_ANSI__)
 476 endif(MINGW AND NOT HAVE_KDE)
 477
 478 # Now set up install locations; those are set by KDE if integration is enabled
 479 if(NOT HAVE_KDE)
 480   if(WIN32)
 481     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 482     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 483     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 484     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 485   else(WIN32)
 486     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 487     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 488     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 489     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 490   endif(WIN32)
 491 endif(NOT HAVE_KDE)
 492
 493 if(EMBED_DATA)
 494   message(STATUS "Embedding data files into the binary")
 495 else(EMBED_DATA)
 496   message(STATUS "Installing data files separately")
 497 endif(EMBED_DATA)
 498
 499 # RPATH needs to be set correctly
 500 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 501 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 502 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 503
 504 # Set global buildflags
 505 # This is very much non-portable, so don't use -DSTATIC until you know what
 506 # you do.
 507 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 508   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 509   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 510   if(HAVE_SSL)
 511     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 512   endif(HAVE_SSL)
 513 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 514
 515 if(WIN32)
 516   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 517   if(MSVC)
 518     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 519     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 520     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 521     link_libraries(Version dwmapi shlwapi)
 522   endif(MSVC)
 523   if(HAVE_SSL AND STATIC)
 524      find_package(OpenSSL REQUIRED)
 525      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 526   endif(HAVE_SSL AND STATIC)
 527 endif(WIN32)
 528
 529 if(HAVE_INDICATEQT)
 530   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 531 endif(HAVE_INDICATEQT)
 532
 533 if(NOT WIN32)
 534   check_function_exists(umask HAVE_UMASK)
 535   if(HAVE_UMASK)
 536     add_definitions(-DHAVE_UMASK)
 537   endif(HAVE_UMASK)
 538 endif(NOT WIN32)
 539
 540 # We need to create a version.gen
 541 # For this, we create our genversion binary and make sure it is run every time.
 542
 543 setup_qt_variables()
 544 include_directories(${QUASSEL_QT_INCLUDES})
 545
 546 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 547 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 548 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 549
 550 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 551 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 552                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 553 add_dependencies(genversion_run genversion)
 554
 555 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 556 set(COMMON_DEPS ${RC_WIN32})
 557 set(CORE_DEPS )
 558 set(CLIENT_DEPS )
 559
 560 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 561 add_subdirectory(data)
 562 add_subdirectory(icons)
 563 add_subdirectory(pics)
 564 add_subdirectory(po)
 565 add_subdirectory(src)