CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 12)
  14 set(QUASSEL_PATCH  4)
  15 set(QUASSEL_VERSION_STRING "0.12.4")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  44 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  45 if (USE_QT4) # takes precedence
  46     set(USE_QT5 OFF)
  47 else()
  48     if (NOT USE_QT5)
  49         set(USE_QT4 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 if (NOT WITH_KDE)
  75     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  76 endif()
  77
  78 # For this, the feature info is added after we know if QtWebkit is installed
  79 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" ON)
  80
  81 # For this, the feature info is added after we know if QtWebEngine is installed
  82 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  83
  84 if (APPLE)
  85     # Notification Center is only available in > 10.8, which is Darwin v12
  86     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  87         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  88         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  89     endif()
  90 endif()
  91
  92 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  93 set(EMBED_DEFAULT OFF)
  94 if (STATIC OR WIN32 OR APPLE)
  95     set(EMBED_DEFAULT ON)
  96 endif()
  97 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  98                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  99 if (NOT EMBED_DEFAULT)
 100     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 101 endif()
 102
 103 # The following options are not for end-user consumption, so don't list them in the feature summary
 104 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 105
 106 # Handle with care
 107 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 108
 109 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 110 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 111
 112 # For static builds, arbitrary extra libs might need to be linked
 113 # Define a comma-separated list here
 114 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 115 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 116 if (LINK_EXTRA)
 117     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 118     link_libraries(${LINK_EXTRA})
 119 endif()
 120
 121
 122 # Setup CMake
 123 #####################################################################
 124
 125 if (USE_QT5 AND WITH_KDE)
 126     cmake_minimum_required(VERSION 2.8.12)
 127 else()
 128     cmake_minimum_required(VERSION 2.8.9)
 129 endif()
 130
 131 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 132 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 133 if (POLICY CMP0043)
 134     cmake_policy(SET CMP0043 OLD)
 135 endif()
 136
 137 # Honor visibility settings for all target types
 138 if (POLICY CMP0063)
 139     cmake_policy(SET CMP0063 NEW)
 140 endif()
 141
 142
 143 # Simplify later checks
 144 #####################################################################
 145
 146 if (WANT_MONO OR WANT_QTCLIENT)
 147     set(BUILD_GUI true)
 148 endif()
 149 if (WANT_MONO OR WANT_CORE)
 150     set(BUILD_CORE true)
 151 endif()
 152
 153
 154 # Set up Qt
 155 #####################################################################
 156
 157 if (USE_QT5)
 158     message(STATUS "Building for Qt5...")
 159     set(QT_MIN_VERSION "5.2.0")
 160     add_definitions(-DHAVE_QT5)
 161 else()
 162     message(STATUS "Building for Qt4...")
 163     set(QT_MIN_VERSION "4.8.0")
 164
 165     # Select a Qt installation here, if you don't want to use system Qt
 166     if(QT_PATH)
 167         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 168         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 169     endif()
 170 endif()
 171
 172
 173 # Find package dependencies
 174 #
 175 # Note that you can forcefully disable optional packages
 176 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 177 #####################################################################
 178
 179 if (USE_QT5)
 180     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 181     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 182         URL "http://qt.digia.com"
 183         DESCRIPTION "contains core functionality for Qt"
 184     )
 185     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 186     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 187     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 188         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 189     endif()
 190
 191     find_package(Qt5Network QUIET)
 192     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 193         DESCRIPTION "the network module for Qt5"
 194     )
 195
 196     if (BUILD_GUI)
 197         find_package(Qt5Gui QUIET)
 198         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 199             DESCRIPTION "the GUI module for Qt5"
 200         )
 201         find_package(Qt5Widgets QUIET)
 202         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 203             DESCRIPTION "the widgets module for Qt5"
 204         )
 205
 206         find_package(Qt5DBus QUIET)
 207         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 208             URL "http://qt.digia.com"
 209             DESCRIPTION "D-Bus support for Qt5"
 210             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 211         )
 212         if (Qt5DBus_FOUND)
 213             find_package(dbusmenu-qt5 QUIET CONFIG)
 214             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 215                 URL "https://launchpad.net/libdbusmenu-qt"
 216                 DESCRIPTION "a library implementing the DBusMenu specification"
 217                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 218             )
 219         endif()
 220
 221         find_package(Phonon4Qt5 QUIET)
 222         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 223             URL "https://projects.kde.org/projects/kdesupport/phonon"
 224             DESCRIPTION "a multimedia abstraction library"
 225             PURPOSE     "Required for audio notifications"
 226         )
 227
 228         find_package(LibsnoreQt5 0.7.0 QUIET)
 229         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 230             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 231             DESCRIPTION "a cross-platform notification framework"
 232             PURPOSE     "Enable support for the snorenotify framework"
 233         )
 234         if(LibsnoreQt5_FOUND)
 235             find_package(LibsnoreSettingsQt5)
 236             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 237                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 238                 DESCRIPTION "a cross-platform notification framework"
 239                 PURPOSE     "Enable support for the snorenotify framework"
 240             )
 241         endif()
 242
 243
 244         if (WITH_WEBKIT)
 245             find_package(Qt5WebKit QUIET)
 246             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 247                 URL "http://qt.digia.com"
 248                 DESCRIPTION "a WebKit implementation for Qt"
 249                 PURPOSE     "Needed for displaying previews for URLs in chat"
 250             )
 251             if (Qt5WebKit_FOUND)
 252                 find_package(Qt5WebKitWidgets QUIET)
 253                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 254                     URL "http://qt.digia.com"
 255                     DESCRIPTION "widgets for Qt's WebKit implementation"
 256                     PURPOSE     "Needed for displaying previews for URLs in chat"
 257                 )
 258             endif()
 259         endif()
 260
 261         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 262             set(HAVE_WEBKIT true)
 263         endif()
 264         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 265
 266         if (WITH_WEBENGINE)
 267             find_package(Qt5WebEngine QUIET)
 268             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 269                 URL "http://qt.digia.com"
 270                 DESCRIPTION "a WebEngine implementation for Qt"
 271                 PURPOSE     "Needed for displaying previews for URLs in chat"
 272             )
 273             if (Qt5WebEngine_FOUND)
 274                 find_package(Qt5WebEngineWidgets QUIET)
 275                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 276                     URL "http://qt.digia.com"
 277                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 278                     PURPOSE     "Needed for displaying previews for URLs in chat"
 279                 )
 280             endif()
 281         endif()
 282
 283         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 284             set(HAVE_WEBENGINE true)
 285         endif()
 286         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 287
 288         # KDE Frameworks
 289         ################
 290
 291         if (WITH_KDE)
 292             set(ecm_find_type "REQUIRED")
 293         else()
 294             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 295             set(ecm_find_type "RECOMMENDED")
 296         endif()
 297
 298         # extra-cmake-modules
 299         find_package(ECM NO_MODULE QUIET)
 300         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 301             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 302             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 303             PURPOSE     "Required to find KDE Frameworks components"
 304         )
 305
 306         if (ECM_FOUND)
 307             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 308         endif()
 309
 310         if (WITH_KDE)
 311             find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 312             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 313                 URL "http://www.kde.org"
 314                 DESCRIPTION "KDE Frameworks"
 315                 PURPOSE     "Required for integration into the Plasma desktop"
 316             )
 317
 318         endif()
 319
 320     endif(BUILD_GUI)
 321
 322     if (BUILD_CORE)
 323         find_package(Qt5Script QUIET)
 324         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 325             DESCRIPTION "provides scripting support for Qt5"
 326         )
 327         find_package(Qt5Sql QUIET)
 328         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 329             DESCRIPTION "the database support module for Qt5"
 330         )
 331
 332         find_package(QCA2-QT5)
 333         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 334             URL "https://projects.kde.org/projects/kdesupport/qca"
 335             DESCRIPTION "Qt Cryptographic Architecture"
 336             PURPOSE "Required for encryption support"
 337         )
 338
 339     endif(BUILD_CORE)
 340
 341     find_package(Qt5LinguistTools QUIET)
 342     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 343                            DESCRIPTION "contains tools for handling translation files"
 344                            PURPOSE "Required for having translations"
 345     )
 346
 347     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 348     if (Qt5LinguistTools_FOUND)
 349         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 350             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 351             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 352             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 353         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 354             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 355             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 356         endif()
 357
 358         # Compatibility with the Qt4 variables
 359         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 360         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 361         if (Qt5_LCONVERT_EXECUTABLE)
 362             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 363         endif()
 364     endif()
 365
 366 else(USE_QT5)
 367     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 368
 369     if (BUILD_GUI)
 370         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 371         if (QT_QTDBUS_FOUND)
 372             find_package(dbusmenu-qt QUIET CONFIG)
 373             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 374                 URL "https://launchpad.net/libdbusmenu-qt"
 375                 DESCRIPTION "a library implementing the DBusMenu specification"
 376                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 377             )
 378         endif()
 379
 380         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 381             set(HAVE_WEBKIT true)
 382         endif()
 383         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 384
 385         if (WITH_KDE)
 386             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 387             set(_cflags ${CMAKE_C_FLAGS})
 388             find_package(KDE4 4.4 QUIET)
 389             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 390                 URL "http://www.kde.org"
 391                 DESCRIPTION "a world-class desktop environment"
 392                 PURPOSE "Enables various bits for improving integration with KDE"
 393             )
 394             set(CMAKE_C_FLAGS ${_cflags})
 395
 396         else(WITH_KDE)
 397             find_package(Phonon QUIET)
 398             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 399                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 400                 DESCRIPTION "a multimedia abstraction library"
 401                 PURPOSE     "Required for audio notifications"
 402             )
 403         endif(WITH_KDE)
 404
 405         find_package(IndicateQt QUIET)
 406         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 407             URL "https://launchpad.net/libindicate-qt/"
 408             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 409             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 410         )
 411
 412     endif(BUILD_GUI)
 413
 414     if (BUILD_CORE)
 415
 416         find_package(QCA2 QUIET)
 417         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 418             URL "https://projects.kde.org/projects/kdesupport/qca"
 419             DESCRIPTION "Qt Cryptographic Architecture"
 420             PURPOSE     "Required for encryption support"
 421         )
 422
 423
 424     endif()
 425
 426     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 427     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 428     if (QT_LRELEASE_EXECUTABLE)
 429         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 430         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 431     endif()
 432 endif()
 433
 434
 435 # Non-Qt-based packages
 436
 437 # zlib for compression, however we can always fall back to miniz
 438 find_package(ZLIB QUIET)
 439 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 440     URL "http://www.zlib.net"
 441     DESCRIPTION "a popular compression library"
 442     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 443 )
 444
 445
 446 if (NOT WIN32)
 447     # Execinfo is needed for generating backtraces
 448     find_package(ExecInfo QUIET)
 449     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 450         DESCRIPTION "a library for inspecting backtraces"
 451         PURPOSE "Used for generating backtraces in case of a crash"
 452     )
 453 endif()
 454
 455 # Check for SSL support in Qt
 456 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 457 # a small test program checking the defines. This works for both Qt4 and Qt5.
 458 cmake_push_check_state(RESET)
 459 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 460 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 461
 462 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 463     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 464 endif()
 465
 466 check_cxx_source_compiles("
 467     #include \"qglobal.h\"
 468     #if defined QT_NO_SSL
 469     #  error \"No SSL support\"
 470     #endif
 471     int main() {}"
 472     HAVE_SSL)
 473 cmake_pop_check_state()
 474
 475 # Additional compile settings
 476 #####################################################################
 477
 478 # This sets -fPIC and friends if required by the installed Qt5 library
 479 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 480     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 481 endif()
 482
 483 # Needed to compile with mingw without kde
 484 if (MINGW AND NOT KDE4_FOUND)
 485     add_definitions(-D_WIN32_WINNT=0x0500)
 486     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 487     # workaround for bug in mingw gcc 4.0
 488     add_definitions(-U__STRICT_ANSI__)
 489 endif()
 490
 491 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 492 if (CMAKE_COMPILER_IS_GNUCXX)
 493     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 494 endif()
 495
 496
 497 # Setup KDE / KDE Frameworks
 498 #####################################################################
 499
 500 # We want to do this up here, so we have the necessary variables and defines set before
 501 # compiling anything
 502
 503 if (KDE4_FOUND)
 504     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 505     set(EMBED_DATA OFF)
 506
 507     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 508     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 509     set(WITH_KDE4 TRUE)
 510 endif()
 511
 512 if (USE_QT5 AND WITH_KDE)
 513     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 514     set(EMBED_DATA OFF)
 515
 516     include(KDEInstallDirs)
 517     include(KDECompilerSettings)
 518     include(KDECMakeSettings)
 519
 520     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 521     set(WITH_KF5 TRUE)
 522 endif()
 523
 524 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 525 include(QuasselInstallDirs)
 526
 527 # Various config-dependent checks and settings
 528 #####################################################################
 529
 530 if (NOT ZLIB_FOUND)
 531     message(STATUS "zlib NOT found, using bundled miniz for compression")
 532     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 533         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 534     endif()
 535 endif()
 536
 537 if (HAVE_SSL)
 538     add_definitions(-DHAVE_SSL)
 539 endif()
 540 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 541
 542 # Check for syslog support
 543 if (NOT WIN32)
 544     check_include_file(syslog.h HAVE_SYSLOG)
 545     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 546 endif()
 547
 548 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 549
 550 if (EMBED_DATA)
 551     message(STATUS "Embedding data files into the binary")
 552 else()
 553     message(STATUS "Installing data files separately")
 554 endif()
 555
 556 if (INDICATEQT_FOUND)
 557     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 558 endif()
 559
 560 if (NOT WIN32)
 561     check_function_exists(umask HAVE_UMASK)
 562     if(HAVE_UMASK)
 563         add_definitions(-DHAVE_UMASK)
 564     endif(HAVE_UMASK)
 565 endif()
 566
 567
 568 # Windows-specific stuff
 569 #####################################################################
 570
 571 if (WIN32)
 572     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 573     if (MSVC)
 574         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 575         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 576         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 577         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 578         link_libraries(Version dwmapi shlwapi)
 579         if (USE_QT5)
 580             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 581         endif()
 582     endif()
 583     if(HAVE_SSL AND STATIC)
 584         find_package(OpenSSL REQUIRED)
 585         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 586     endif()
 587 endif()
 588
 589
 590 # Static builds (very much non-portable, so don't use -DSTATIC
 591 # unless you know what you do!)
 592 #####################################################################
 593
 594 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 595     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 596     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 597     if (HAVE_SSL)
 598         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 599     endif()
 600 endif()
 601
 602
 603 # Generate version information from Git
 604 #####################################################################
 605
 606 include(GetGitRevisionDescription)
 607 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 608 git_describe(GIT_DESCRIBE --long)
 609
 610 # If in a Git repo we can get the commit-date from a git command
 611 if (GIT_HEAD)
 612     execute_process(
 613         COMMAND git show -s --format=%ct
 614         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 615         OUTPUT_VARIABLE GIT_COMMIT_DATE
 616         OUTPUT_STRIP_TRAILING_WHITESPACE
 617     )
 618 endif()
 619
 620 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 621 # enviroment
 622 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 623   if (DEFINED ENV{GIT_HEAD})
 624       set(GIT_HEAD $ENV{GIT_HEAD})
 625   endif ()
 626   if (DEFINED ENV{GIT_DESCRIBE})
 627      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 628   endif()
 629 endif()
 630
 631 # Sanitize things if we're not in a Git repo
 632 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 633     set(GIT_HEAD "")
 634     set(GIT_DESCRIBE "")
 635     set(GIT_COMMIT_DATE 0)
 636 endif()
 637
 638 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 639
 640 # Prepare the build
 641 #####################################################################
 642
 643 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 644 set(COMMON_DEPS ${RC_WIN32})
 645 set(CORE_DEPS )
 646 set(CLIENT_DEPS )
 647
 648 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 649 add_subdirectory(data)
 650 add_subdirectory(icons)
 651 add_subdirectory(pics)
 652 add_subdirectory(po)
 653
 654
 655 # Set up and display feature summary
 656 #####################################################################
 657
 658 feature_summary(WHAT ALL
 659                 INCLUDE_QUIET_PACKAGES
 660                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 661 )
 662
 663 # Finally, compile the sources
 664 # We want this after displaying the feature summary to avoid ugly
 665 # CMake backtraces in case a required Qt5 module is missing
 666 #####################################################################
 667
 668 add_subdirectory(src)