CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 11)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.11-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37
  38 # Options and variables that can be set on the command line
  39 #####################################################################
  40
  41 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  42 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  43 if (USE_QT4) # takes precedence
  44     set(USE_QT5 OFF)
  45 else()
  46     if (NOT USE_QT5)
  47         set(USE_QT4 ON)
  48     endif()
  49 endif()
  50
  51 # Select the binaries to build
  52 option(WANT_CORE     "Build the core (server) binary"           ON)
  53 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  54 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  55 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  56 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  57 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  58
  59 # Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
  60 cmake_dependent_option(WITH_KDE "KDE4 integration" OFF "USE_QT4" OFF)
  61 add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  62
  63 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  64 if (NOT WITH_KDE)
  65     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  66 endif()
  67
  68 # For this, the feature info is added after we know if QtWebkit is installed
  69 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  70
  71 if (APPLE)
  72     # Notification Center is only available in > 10.8, which is Darwin v12
  73     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  75         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  76     endif()
  77 endif()
  78
  79 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  80 set(EMBED_DEFAULT OFF)
  81 if (STATIC OR WIN32 OR APPLE)
  82     set(EMBED_DEFAULT ON)
  83 endif()
  84 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  85                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  86 if (NOT EMBED_DEFAULT)
  87     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  88 endif()
  89
  90 # The following options are not for end-user consumption, so don't list them in the feature summary
  91 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  92
  93 # Handle with care
  94 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
  95
  96 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
  97 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
  98
  99 # For static builds, arbitrary extra libs might need to be linked
 100 # Define a comma-separated list here
 101 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 102 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 103 if (LINK_EXTRA)
 104     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 105     link_libraries(${LINK_EXTRA})
 106 endif()
 107
 108
 109 # Simplify later checks
 110 #####################################################################
 111
 112 if (WANT_MONO OR WANT_QTCLIENT)
 113     set(BUILD_GUI true)
 114 endif()
 115 if (WANT_MONO OR WANT_CORE)
 116     set(BUILD_CORE true)
 117 endif()
 118
 119
 120 # Set up Qt
 121 #####################################################################
 122
 123 if (USE_QT5)
 124     message(STATUS "Building for Qt5...")
 125     set(QT_MIN_VERSION "5.2.0")
 126     add_definitions(-DHAVE_QT5)
 127 else()
 128     message(STATUS "Building for Qt4...")
 129     if (BUILD_GUI)
 130         set(QT_MIN_VERSION "4.6.0")
 131     else()
 132         set(QT_MIN_VERSION "4.4.0")
 133     endif()
 134
 135     # Select a Qt installation here, if you don't want to use system Qt
 136     if(QT_PATH)
 137         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 138         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 139     endif()
 140 endif()
 141
 142 # Find package dependencies
 143 #
 144 # Note that you can forcefully disable optional packages
 145 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 146 #####################################################################
 147
 148 if (USE_QT5)
 149     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 150     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 151         URL "http://qt.digia.com"
 152         DESCRIPTION "contains core functionality for Qt"
 153     )
 154     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 155     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 156     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 157         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 158     endif()
 159
 160     find_package(Qt5Network QUIET)
 161     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 162         DESCRIPTION "the network module for Qt5"
 163     )
 164
 165     if (BUILD_GUI)
 166         find_package(Qt5Gui QUIET)
 167         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 168             DESCRIPTION "the GUI module for Qt5"
 169         )
 170         find_package(Qt5Widgets QUIET)
 171         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 172             DESCRIPTION "the widgets module for Qt5"
 173         )
 174
 175         find_package(Qt5DBus QUIET)
 176         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 177             URL "http://qt.digia.com"
 178             DESCRIPTION "D-Bus support for Qt5"
 179             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 180         )
 181         if (Qt5DBus_FOUND)
 182             find_package(dbusmenu-qt5 QUIET CONFIG)
 183             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 184                 URL "https://launchpad.net/libdbusmenu-qt"
 185                 DESCRIPTION "a library implementing the DBusMenu specification"
 186                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 187             )
 188         endif()
 189
 190         find_package(Phonon4Qt5 QUIET)
 191         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 192             URL "https://projects.kde.org/projects/kdesupport/phonon"
 193             DESCRIPTION "a multimedia abstraction library"
 194             PURPOSE     "Required for audio notifications"
 195         )
 196
 197         find_package(LibsnoreQt5 QUIET)
 198         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 199             URL "https://github.com/TheOneRing/Snorenotify"
 200             DESCRIPTION "a cross-platform notification framework"
 201             PURPOSE     "Enable support for the snorenotify framework"
 202         )
 203
 204         if (WITH_WEBKIT)
 205             find_package(Qt5WebKit QUIET)
 206             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 207                 URL "http://qt.digia.com"
 208                 DESCRIPTION "a WebKit implementation for Qt"
 209                 PURPOSE     "Needed for displaying previews for URLs in chat"
 210             )
 211             if (Qt5WebKit_FOUND)
 212                 find_package(Qt5WebKitWidgets QUIET)
 213                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 214                     URL "http://qt.digia.com"
 215                     DESCRIPTION "widgets for Qt's WebKit implementation"
 216                     PURPOSE     "Needed for displaying previews for URLs in chat"
 217                 )
 218             endif()
 219         endif()
 220         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 221
 222     endif(BUILD_GUI)
 223     if (BUILD_CORE)
 224         find_package(Qt5Script QUIET)
 225         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 226             DESCRIPTION "provides scripting support for Qt5"
 227         )
 228         find_package(Qt5Sql QUIET)
 229         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 230             DESCRIPTION "the database support module for Qt5"
 231         )
 232
 233         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 234         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 235         #find_package(QCA2 QUIET)
 236         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 237         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 238         #    DESCRIPTION "Qt Cryptographic Architecture"
 239         #    PURPOSE "Required for encryption support"
 240         #)
 241
 242     endif(BUILD_CORE)
 243
 244     find_package(Qt5LinguistTools QUIET)
 245     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 246                            DESCRIPTION "contains tools for handling translation files"
 247                            PURPOSE "Required for having translations"
 248     )
 249     # Qt5 does not define a target for lconvert, so we need to find it ourselves
 250     if (Qt5LinguistTools_FOUND)
 251         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 252             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 253             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 254             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 255         endif()
 256         # Compatibility with the Qt4 variables
 257         set (QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 258         set (QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 259     endif()
 260
 261 else(USE_QT5)
 262     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 263
 264     if (BUILD_GUI)
 265         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 266         if (QT_QTDBUS_FOUND)
 267             find_package(dbusmenu-qt QUIET CONFIG)
 268             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 269                 URL "https://launchpad.net/libdbusmenu-qt"
 270                 DESCRIPTION "a library implementing the DBusMenu specification"
 271                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 272             )
 273         endif()
 274
 275         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 276             set(HAVE_WEBKIT true)
 277         endif()
 278         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 279
 280         if (WITH_KDE)
 281             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 282             set(_cflags ${CMAKE_C_FLAGS})
 283             find_package(KDE4 4.4 QUIET)
 284             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 285                 URL "http://www.kde.org"
 286                 DESCRIPTION "a world-class desktop environment"
 287                 PURPOSE "Enables various bits for improving integration with KDE"
 288             )
 289             set(CMAKE_C_FLAGS ${_cflags})
 290
 291         else(WITH_KDE)
 292             find_package(Phonon QUIET)
 293             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 294                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 295                 DESCRIPTION "a multimedia abstraction library"
 296                 PURPOSE     "Required for audio notifications"
 297             )
 298
 299             find_package(Libsnore QUIET)
 300             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 301                 URL "https://github.com/TheOneRing/Snorenotify"
 302                 DESCRIPTION "a cross-platform notification framework"
 303                 PURPOSE     "Enable support for the snorenotify framework"
 304             )
 305         endif(WITH_KDE)
 306
 307         find_package(IndicateQt QUIET)
 308         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 309             URL "https://launchpad.net/libindicate-qt/"
 310             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 311             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 312         )
 313
 314     endif(BUILD_GUI)
 315     if (BUILD_CORE)
 316
 317         find_package(QCA2 QUIET)
 318         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 319             URL "https://projects.kde.org/projects/kdesupport/qca"
 320             DESCRIPTION "Qt Cryptographic Architecture"
 321             PURPOSE     "Required for encryption support"
 322         )
 323
 324
 325     endif()
 326
 327     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 328     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 329     if (QT_LRELEASE_EXECUTABLE)
 330         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 331         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 332     endif()
 333 endif()
 334
 335
 336 # Non-Qt-based packages
 337
 338 # zlib for compression, however we can always fall back to miniz
 339 find_package(ZLIB QUIET)
 340 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 341     URL "http://www.zlib.net"
 342     DESCRIPTION "a popular compression library"
 343     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 344 )
 345
 346
 347 if (NOT WIN32)
 348     # Execinfo is needed for generating backtraces
 349     find_package(ExecInfo QUIET)
 350     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 351         DESCRIPTION "a library for inspecting backtraces"
 352         PURPOSE "Used for generating backtraces in case of a crash"
 353     )
 354 endif()
 355
 356
 357 # Various checks
 358 #####################################################################
 359
 360 if (NOT ZLIB_FOUND)
 361     message(STATUS "zlib NOT found, using bundled miniz for compression")
 362     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 363         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 364     endif()
 365 endif()
 366
 367 if (KDE4_FOUND)
 368     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 369     set(EMBED_DATA OFF)
 370
 371     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 372     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 373 endif()
 374
 375 # Check for SSL support in Qt
 376 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 377 # a small test program checking the defines. This works for both Qt4 and Qt5.
 378 cmake_push_check_state(RESET)
 379 if (Qt5_POSITION_INDEPENDENT_CODE)
 380     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 381 endif()
 382 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 383 check_cxx_source_compiles("
 384     #include \"qglobal.h\"
 385     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 386     #  error \"No SSL support\"
 387     #endif
 388     int main() {}"
 389     HAVE_SSL)
 390 cmake_pop_check_state()
 391
 392 if (HAVE_SSL)
 393     add_definitions(-DHAVE_SSL)
 394 endif()
 395 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 396
 397 # Check for syslog support
 398 if (NOT WIN32)
 399     check_include_file(syslog.h HAVE_SYSLOG)
 400     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 401 endif()
 402
 403 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 404
 405 # Various settings
 406 ##################
 407
 408 # needed to compile with mingw without kde
 409 if (MINGW AND NOT KDE4_FOUND)
 410     add_definitions(-D_WIN32_WINNT=0x0500)
 411     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 412 # workaround for bug in mingw gcc 4.0
 413     add_definitions(-U__STRICT_ANSI__)
 414 endif()
 415
 416 # Now set up install locations; those are set by KDE if integration is enabled
 417 if(NOT KDE4_FOUND)
 418   if(WIN32)
 419     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 420     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 421     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 422     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 423   else(WIN32)
 424     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 425     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 426     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 427     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 428   endif(WIN32)
 429 endif()
 430
 431 if(EMBED_DATA)
 432   message(STATUS "Embedding data files into the binary")
 433 else(EMBED_DATA)
 434   message(STATUS "Installing data files separately")
 435 endif(EMBED_DATA)
 436
 437 # RPATH needs to be set correctly
 438 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 439 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 440 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 441
 442 # Set global buildflags
 443 # This is very much non-portable, so don't use -DSTATIC until you know what
 444 # you do.
 445 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 446   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 447   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 448   if(HAVE_SSL)
 449     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 450   endif(HAVE_SSL)
 451 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 452
 453 if(WIN32)
 454   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 455   if(MSVC)
 456     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 457     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 458     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 459     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 460     link_libraries(Version dwmapi shlwapi)
 461     if(USE_QT5)
 462       set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 463     endif(USE_QT5)
 464   endif(MSVC)
 465   if(HAVE_SSL AND STATIC)
 466      find_package(OpenSSL REQUIRED)
 467      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 468   endif(HAVE_SSL AND STATIC)
 469 endif(WIN32)
 470
 471 if(INDICATEQT_FOUND)
 472   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 473 endif()
 474
 475 if(NOT WIN32)
 476   check_function_exists(umask HAVE_UMASK)
 477   if(HAVE_UMASK)
 478     add_definitions(-DHAVE_UMASK)
 479   endif(HAVE_UMASK)
 480 endif(NOT WIN32)
 481
 482 # Generate version information from Git
 483 include(GetGitRevisionDescription)
 484 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 485 git_describe(GIT_DESCRIBE --long)
 486
 487 # Sanitize things if we're not in a Git repo
 488 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 489     set(GIT_HEAD "")
 490     set(GIT_DESCRIBE "")
 491 endif()
 492
 493 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 494
 495 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 496 set(COMMON_DEPS ${RC_WIN32})
 497 set(CORE_DEPS )
 498 set(CLIENT_DEPS )
 499
 500 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 501 add_subdirectory(data)
 502 add_subdirectory(icons)
 503 add_subdirectory(pics)
 504 add_subdirectory(po)
 505
 506 # Set up and display feature summary
 507 #####################################################################
 508
 509 feature_summary(WHAT ALL
 510                 INCLUDE_QUIET_PACKAGES
 511                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 512 )
 513
 514 # Finally, compile the sources
 515 # We want this after displaying the feature summary to avoid ugly
 516 # CMake backtraces in case a required Qt5 modules misses
 517 #####################################################################
 518
 519 add_subdirectory(src)