CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 project(QuasselIRC)
  29
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32
  33 # For building against Qt5, we check for an even newer cmake version below!
  34 cmake_minimum_required(VERSION 2.8.1 FATAL_ERROR)
  35
  36 if(COMMAND cmake_policy)
  37    cmake_policy(SET CMP0003 NEW)
  38 endif(COMMAND cmake_policy)
  39
  40 # Use our own (well, and KDE's) version of some modules
  41 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  42 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  43 include(QuasselMacros)
  44
  45 # Various options and variables that can be set on the command line
  46 option(WANT_CORE     "Build the core (server) binary"           ON)
  47 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  48 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  49
  50 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  51 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  52 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  53 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  54 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  55 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  56 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  57 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  58
  59 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  60 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  61 # run on a matching KDE version only.
  62 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  63
  64 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  65 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  66
  67 option(STATIC        "Enable static building (might not be portable)" OFF)
  68
  69 if(APPLE)
  70   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  71   option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  72 endif(APPLE)
  73
  74 # Default to embedding data in the static case
  75 if(STATIC OR WIN32)
  76   set(EMBED_DEFAULT ON)
  77 else(STATIC OR WIN32)
  78   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  79 endif(STATIC OR WIN32)
  80
  81 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  82
  83 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  84
  85 # Some settings imply others
  86 if(STATIC)
  87   add_definitions(-DSTATIC)
  88   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  89 endif(STATIC)
  90
  91 if(WIN32)
  92   # We don't support separately installed resources yet on Win32
  93   set(EMBED_DATA ON)
  94 endif(WIN32)
  95
  96 # For static builds, arbitrary extra libs might need to be linked
  97 # Define a comma-separated list here
  98 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
  99 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 100 if(LINK_EXTRA)
 101   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 102   link_libraries(${LINK_EXTRA})
 103 endif(LINK_EXTRA)
 104
 105 # Build Type
 106 # We need to make sure it's not empty
 107 # Supported: Release, RelWithDebugInfo, Debug, Debugfull
 108
 109 # On WIN32, only Release seems to work correctly (?)
 110 if(WIN32)
 111   set(DEFAULT_BUILD_TYPE "Release")
 112 else(WIN32)
 113   set(DEFAULT_BUILD_TYPE "RelWithDebugInfo")
 114 endif(WIN32)
 115
 116 set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type")
 117 if(NOT CMAKE_BUILD_TYPE)
 118   set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type" FORCE)
 119 endif(NOT CMAKE_BUILD_TYPE)
 120
 121 # Qt debug flags
 122 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 123 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_FULLDEBUG QT_DEBUG)
 124 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 125 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 126 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 127
 128 IF(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 129   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 130 ENDIF()
 131
 132 # Enable various flags on gcc
 133 if(CMAKE_COMPILER_IS_GNUCXX)
 134   # Let's just hope that all gccs support these options and skip the tests...
 135   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 136   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 137   set(CMAKE_CXX_FLAGS_RELEASE          "-O2 ${CMAKE_CXX_FLAGS}")
 138   set(CMAKE_CXX_FLAGS_RELWITHDEBUGINFO "-g -O2 ${CMAKE_CXX_FLAGS}")
 139   set(CMAKE_CXX_FLAGS_DEBUG            "-g -ggdb -fno-reorder-blocks -fno-schedule-insns -fno-inline ${CMAKE_CXX_FLAGS}")
 140   set(CMAKE_CXX_FLAGS_DEBUGFULL        "-g3 ${CMAKE_CXX_FLAGS_DEBUG}")
 141 endif(CMAKE_COMPILER_IS_GNUCXX)
 142
 143 # Mac build stuff
 144 if(APPLE AND DEPLOY)
 145   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 146   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 147   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 148   add_definitions(-DMAC_10_6_SDK)
 149 endif(APPLE AND DEPLOY)
 150
 151 # Simplify checks
 152 if(WANT_MONO OR WANT_QTCLIENT)
 153   set(BUILD_GUI true)
 154 endif(WANT_MONO OR WANT_QTCLIENT)
 155 if(WANT_MONO OR WANT_CORE)
 156   set(BUILD_CORE true)
 157 endif(WANT_MONO OR WANT_CORE)
 158
 159
 160 # Version checks
 161 ################
 162
 163 if(WITH_QT5)
 164   set(QT_MIN_VERSION "5.0.0")
 165   add_definitions(-DHAVE_QT5)
 166
 167   # Qt5 needs a new enough cmake...
 168   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 169
 170   # ... for automoc
 171   set(CMAKE_AUTOMOC ON)
 172 else(WITH_QT5)
 173
 174   # GUI stuff needs some new features
 175   if(BUILD_GUI)
 176     set(QT_MIN_VERSION "4.6.0")
 177   else(BUILD_GUI)
 178     set(QT_MIN_VERSION "4.4.0")
 179   endif(BUILD_GUI)
 180 endif(WITH_QT5)
 181
 182
 183 # Dependencies
 184 ##############
 185
 186 if(WITH_QT5)
 187   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 188   # We need QtWidgets
 189   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 190
 191   # Setup the i18n-related variables
 192   find_package(Qt5LinguistTools)
 193
 194 else(WITH_QT5)
 195   # Select a Qt installation here, if you don't want to use system Qt
 196   if(QT)
 197     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 198     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 199   endif(QT)
 200
 201   # Now that we have the correct $PATH, lets find Qt!
 202   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 203 endif(WITH_QT5)
 204
 205
 206 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 207 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 208 if(QT_LRELEASE_EXECUTABLE)
 209   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 210   if(WITH_QT5)
 211     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 212   else(WITH_QT5)
 213     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 214   endif(WITH_QT5)
 215 endif(QT_LRELEASE_EXECUTABLE)
 216
 217
 218 # Execinfo is needed for generating backtraces
 219 find_package(ExecInfo)
 220 if(EXECINFO_FOUND)
 221   add_definitions(-DHAVE_EXECINFO)
 222   include_directories(${EXECINFO_INCLUDES})
 223   link_libraries(${EXECINFO_LIBRARIES})
 224 endif(EXECINFO_FOUND)
 225
 226
 227 # PkgConfig isn't strictly required.
 228 # However, some optional deps might not be found if it's not present, so warn!
 229 find_package(PkgConfig)
 230 if(NOT PKG_CONFIG_FOUND)
 231   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 232   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 233 endif(NOT PKG_CONFIG_FOUND)
 234
 235
 236 # Setup OpenSSL
 237 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 238 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 239 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 240 if(WITH_OPENSSL)
 241   if(QT_QCONFIG MATCHES "openssl")
 242     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 243     add_definitions(-DHAVE_SSL)
 244     set(HAVE_SSL true)
 245   else(QT_QCONFIG MATCHES "openssl")
 246     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 247     add_definitions(-DQT_NO_OPENSSL)
 248   endif(QT_QCONFIG MATCHES "openssl")
 249 else(WITH_OPENSSL)
 250   message(STATUS "Not enabling OpenSSL support")
 251 endif(WITH_OPENSSL)
 252
 253
 254 # Check for GUI specific stuff
 255 if(BUILD_GUI)
 256
 257   # Setup D-Bus support
 258   if(WITH_DBUS)
 259     if(WITH_QT5)
 260       find_package(Qt5DBus ${QT_MIN_VERSION})
 261       find_package(Qt5DBusTools)
 262     endif(WITH_QT5)
 263
 264     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 265       message(STATUS "Found QtDBus, enabling D-Bus support")
 266       add_definitions(-DHAVE_DBUS)
 267       set(HAVE_DBUS true)
 268       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 269
 270       # check if we have dbusmenu as well
 271       if(NOT WITH_QT5)
 272         find_package(DBusMenuQt)
 273         if(DBUSMENUQT_FOUND)
 274           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 275           add_definitions(-DHAVE_DBUSMENU)
 276           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 277           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 278           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 279         else(DBUSMENUQT_FOUND)
 280           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 281         endif(DBUSMENUQT_FOUND)
 282       endif(NOT WITH_QT5)
 283
 284     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 285       message(STATUS "QtDBus not found, disabling D-Bus support")
 286     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 287   else(WITH_DBUS)
 288     message(STATUS "Not enabling D-Bus support")
 289   endif(WITH_DBUS)
 290
 291   # Setup QtWebkit support
 292   if(WITH_WEBKIT)
 293     if(WITH_QT5)
 294       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 295     endif(WITH_QT5)
 296     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 297       message(STATUS "Found QtWebKit, enabling WebKit support")
 298       add_definitions(-DHAVE_WEBKIT)
 299       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 300       set(HAVE_WEBKIT true)
 301     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 302       message(STATUS "QtWebkit not found, disabling Webkit support")
 303     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 304   else(WITH_WEBKIT)
 305     message(STATUS "Not enabling Webkit support")
 306   endif(WITH_WEBKIT)
 307
 308   # Setup KDE4 support
 309   if(WITH_KDE AND NOT WITH_QT5)
 310     find_package(KDE4)
 311     if(KDE4_FOUND)
 312       message(STATUS "Enabling KDE4 integration")
 313       include_directories(${KDE4_INCLUDES})
 314       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 315       set(HAVE_KDE 1)
 316       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} knotifyconfig)
 317       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 318       set(EMBED_DATA OFF)
 319     else(KDE4_FOUND)
 320       message(STATUS "KDE4 not found, disabling KDE integration")
 321     endif(KDE4_FOUND)
 322   else(WITH_KDE AND NOT WITH_QT5)
 323     message(STATUS "Not enabling KDE4 integration")
 324   endif(WITH_KDE AND NOT WITH_QT5)
 325
 326   # Setup Phonon support - we only need this if we don't have or want KDE4
 327   if(NOT HAVE_KDE)
 328     if(WITH_PHONON)
 329       if(WITH_QT5)
 330         find_package(Qt5phonon)
 331         if(Qt5phonon_FOUND)
 332           message(STATUS "Enabling Phonon support")
 333           add_definitions(-DHAVE_PHONON)
 334           set(HAVE_PHONON true)
 335           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 336         else(Qt5phonon_FOUND)
 337           message(STATUS "Phonon not found, disabling audio notifications")
 338         endif(Qt5phonon_FOUND)
 339       else(WITH_QT5)
 340         find_package(Phonon)
 341         if(PHONON_FOUND)
 342           message(STATUS "Enabling Phonon support")
 343           add_definitions(-DHAVE_PHONON)
 344           include_directories(${PHONON_INCLUDES})
 345           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 346           set(HAVE_PHONON true)
 347         else(PHONON_FOUND)
 348           message(STATUS "Phonon not found, disabling audio notifications")
 349         endif(PHONON_FOUND)
 350       endif(WITH_QT5)
 351     else(WITH_PHONON)
 352       message(STATUS "Not enabling Phonon support")
 353     endif(WITH_PHONON)
 354   endif(NOT HAVE_KDE)
 355
 356   # Setup libindicate-qt support
 357   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 358     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 359     if(INDICATEQT_FOUND)
 360       message(STATUS "Enabling Ayatana notification support")
 361       set(HAVE_INDICATEQT true)
 362       add_definitions(-DHAVE_INDICATEQT)
 363       link_directories(${INDICATEQT_LIBRARY_DIRS})
 364       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 365     else(INDICATEQT_FOUND)
 366       message(STATUS "Disabling Ayatana notification support")
 367     endif(INDICATEQT_FOUND)
 368   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 369     message(STATUS "Not enabling Ayatana notification support")
 370     # We don't want to link against it even if another package has found it
 371     set(INDICATEQT_LIBRARIES "")
 372   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 373
 374   # Setup OS X notification center support
 375   if(WITH_NOTIFICATION_CENTER AND APPLE)
 376     set(HAVE_NOTIFICATION_CENTER true)
 377     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 378     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 379       /System/Library/Frameworks/Foundation.framework
 380     )
 381   endif()
 382
 383 endif(BUILD_GUI)
 384
 385 # Core-only deps
 386 if(BUILD_CORE)
 387
 388   # Setup encryption support
 389   if(WITH_CRYPT AND NOT WITH_QT5)
 390     find_package(QCA2)
 391     if(QCA2_FOUND)
 392       message(STATUS "Enabling encryption support")
 393       add_definitions(-DHAVE_QCA2)
 394       set(LINK_QCA2 QCA2)
 395       set(HAVE_QCA2 true)
 396       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 397     else(QCA2_FOUND)
 398       message(STATUS "Disabling encryption support")
 399     endif(QCA2_FOUND)
 400   else(WITH_CRYPT AND NOT WITH_QT5)
 401     message(STATUS "Not enabling encryption support")
 402   endif(WITH_CRYPT AND NOT WITH_QT5)
 403
 404   # Setup syslog support
 405   if(WITH_SYSLOG)
 406     check_include_file(syslog.h HAVE_SYSLOG_H)
 407     if(HAVE_SYSLOG_H)
 408       message(STATUS "Enabling syslog support")
 409       set(HAVE_SYSLOG true)
 410       add_definitions(-DHAVE_SYSLOG)
 411     else(HAVE_SYSLOG_H)
 412       message(STATUS "Disabling syslog support")
 413     endif(HAVE_SYSLOG_H)
 414   else(WITH_SYSLOG)
 415     message(STATUS "Not enabling syslog support")
 416   endif(WITH_SYSLOG)
 417
 418 endif(BUILD_CORE)
 419
 420
 421 # Various settings
 422 ##################
 423
 424 # needed to compile with mingw without kde
 425 if(MINGW AND NOT HAVE_KDE)
 426     add_definitions(-D_WIN32_WINNT=0x0500)
 427     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 428 # workaround for bug in mingw gcc 4.0
 429     add_definitions(-U__STRICT_ANSI__)
 430 endif(MINGW AND NOT HAVE_KDE)
 431
 432 # Now set up install locations; those are set by KDE if integration is enabled
 433 if(NOT HAVE_KDE)
 434   if(WIN32)
 435     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 436     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 437     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 438     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 439   else(WIN32)
 440     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 441     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 442     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 443     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 444   endif(WIN32)
 445 endif(NOT HAVE_KDE)
 446
 447 if(EMBED_DATA)
 448   message(STATUS "Embedding data files into the binary")
 449 else(EMBED_DATA)
 450   message(STATUS "Installing data files separately")
 451 endif(EMBED_DATA)
 452
 453 # RPATH needs to be set correctly
 454 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 455 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 456 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 457
 458 # Set global buildflags
 459 # This is very much non-portable, so don't use -DSTATIC until you know what
 460 # you do.
 461 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 462   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 463   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 464   if(HAVE_SSL)
 465     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 466   endif(HAVE_SSL)
 467 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 468
 469 if(WIN32)
 470   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 471   if(MSVC)
 472     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 473     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 474     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 475     link_libraries(Version dwmapi shlwapi)
 476   endif(MSVC)
 477   if(HAVE_SSL AND STATIC)
 478      find_package(OpenSSL REQUIRED)
 479      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 480   endif(HAVE_SSL AND STATIC)
 481 endif(WIN32)
 482
 483 if(HAVE_INDICATEQT)
 484   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 485 endif(HAVE_INDICATEQT)
 486
 487 if(NOT WIN32)
 488   check_function_exists(umask HAVE_UMASK)
 489   if(HAVE_UMASK)
 490     add_definitions(-DHAVE_UMASK)
 491   endif(HAVE_UMASK)
 492 endif(NOT WIN32)
 493
 494 # We need to create a version.gen
 495 # For this, we create our genversion binary and make sure it is run every time.
 496
 497 setup_qt_variables()
 498 include_directories(${QUASSEL_QT_INCLUDES})
 499
 500 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 501 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 502 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 503
 504 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 505 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 506                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 507 add_dependencies(genversion_run genversion)
 508
 509 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 510 set(COMMON_DEPS ${RC_WIN32})
 511 set(CORE_DEPS )
 512 set(CLIENT_DEPS )
 513
 514 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 515 add_subdirectory(data)
 516 add_subdirectory(icons)
 517 add_subdirectory(pics)
 518 add_subdirectory(po)
 519 add_subdirectory(src)