CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 # You may pass various options to cmake:
   3 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   4 #                     : select binaries to build
   5 # -DWITH_OPENSSL=OFF  : Disable OpenSSL support
   6 # -DWITH_DBUS=OFF     : Disable D-Bus support
   7 # -DOXYGEN_ICONS=(Builtin|External)  : If "Builtin" (the default), compile our Oxygen Icon Theme subset into the binary
   8 #                                    : If "External", we assume Oxygen is already installed on the system
   9 # -DQUASSEL_ICONS=(Builtin|External) : If "Builtin" (the default), put our own icons into the binary
  10 #                                    : If "External", we install our icons into $PREFIX/share/apps/quassel (UNIX only)
  11 # -DQT=/path/to/qt    : Choose a Qt4 installation to use instead of the system Qt4
  12 # -DSTATIC=ON         : Enable static building of Quassel. Use with care.
  13 # -DDEPLOY=ON         : Mac OS X only. Use only for creating Quassel Packages!
  14 #
  15 # NOTE: You need to remove CMakeCache.txt if you plan to change any of these values!
  16
  17 project(QuasselIRC)
  18
  19 cmake_minimum_required(VERSION 2.6.0 FATAL_ERROR)
  20
  21 if(COMMAND cmake_policy)
  22    cmake_policy(SET CMP0003 NEW)
  23    cmake_policy(SET CMP0005 NEW)
  24 endif(COMMAND cmake_policy)
  25
  26 # Use our own (well, and KDE's) version of some modules
  27 # In particular cmake's FindQt4 and FindOpenSSL are quite buggy
  28 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  29
  30 # Various options and variables that can be set on the command line
  31 option(WANT_CORE     "Build the core (server) binary"           ON)
  32 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  33 option(WANT_MONO     "Build the monolithic (all-in-one) binary" OFF)
  34
  35 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  36 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  37
  38 option(STATIC        "Enable static building (might not be portable)" OFF)
  39 option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  40 option(SPUTDEV       "Do not use!" OFF)
  41
  42 set(OXYGEN_ICONS "Builtin" CACHE STRING "Builtin: Compile Oxygen icons into the binary; External: Use system-installed Oxygen")
  43 set(QUASSEL_ICONS "Builtin" CACHE STRING "Builtin: Compile Quassel icons into the binary; External: Install them separately")
  44
  45 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt")
  46 set(LINGUAS "" CACHE STRING "Space-separated List of locales specifying languages that should be compiled")
  47
  48 if(STATIC)
  49   set(CMAKE_BUILD_TYPE Release)
  50   set(OXYGEN_ICONS "Builtin")
  51   set(QUASSEL_ICONS "Builtin")
  52 endif(STATIC)
  53
  54 # RPATH needs to be set correctly
  55 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
  56 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
  57
  58 # Define install locations. Using variables will allow overriding this by the KDE macros later.
  59 set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  60 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps)
  61 set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons)
  62 set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications)
  63
  64 add_definitions(-DPREFIX=${CMAKE_INSTALL_PREFIX})
  65
  66 # Enable various flags on gcc
  67 if(CMAKE_COMPILER_IS_GNUCXX)
  68   # Let's just hope that all gccs support these options and skip the tests...
  69   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor")
  70 endif(CMAKE_COMPILER_IS_GNUCXX)
  71
  72 set(QT_MIN_VERSION "4.4.0")
  73
  74 if(APPLE AND DEPLOY)
  75   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
  76   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
  77   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
  78   add_definitions(-DMAC_10_4_SDK)
  79 endif(APPLE AND DEPLOY)
  80
  81 include(QuasselMacros)
  82
  83 # Execinfo is needed for generating backtraces
  84 find_package(ExecInfo)
  85 if(EXECINFO_FOUND)
  86   add_definitions(-DHAVE_EXECINFO)
  87   include_directories(${EXECINFO_INCLUDES})
  88   link_libraries(${EXECINFO_LIBRARIES})
  89 endif(EXECINFO_FOUND)
  90
  91 # Select a Qt installation here, if you don't want to use system Qt
  92 if(QT)
  93   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
  94   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
  95 endif(QT)
  96
  97 # Now that we have the correct $PATH, lets find Qt!
  98 find_package(Qt4 REQUIRED)
  99
 100 set(QT_DONT_USE_QTGUI 1)
 101 include(${QT_USE_FILE})
 102 include_directories(${QT_INCLUDES})
 103
 104 # Setup OpenSSL
 105 if(WITH_OPENSSL)
 106   find_package(OpenSSL)
 107 else(WITH_OPENSSL)
 108   message(STATUS "Disabling OpenSSL support")
 109 endif(WITH_OPENSSL)
 110
 111 if(OPENSSL_FOUND)
 112   if(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 113     message(STATUS "Found OpenSSL support in Qt")
 114     add_definitions(-DHAVE_SSL)
 115     set(HAVE_SSL true)
 116     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_SSL)
 117   else(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 118     message(STATUS "No OpenSSL support found in Qt, disabling")
 119   endif(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 120 else(OPENSSL_FOUND)
 121   add_definitions(-DQT_NO_OPENSSL)
 122 endif(OPENSSL_FOUND)
 123
 124 # Setup D-Bus support
 125 if(WITH_DBUS)
 126   if(QT_QTDBUS_FOUND)
 127     message(STATUS "Found QtDBus, enabling D-Bus support")
 128     add_definitions(-DHAVE_DBUS)
 129     set(LINK_DBUS DBUS)
 130     set(HAVE_DBUS true)
 131     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_DBUS)
 132   else(QT_QTDBUS_FOUND)
 133     message(STATUS "QtDBus not found, disabling D-Bus support")
 134   endif(QT_QTDBUS_FOUND)
 135 else(WITH_DBUS)
 136   message(STATUS "Disabling D-Bus support")
 137 endif(WITH_DBUS)
 138
 139 # Set global buildflags
 140 # This is very much non-portable, so don't use -DSTATIC until you know what
 141 # you do.
 142 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 143   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 144   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 145   if(HAVE_SSL)
 146     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 147   endif(HAVE_SSL)
 148 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 149
 150 if(STATIC AND WIN32)
 151   link_libraries(imm32 winmm)  # missing by default :/
 152    if(HAVE_SSL)
 153      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 154    endif(HAVE_SSL)
 155 endif(STATIC AND WIN32)
 156
 157 if(WIN32)
 158   set(RC_WIN32 pics/win32.rc)  # for app icons on windows
 159 endif(WIN32)
 160
 161 # This is dirty, but I haven't found a cleaner way to ensure that the generated .qrc files
 162 # (which will be removed with make clean) are regenerated :/
 163 set_directory_properties(PROPERTIES
 164                          ADDITIONAL_MAKE_CLEAN_FILES CMakeCache.txt)
 165
 166 # We need to create a version.gen
 167 # For this, we create our genversion binary and make sure it is run every time.
 168 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 169 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
 170
 171 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 172 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 173                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/common/version.gen)
 174 add_dependencies(genversion_run genversion)
 175
 176 # Decide what to do with icons
 177 if(WANT_QTCLIENT OR WANT_MONO)
 178   if(QUASSEL_ICONS MATCHES "External")
 179     message(STATUS "Install Quassel icons to ${CMAKE_INSTALL_PREFIX}/share/apps/quassel")
 180   else(QUASSEL_ICONS MATCHES "External")
 181     set(QUASSEL_ICONS "Builtin")
 182     message(STATUS "Compile Quassel icons into the binary")
 183   endif(QUASSEL_ICONS MATCHES "External")
 184
 185   if(OXYGEN_ICONS MATCHES "External")
 186     message(STATUS "Use system-installed Oxygen icon theme")
 187   else(OXYGEN_ICONS MATCHES "External")
 188     set(OXYGEN_ICONS "Builtin")
 189     message(STATUS "Compile Oxygen icon theme subset into the binary")
 190   endif(OXYGEN_ICONS MATCHES "External")
 191 endif(WANT_QTCLIENT OR WANT_MONO)
 192
 193 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 194
 195 set(COMMON_DEPS ${RC_WIN32})
 196 set(CORE_DEPS )
 197 set(CLIENT_DEPS )
 198 set(KDE_DEPS )
 199
 200 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 201 add_subdirectory(data)
 202 add_subdirectory(icons)
 203 #add_subdirectory(pics)
 204 add_subdirectory(i18n)
 205 add_subdirectory(src)
 206
 207 # Make sure version.gen exists before building mod_common
 208 # TODO: make only main.cpp depend on that! Recompiles suck...
 209 add_dependencies(mod_common genversion_run)