CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   5 #                     : select binaries to build
   6 # -DWITH_OPENSSL=OFF  : Disable OpenSSL support
   7 # -DWITH_DBUS=OFF     : Disable D-Bus support (dbus notifications)
   8 # -DWITH_WEBKIT=OFF   : Disable WebKit support (link previews)
   9 # -DWITH_PHONON=OFF   : Disable Phonon support (audio notifications)
  10 # -DWITH_KDE=ON       : Enable KDE4 support
  11 #
  12 # -DEMBED_DATA=ON     : Embed all data files in icons the binary, rather than installing them separately
  13 #
  14 # -DQT=/path/to/qt    : Choose a Qt4 installation to use instead of the system Qt4
  15 # -DSTATIC=ON         : Enable static building of Quassel. Use with care.
  16 # -DDEPLOY=ON         : Mac OS X only. Use only for creating Quassel Packages!
  17 #
  18 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  19
  20 project(QuasselIRC)
  21
  22 cmake_minimum_required(VERSION 2.6.0 FATAL_ERROR)
  23
  24 if(COMMAND cmake_policy)
  25    cmake_policy(SET CMP0003 NEW)
  26 endif(COMMAND cmake_policy)
  27
  28 # Use our own (well, and KDE's) version of some modules
  29 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  30 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  31 include(QuasselMacros)
  32
  33 # Various options and variables that can be set on the command line
  34 option(WANT_CORE     "Build the core (server) binary"           ON)
  35 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  36 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  37
  38 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  39 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  40 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  41 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  42 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  43
  44 # We use icon paths from KDE 4.3 trunk, which are partially invalid on older and possibly
  45 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  46 # run on a matching KDE version only.
  47 option(WITH_OXYGEN   "Install Oxygen icons. Heavily recommended unless you use KDE 4.3" ON)
  48
  49 option(STATIC        "Enable static building (might not be portable)" OFF)
  50
  51 if(APPLE)
  52   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  53 endif(APPLE)
  54
  55 # Default to embedding data in the static case
  56 if(STATIC OR WIN32)
  57   set(EMBED_DEFAULT ON)
  58 else(STATIC OR WIN32)
  59   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  60 endif(STATIC OR WIN32)
  61
  62 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  63
  64 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  65 set(LINGUAS "" CACHE STRING "Comma-separated list of locales specifying languages that should be compiled")
  66
  67 # Some settings imply others
  68 if(STATIC)
  69   add_definitions(-DSTATIC)
  70   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  71 endif(STATIC)
  72
  73 if(WIN32)
  74   # We don't support separately installed resources yet on Win32
  75   set(EMBED_DATA ON)
  76 endif(WIN32)
  77
  78 # For static builds, arbitrary extra libs might need to be linked
  79 # Define a comma-separated list here
  80 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
  81 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
  82 string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
  83 link_libraries(${LINK_EXTRA})
  84
  85 # Build Type
  86 # We need to make sure it's not empty
  87 # Supported: Release, RelWithDebugInfo, Debug, Debugfull
  88
  89 # On WIN32, only Release seems to work correctly (?)
  90 if(WIN32)
  91   set(DEFAULT_BUILD_TYPE "Release")
  92 else(WIN32)
  93   set(DEFAULT_BUILD_TYPE "RelWithDebugInfo")
  94 endif(WIN32)
  95
  96 set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type")
  97 if(NOT CMAKE_BUILD_TYPE)
  98   set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type" FORCE)
  99 endif(NOT CMAKE_BUILD_TYPE)
 100
 101 # Enable various flags on gcc
 102 if(CMAKE_COMPILER_IS_GNUCXX)
 103   # Let's just hope that all gccs support these options and skip the tests...
 104   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor")
 105   set(CMAKE_CXX_FLAGS_RELWITHDEBUGINFO "-O2")
 106   set(CMAKE_CXX_FLAGS_DEBUG "-g -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 107   set(CMAKE_CXX_FLAGS_DEBUGFULL "-g3")
 108 endif(CMAKE_COMPILER_IS_GNUCXX)
 109
 110 set(QT_MIN_VERSION "4.4.0")
 111
 112 if(APPLE AND DEPLOY)
 113   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
 114   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
 115   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
 116   add_definitions(-DMAC_10_4_SDK)
 117 endif(APPLE AND DEPLOY)
 118
 119 # Execinfo is needed for generating backtraces
 120 find_package(ExecInfo)
 121 if(EXECINFO_FOUND)
 122   add_definitions(-DHAVE_EXECINFO)
 123   include_directories(${EXECINFO_INCLUDES})
 124   link_libraries(${EXECINFO_LIBRARIES})
 125 endif(EXECINFO_FOUND)
 126
 127 # Select a Qt installation here, if you don't want to use system Qt
 128 if(QT)
 129   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 130   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 131 endif(QT)
 132
 133 # Now that we have the correct $PATH, lets find Qt!
 134 find_package(Qt4 REQUIRED)
 135
 136 set(QT_DONT_USE_QTGUI 1)
 137 include(${QT_USE_FILE})
 138 include_directories(${QT_INCLUDES})
 139
 140 # Setup OpenSSL
 141 if(WITH_OPENSSL)
 142   find_package(OpenSSL)
 143 else(WITH_OPENSSL)
 144   message(STATUS "Disabling OpenSSL support")
 145 endif(WITH_OPENSSL)
 146
 147 if(OPENSSL_FOUND)
 148   if(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 149     message(STATUS "Found OpenSSL support in Qt")
 150     add_definitions(-DHAVE_SSL)
 151     set(HAVE_SSL true)
 152     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_SSL)
 153   else(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 154     message(STATUS "No OpenSSL support found in Qt, disabling")
 155   endif(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 156 else(OPENSSL_FOUND)
 157   add_definitions(-DQT_NO_OPENSSL)
 158 endif(OPENSSL_FOUND)
 159
 160 # Setup D-Bus support
 161 if(WITH_DBUS)
 162   if(QT_QTDBUS_FOUND)
 163     message(STATUS "Found QtDBus, enabling D-Bus support")
 164     add_definitions(-DHAVE_DBUS)
 165     set(LINK_DBUS DBUS)
 166     set(HAVE_DBUS true)
 167     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_DBUS)
 168   else(QT_QTDBUS_FOUND)
 169     message(STATUS "QtDBus not found, disabling D-Bus support")
 170   endif(QT_QTDBUS_FOUND)
 171 else(WITH_DBUS)
 172   message(STATUS "Disabling D-Bus support")
 173 endif(WITH_DBUS)
 174
 175 # Setup QtWebKit support
 176 if(WITH_WEBKIT)
 177   if(QT_QTWEBKIT_FOUND)
 178     message(STATUS "Found QtWebKit, enabling WebKit support")
 179     add_definitions(-DHAVE_WEBKIT)
 180     set(LINK_WEBKIT WEBKIT)
 181     set(HAVE_WEBKIT true)
 182     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_WEBKIT)
 183   else(QT_QTWEBKIT_FOUND)
 184     message(STATUS "QtWebKit not found, disabling WebKit support")
 185   endif(QT_QTWEBKIT_FOUND)
 186 else(WITH_WEBKIT)
 187   message(STATUS "Disabling WebKit support")
 188 endif(WITH_WEBKIT)
 189
 190 # Setup KDE4 support
 191 if(WITH_KDE)
 192   find_package(KDE4)
 193   if(KDE4_FOUND)
 194     message(STATUS "Enabling KDE4 integration")
 195     include_directories(${KDE4_INCLUDES})
 196     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 197     set(HAVE_KDE 1)
 198     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_KDE)
 199     set(QUASSEL_KDE_LIBRARIES ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} knotifyconfig)
 200     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 201     set(EMBED_DATA OFF)
 202   else(KDE4_FOUND)
 203     message(STATUS "KDE4 not found, disabling KDE integration")
 204   endif(KDE4_FOUND)
 205 else(WITH_KDE)
 206   message(STATUS "Disabling KDE4 integration")
 207 endif(WITH_KDE)
 208
 209 # Setup Phonon support - we only need this if we don't have or want KDE4
 210 if(NOT HAVE_KDE)
 211   if(WITH_PHONON)
 212     find_package(Phonon)
 213     if(PHONON_FOUND)
 214       message(STATUS "Enabling Phonon support")
 215       add_definitions(-DHAVE_PHONON)
 216       set(HAVE_PHONON true)
 217       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_PHONON)
 218     else(PHONON_FOUND)
 219       message(STATUS "Phonon not found, disabling audio notifications")
 220     endif(PHONON_FOUND)
 221   else(WITH_PHONON)
 222     message(STATUS "Disabling Phonon support")
 223   endif(WITH_PHONON)
 224 endif(NOT HAVE_KDE)
 225
 226 # Now set up install locations; those are set by KDE if integration is enabled
 227 if(NOT HAVE_KDE)
 228   if(WIN32)
 229     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 230     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 231     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 232     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 233   else(WIN32)
 234     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 235     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 236     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 237     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 238   endif(WIN32)
 239 endif(NOT HAVE_KDE)
 240
 241 # RPATH needs to be set correctly
 242 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 243 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 244 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 245
 246 # Set global buildflags
 247 # This is very much non-portable, so don't use -DSTATIC until you know what
 248 # you do.
 249 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 250   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 251   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 252   if(HAVE_SSL)
 253     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 254   endif(HAVE_SSL)
 255 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 256
 257 if(WIN32)
 258   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 259
 260   if(HAVE_SSL)
 261      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 262   endif(HAVE_SSL)
 263 endif(WIN32)
 264
 265 if(STATIC)
 266   link_directories(${QT_PLUGINS_DIR}/imageformats)
 267   link_libraries(qjpeg qgif)
 268 endif(STATIC)
 269
 270 # We need to create a version.gen
 271 # For this, we create our genversion binary and make sure it is run every time.
 272 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 273 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
 274
 275 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 276 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 277                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 278 add_dependencies(genversion_run genversion)
 279
 280 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 281 set(COMMON_DEPS ${RC_WIN32})
 282 set(CORE_DEPS )
 283 set(CLIENT_DEPS )
 284
 285 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 286 add_subdirectory(data)
 287 add_subdirectory(icons)
 288 add_subdirectory(pics)
 289 add_subdirectory(i18n)
 290 add_subdirectory(src)