CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 11)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.11-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37
  38 # Options and variables that can be set on the command line
  39 #####################################################################
  40
  41 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  42 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  43 if (USE_QT4) # takes precedence
  44     set(USE_QT5 OFF)
  45 else()
  46     if (NOT USE_QT5)
  47         set(USE_QT4 ON)
  48     endif()
  49 endif()
  50
  51 # Select the binaries to build
  52 option(WANT_CORE     "Build the core (server) binary"           ON)
  53 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  54 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  55 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  56 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  57 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  58
  59 # Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
  60 cmake_dependent_option(WITH_KDE "KDE4 integration" OFF "USE_QT4" OFF)
  61 add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  62
  63 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  64 if (NOT WITH_KDE)
  65     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  66 endif()
  67
  68 # For this, the feature info is added after we know if QtWebkit is installed
  69 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  70
  71 if (APPLE)
  72     # Notification Center is only available in > 10.8, which is Darwin v12
  73     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  75         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  76     endif()
  77 endif()
  78
  79 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  80 set(EMBED_DEFAULT OFF)
  81 if (STATIC OR WIN32 OR APPLE)
  82     set(EMBED_DEFAULT ON)
  83 endif()
  84 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  85                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  86 if (NOT EMBED_DEFAULT)
  87     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  88 endif()
  89
  90 # The following options are not for end-user consumption, so don't list them in the feature summary
  91 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  92
  93 # Handle with care
  94 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
  95
  96 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
  97 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
  98
  99 # For static builds, arbitrary extra libs might need to be linked
 100 # Define a comma-separated list here
 101 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 102 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 103 if (LINK_EXTRA)
 104     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 105     link_libraries(${LINK_EXTRA})
 106 endif()
 107
 108
 109 # Simplify later checks
 110 #####################################################################
 111
 112 if (WANT_MONO OR WANT_QTCLIENT)
 113     set(BUILD_GUI true)
 114 endif()
 115 if (WANT_MONO OR WANT_CORE)
 116     set(BUILD_CORE true)
 117 endif()
 118
 119
 120 # Set up Qt
 121 #####################################################################
 122
 123 if (USE_QT5)
 124     message(STATUS "Building with the Qt5 libraries...")
 125     set(QT_MIN_VERSION "5.2.0")
 126     add_definitions(-DHAVE_QT5)
 127 else()
 128     message(STATUS "Building with the Qt4 libraries...")
 129     if (BUILD_GUI)
 130         set(QT_MIN_VERSION "4.6.0")
 131     else()
 132         set(QT_MIN_VERSION "4.4.0")
 133     endif()
 134 endif()
 135
 136 if (USE_QT5)
 137     find_package(Qt5Core ${QT_MIN_VERSION} QUIET REQUIRED)
 138
 139     # Contains lconvert and friends
 140     find_package(Qt5LinguistTools QUIET)
 141     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 142                            PURPOSE "Required for localization support"
 143     )
 144 else()
 145     # Select a Qt installation here, if you don't want to use system Qt
 146     if(QT_PATH)
 147         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 148         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 149     endif()
 150
 151     # Now that we have the correct $PATH, lets find Qt!
 152     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 153 endif()
 154
 155 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 156 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 157 if (QT_LRELEASE_EXECUTABLE)
 158     get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 159     if (USE_QT5)
 160         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 161     else()
 162         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 163     endif()
 164 endif()
 165
 166 add_feature_info("Qt Linguist Tools" QT_LRELEASE_EXECUTABLE "Translation support for Quassel")
 167
 168 # Optional Dependencies
 169 #
 170 # Note that you can forcefully disable optional packages
 171 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 172 #####################################################################
 173
 174 if(USE_QT5)
 175     if (BUILD_GUI)
 176         find_package(Qt5DBus QUIET)
 177         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 178             URL "http://qt.digia.com"
 179             DESCRIPTION "D-Bus support for Qt5"
 180             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 181         )
 182         if (Qt5DBus_FOUND)
 183             find_package(dbusmenu-qt5 QUIET)
 184             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 185                 URL "https://launchpad.net/libdbusmenu-qt"
 186                 DESCRIPTION "a library implementing the DBusMenu specification"
 187                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 188             )
 189         endif()
 190
 191         find_package(Phonon4Qt5 QUIET)
 192         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 193             URL "https://projects.kde.org/projects/kdesupport/phonon"
 194             DESCRIPTION "a multimedia abstraction library"
 195             PURPOSE     "Required for audio notifications"
 196         )
 197
 198         if (WITH_WEBKIT)
 199             find_package(Qt5Webkit QUIET)
 200             set_package_properties(Qt5Webkit PROPERTIES TYPE RECOMMENDED
 201                 URL "http://qt.digia.com"
 202                 DESCRIPTION "a Webkit implementation for Qt"
 203                 PURPOSE     "Needed for displaying previews for URLs in chat"
 204             )
 205         endif()
 206         add_feature_info("WITH_WEBKIT and QtWebkit module" Qt5Webkit_FOUND "Support showing previews for URLs in chat")
 207
 208     endif(BUILD_GUI)
 209     if (BUILD_CORE)
 210         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 211         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 212         #find_package(QCA2 QUIET)
 213         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 214         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 215         #    DESCRIPTION "Qt Cryptographic Architecture"
 216         #    PURPOSE "Required for encryption support"
 217         #)
 218
 219     endif(BUILD_CORE)
 220
 221 else(USE_QT5)
 222     if (BUILD_GUI)
 223         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 224         if (QT_QTDBUS_FOUND)
 225             find_package(libdbusmenu-qt QUIET)
 226             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 227                 URL "https://launchpad.net/libdbusmenu-qt"
 228                 DESCRIPTION "a library implementing the DBusMenu specification"
 229                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 230             )
 231         endif()
 232
 233         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 234             set(HAVE_WEBKIT true)
 235         endif()
 236         add_feature_info("WITH_WEBKIT and QtWebkit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 237
 238         if (WITH_KDE)
 239             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 240             set(_cflags ${CMAKE_C_FLAGS})
 241             find_package(KDE4 4.4 QUIET)
 242             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 243                 URL "http://www.kde.org"
 244                 DESCRIPTION "a world-class desktop environment"
 245                 PURPOSE "Enables various bits for improving integration with KDE"
 246             )
 247             set(CMAKE_C_FLAGS ${_cflags})
 248
 249         else(WITH_KDE)
 250             find_package(Phonon QUIET)
 251             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 252                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 253                 DESCRIPTION "a multimedia abstraction library"
 254                 PURPOSE     "Required for audio notifications"
 255             )
 256
 257             find_package(Libsnore QUIET)
 258             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 259                 URL "https://github.com/TheOneRing/Snorenotify"
 260                 DESCRIPTION "a cross-platform notification framework"
 261                 PURPOSE     "Enable support for the snorenotify framework"
 262             )
 263         endif(WITH_KDE)
 264
 265         find_package(IndicateQt QUIET)
 266         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 267             URL "https://launchpad.net/libindicate-qt/"
 268             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 269             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 270         )
 271
 272     endif(BUILD_GUI)
 273     if (BUILD_CORE)
 274
 275         find_package(QCA2 QUIET)
 276         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 277             URL "https://projects.kde.org/projects/kdesupport/qca"
 278             DESCRIPTION "Qt Cryptographic Architecture"
 279             PURPOSE     "Required for encryption support"
 280         )
 281
 282
 283     endif()
 284 endif()
 285
 286 # Non-Qt-based packages
 287
 288 # zlib for compression, however we can always fall back to miniz
 289 find_package(ZLIB QUIET)
 290 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 291     URL "http://www.zlib.net"
 292     DESCRIPTION "a popular compression library"
 293     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 294 )
 295
 296
 297 if (NOT WIN32)
 298     # Execinfo is needed for generating backtraces
 299     find_package(ExecInfo QUIET)
 300     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 301         DESCRIPTION "a library for inspecting backtraces"
 302         PURPOSE "Used for generating backtraces in case of a crash"
 303     )
 304 endif()
 305
 306
 307 # Various checks
 308 #####################################################################
 309
 310 if (NOT ZLIB_FOUND)
 311     message(STATUS "zlib NOT found, using bundled miniz for compression")
 312     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 313         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 314     endif()
 315 endif()
 316
 317 if (KDE4_FOUND)
 318     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 319     set(EMBED_DATA OFF)
 320
 321     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 322     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 323 endif()
 324
 325 # Check for SSL support in Qt
 326 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 327 # a small test program checking the defines. This works for both Qt4 and Qt5.
 328 cmake_push_check_state(RESET)
 329 if (Qt5_POSITION_INDEPENDENT_CODE)
 330     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 331 endif()
 332 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 333 check_cxx_source_compiles("
 334     #include \"qglobal.h\"
 335     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 336     #  error \"No SSL support\"
 337     #endif
 338     int main() {}"
 339     HAVE_SSL)
 340 cmake_pop_check_state()
 341
 342 if (HAVE_SSL)
 343     add_definitions(-DHAVE_SSL)
 344 endif()
 345 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 346
 347 # Check for syslog support
 348 if (NOT WIN32)
 349     check_include_file(syslog.h HAVE_SYSLOG)
 350     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 351 endif()
 352
 353
 354 # Various settings
 355 ##################
 356
 357 # needed to compile with mingw without kde
 358 if (MINGW AND NOT KDE4_FOUND)
 359     add_definitions(-D_WIN32_WINNT=0x0500)
 360     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 361 # workaround for bug in mingw gcc 4.0
 362     add_definitions(-U__STRICT_ANSI__)
 363 endif()
 364
 365 # Now set up install locations; those are set by KDE if integration is enabled
 366 if(NOT KDE4_FOUND)
 367   if(WIN32)
 368     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 369     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 370     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 371     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 372   else(WIN32)
 373     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 374     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 375     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 376     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 377   endif(WIN32)
 378 endif()
 379
 380 if(EMBED_DATA)
 381   message(STATUS "Embedding data files into the binary")
 382 else(EMBED_DATA)
 383   message(STATUS "Installing data files separately")
 384 endif(EMBED_DATA)
 385
 386 # RPATH needs to be set correctly
 387 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 388 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 389 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 390
 391 # Set global buildflags
 392 # This is very much non-portable, so don't use -DSTATIC until you know what
 393 # you do.
 394 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 395   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 396   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 397   if(HAVE_SSL)
 398     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 399   endif(HAVE_SSL)
 400 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 401
 402 if(WIN32)
 403   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 404   if(MSVC)
 405     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 406     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 407     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 408     link_libraries(Version dwmapi shlwapi)
 409   endif(MSVC)
 410   if(HAVE_SSL AND STATIC)
 411      find_package(OpenSSL REQUIRED)
 412      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 413   endif(HAVE_SSL AND STATIC)
 414 endif(WIN32)
 415
 416 if(INDICATEQT_FOUND)
 417   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 418 endif()
 419
 420 if(NOT WIN32)
 421   check_function_exists(umask HAVE_UMASK)
 422   if(HAVE_UMASK)
 423     add_definitions(-DHAVE_UMASK)
 424   endif(HAVE_UMASK)
 425 endif(NOT WIN32)
 426
 427 # Generate version information from Git
 428 include(GetGitRevisionDescription)
 429 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 430 git_describe(GIT_DESCRIBE --long)
 431
 432 # Sanitize things if we're not in a Git repo
 433 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 434     set(GIT_HEAD "")
 435     set(GIT_DESCRIBE "")
 436 endif()
 437
 438 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 439
 440 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 441 set(COMMON_DEPS ${RC_WIN32})
 442 set(CORE_DEPS )
 443 set(CLIENT_DEPS )
 444
 445 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 446 add_subdirectory(data)
 447 add_subdirectory(icons)
 448 add_subdirectory(pics)
 449 add_subdirectory(po)
 450 add_subdirectory(src)
 451
 452 # Set up and display feature summary
 453 #####################################################################
 454
 455 feature_summary(WHAT ALL
 456                 INCLUDE_QUIET_PACKAGES
 457                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 458 )