CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 3.5)
  10
  11 # Tell CMake about or own modules
  12 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  13
  14 include(QuasselVersion)
  15
  16 message(STATUS "Using CMake ${CMAKE_VERSION}")
  17
  18 # Set up build type rather early
  19 include(BuildType)
  20
  21 # Support ccache if found
  22 # This should happen before calling project(), so compiler settings are validated.
  23 option(USE_CCACHE "Enable support for ccache if available" ON)
  24 if (USE_CCACHE)
  25     message(STATUS "Checking for ccache")
  26     find_program(CCACHE_PROGRAM ccache)
  27     if (CCACHE_PROGRAM)
  28         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  29         message(STATUS "Checking for ccache - enabled")
  30     else()
  31         message(STATUS "Checking for ccache - not found")
  32     endif()
  33 endif()
  34
  35 # Set up project
  36 project(Quassel CXX)
  37
  38 # Let CMake handle file generation for Qt
  39 set(CMAKE_AUTOMOC ON)
  40 set(CMAKE_AUTORCC ON)
  41 set(CMAKE_AUTOUIC ON)
  42
  43 # Needed, otherwise some .moc files won't be found with older CMake versions
  44 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  45
  46 # Include various CMake modules...
  47 include(CMakePushCheckState)
  48 include(CheckFunctionExists)
  49 include(CheckIncludeFileCXX)
  50 include(CheckCXXSourceCompiles)
  51 include(CMakeDependentOption)
  52 include(FeatureSummary)
  53
  54 # ... and our own
  55 include(QuasselCompileSettings)
  56 include(QuasselMacros)
  57
  58 # Options and variables that can be set on the command line
  59 #####################################################################
  60
  61 # Select the binaries to build
  62 option(WANT_CORE     "Build the core (server) binary"           ON)
  63 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  64 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  65 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  66 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  67 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  68
  69 # Whether to enable integration with higher-tier KDE frameworks that require runtime support.
  70 # We still optionally make use of certain Tier 1 frameworks even if WITH_KDE is disabled.
  71 option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  72 add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  73
  74 # Icon theme support. By default, install the Breeze icon theme (may be disabled if a system installation is present)
  75 option(WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme" ON)
  76 add_feature_info(WITH_BUNDLED_ICONS WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme")
  77
  78 option(WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)" OFF)
  79 add_feature_info(WITH_OXYGEN_ICONS WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)")
  80
  81 # For this, the feature info is added after we know if QtWebkit is installed
  82 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  83
  84 # For this, the feature info is added after we know if QtWebEngine is installed
  85 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  86
  87 if (APPLE)
  88     # Notification Center is only available in > 10.8, which is Darwin v12
  89     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
  90         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  91         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  92     endif()
  93     find_library(CARBON_LIBRARY Carbon)
  94     mark_as_advanced(CARBON_LIBRARY)
  95     link_libraries(${CARBON_LIBRARY})
  96 endif()
  97
  98 # Always embed on Windows or OSX; never embed when enabling KDE integration
  99 set(EMBED_DEFAULT OFF)
 100 if (WIN32 OR APPLE)
 101     set(EMBED_DEFAULT ON)
 102 endif()
 103 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 104                                    "NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 105 if (NOT EMBED_DEFAULT)
 106     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 107 endif()
 108
 109 # The following options are not for end-user consumption, so don't list them in the feature summary
 110 option(FATAL_WARNINGS "Make compile warnings fatal (most useful for CI builds)" OFF)
 111 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg" OFF "APPLE" OFF)
 112
 113 # List of authenticators and the cmake flags to build them
 114 # (currently that's just LDAP, but more can be added here).
 115 ####################################################################
 116 option(WITH_LDAP "Enable LDAP authentication support if present on system" ON)
 117
 118 # Setup CMake
 119 #####################################################################
 120
 121 # Visibility settings apply to all targets
 122 if (POLICY CMP0063)
 123     cmake_policy(SET CMP0063 NEW)
 124 endif()
 125
 126 # Let automoc/autouic process generated files
 127 if (POLICY CMP0071)
 128     cmake_policy(SET CMP0071 NEW)
 129 endif()
 130
 131 set(BUILD_SHARED_LIBS TRUE CACHE BOOL "" FORCE)
 132
 133 # Don't use X11 on OSX
 134 if (APPLE)
 135     set(CMAKE_DISABLE_FIND_PACKAGE_X11 true)
 136     set(CMAKE_DISABLE_FIND_PACKAGE_XCB true)
 137     set(CMAKE_DISABLE_FIND_PACKAGE_Qt5X11Extras true)
 138 endif()
 139
 140 # Simplify later checks
 141 #####################################################################
 142
 143 if (WANT_MONO OR WANT_QTCLIENT)
 144     set(BUILD_GUI true)
 145 endif()
 146 if (WANT_MONO OR WANT_CORE)
 147     set(BUILD_CORE true)
 148 endif()
 149
 150 # Set up Qt
 151 #####################################################################
 152
 153 # Find package dependencies
 154 #
 155 # Note that you can forcefully disable optional packages
 156 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 157 #####################################################################
 158
 159 set(QT_MIN_VERSION "5.5.0")
 160
 161 # Required Qt components
 162 set(qt_components Core Network)
 163 if (BUILD_GUI)
 164     list(APPEND qt_components Gui Widgets)
 165 endif()
 166 if (BUILD_CORE)
 167     list(APPEND qt_components Script Sql)
 168 endif()
 169
 170 find_package(Qt5 ${QT_MIN_VERSION} REQUIRED COMPONENTS ${qt_components})
 171 set_package_properties(Qt5 PROPERTIES TYPE REQUIRED
 172     URL "https://www.qt.io/"
 173     DESCRIPTION "the Qt libraries"
 174 )
 175 message(STATUS "Found Qt ${Qt5Core_VERSION}")
 176
 177 # Optional Qt components
 178
 179 find_package(Qt5LinguistTools QUIET)
 180 set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 181     DESCRIPTION "contains tools for handling translation files"
 182     PURPOSE "Required for having translations"
 183 )
 184
 185 if (BUILD_GUI)
 186     if (NOT WIN32)
 187         find_package(Qt5DBus QUIET)
 188         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 189             URL "https://www.qt.io/"
 190             DESCRIPTION "D-Bus support for Qt5"
 191             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 192         )
 193         if (Qt5DBus_FOUND)
 194             find_package(dbusmenu-qt5 QUIET CONFIG)
 195             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 196                 URL "https://launchpad.net/libdbusmenu-qt"
 197                 DESCRIPTION "a library implementing the DBusMenu specification"
 198                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 199             )
 200         endif()
 201     endif()
 202
 203     find_package(Qt5Multimedia QUIET)
 204     set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 205         URL "https://www.qt.io/"
 206         DESCRIPTION "Multimedia support for Qt5"
 207         PURPOSE     "Required for audio notifications"
 208     )
 209
 210     find_package(LibsnoreQt5 0.7.0 QUIET)
 211     set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 212         URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 213         DESCRIPTION "a cross-platform notification framework"
 214         PURPOSE     "Enable support for the snorenotify framework"
 215     )
 216     if (LibsnoreQt5_FOUND)
 217         find_package(LibsnoreSettingsQt5 QUIET)
 218         set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE OPTIONAL
 219             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 220             DESCRIPTION "a cross-platform notification framework"
 221             PURPOSE     "Enable support for the snorenotify framework"
 222         )
 223     endif()
 224
 225     if (WITH_WEBENGINE)
 226         find_package(Qt5WebEngine QUIET)
 227         set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 228             URL "https://www.qt.io/"
 229             DESCRIPTION "a WebEngine implementation for Qt"
 230             PURPOSE     "Needed for displaying previews for URLs in chat"
 231         )
 232         if (Qt5WebEngine_FOUND)
 233             find_package(Qt5WebEngineWidgets QUIET)
 234             set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 235                 URL "https://www.qt.io/"
 236                 DESCRIPTION "widgets for Qt's WebEngine implementation"
 237                 PURPOSE     "Needed for displaying previews for URLs in chat"
 238             )
 239         endif()
 240     endif()
 241
 242     if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 243         set(HAVE_WEBENGINE true)
 244     endif()
 245     add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 246
 247     if (NOT HAVE_WEBENGINE)
 248         if (WITH_WEBKIT)
 249             find_package(Qt5WebKit QUIET)
 250             set_package_properties(Qt5WebKit PROPERTIES TYPE OPTIONAL
 251                 URL "https://www.qt.io/"
 252                 DESCRIPTION "a WebKit implementation for Qt"
 253                 PURPOSE     "Needed for displaying previews for URLs in chat"
 254                 )
 255             if (Qt5WebKit_FOUND)
 256                 find_package(Qt5WebKitWidgets QUIET)
 257                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE OPTIONAL
 258                     URL "https://www.qt.io/"
 259                     DESCRIPTION "widgets for Qt's WebKit implementation"
 260                     PURPOSE     "Needed for displaying previews for URLs in chat"
 261                     )
 262             endif()
 263         endif()
 264
 265         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 266             set(HAVE_WEBKIT true)
 267         endif()
 268         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 269     endif()
 270
 271     # KDE Frameworks
 272     ################
 273
 274     # extra-cmake-modules
 275     if (WITH_KDE)
 276         set(ecm_find_type "REQUIRED")
 277         find_package(ECM NO_MODULE REQUIRED)
 278     else()
 279         # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 280         set(ecm_find_type "RECOMMENDED")
 281         find_package(ECM NO_MODULE QUIET)
 282     endif()
 283
 284     set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 285         URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 286         DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 287         PURPOSE     "Required to find KDE Frameworks components"
 288     )
 289
 290     if (ECM_FOUND)
 291         list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 292         if (WITH_KDE)
 293             find_package(KF5 REQUIRED COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig Sonnet TextWidgets WidgetsAddons XmlGui)
 294             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 295                 URL "http://www.kde.org"
 296                 DESCRIPTION "KDE Frameworks"
 297                 PURPOSE     "Required for integration into the Plasma desktop"
 298             )
 299             message(STATUS "Found KDE Frameworks ${KF5_VERSION}")
 300         endif()
 301
 302         # Optional KF5 tier1 components
 303         find_package(KF5Sonnet QUIET)
 304         set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 305             URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 306             DESCRIPTION "framework for providing spell-checking capabilities"
 307             PURPOSE "Enables spell-checking support in input widgets"
 308         )
 309     endif()
 310 endif()
 311
 312 if (BUILD_CORE)
 313     find_package(Qca-qt5 2.0 QUIET)
 314     set_package_properties(Qca-qt5 PROPERTIES TYPE RECOMMENDED
 315         URL "https://projects.kde.org/projects/kdesupport/qca"
 316         DESCRIPTION "Qt Cryptographic Architecture"
 317         PURPOSE "Required for encryption support"
 318     )
 319
 320     if (WITH_LDAP)
 321         find_package(Ldap QUIET)
 322         set_package_properties(Ldap PROPERTIES TYPE OPTIONAL
 323             URL "http://www.openldap.org/"
 324             DESCRIPTION "LDAP (Lightweight Directory Access Protocol) libraries"
 325             PURPOSE "Enables core user authentication via LDAP"
 326         )
 327     endif()
 328 endif()
 329
 330 # Non-Qt-based packages
 331 #####################################################################
 332
 333 find_package(Boost 1.54 REQUIRED)
 334 set_package_properties(Boost PROPERTIES TYPE REQUIRED
 335     URL "https://www.boost.org/"
 336     DESCRIPTION "Boost libraries for C++"
 337 )
 338 # Older versions don't define the imported target
 339 if (NOT TARGET Boost::boost)
 340     add_library(Boost::boost INTERFACE IMPORTED GLOBAL)
 341     if (Boost_INCLUDE_DIRS)
 342         set_target_properties(Boost::boost PROPERTIES
 343             INTERFACE_INCLUDE_DIRECTORIES "${Boost_INCLUDE_DIRS}")
 344     endif()
 345 endif()
 346
 347 find_package(ZLIB REQUIRED)
 348 set_package_properties(ZLIB PROPERTIES TYPE REQUIRED
 349     URL "http://www.zlib.net"
 350     DESCRIPTION "a popular compression library"
 351     PURPOSE     "Used for protocol compression"
 352 )
 353
 354 if (NOT WIN32)
 355     # Needed for generating backtraces
 356     find_package(Backtrace QUIET)
 357     set_package_properties(Backtrace PROPERTIES TYPE RECOMMENDED
 358         DESCRIPTION "a header (and possibly library) for inspecting backtraces"
 359         PURPOSE "Used for generating backtraces in case of a crash"
 360     )
 361 endif()
 362
 363 # Shared library support
 364 #####################################################################
 365
 366 option(ENABLE_SHARED "Build modules as shared libraries" ON)
 367 add_feature_info(ENABLE_SHARED ENABLE_SHARED "Build modules as shared libraries")
 368
 369 # Setup unit testing
 370 #####################################################################
 371
 372 option(BUILD_TESTING "Enable unit tests" OFF)
 373 add_feature_info(BUILD_TESTING BUILD_TESTING "Build unit tests")
 374
 375 if (BUILD_TESTING)
 376     find_package(GTest QUIET)
 377     set_package_properties(GTest PROPERTIES TYPE REQUIRED
 378         DESCRIPTION "Google's unit testing framework"
 379         PURPOSE "Required for building unit tests"
 380     )
 381
 382     find_package(Qt5Test QUIET)
 383     set_package_properties(Qt5Test PROPERTIES TYPE REQUIRED
 384         DESCRIPTION "unit testing library for the Qt5 framework"
 385         PURPOSE "Required for building unit tests"
 386     )
 387     enable_testing()
 388
 389     # GTest messes with CMAKE_CXX_FLAGS, so process them again
 390     process_cmake_cxx_flags()
 391 endif()
 392
 393 # Check for SSL support in Qt
 394 #####################################################################
 395
 396 cmake_push_check_state(RESET)
 397 set(CMAKE_REQUIRED_LIBRARIES Qt5::Core)
 398 check_cxx_source_compiles("
 399     #include \"qglobal.h\"
 400     #if defined QT_NO_SSL
 401     #  error \"No SSL support\"
 402     #endif
 403     int main() {}"
 404     HAVE_SSL)
 405 cmake_pop_check_state()
 406
 407 if (HAVE_SSL)
 408     add_definitions(-DHAVE_SSL)
 409 endif()
 410 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 411
 412 # Setup support for KDE Frameworks
 413 #####################################################################
 414
 415 if (WITH_KDE)
 416     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 417     set(WITH_KF5 TRUE)
 418
 419     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 420     set(EMBED_DATA OFF)
 421
 422     include(KDEInstallDirs)
 423 endif()
 424
 425 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 426 include(QuasselInstallDirs)
 427
 428 # RPATH and output settings
 429 #####################################################################
 430
 431 # Build artifacts in a well-known location; especially important for Windows DLLs
 432 # (which go into RUNTIME_OUTPUT_DIRECTORY and can thus be found by executables)
 433 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
 434 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
 435 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
 436
 437 # These RPATH settings allow for running directly from the build dir
 438 set(CMAKE_SKIP_BUILD_RPATH            FALSE)
 439 set(CMAKE_BUILD_WITH_INSTALL_RPATH    FALSE)
 440 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE )
 441
 442 # Set install RPATH only if libdir isn't a system directory
 443 if (IS_ABSOLUTE "${CMAKE_INSTALL_LIBDIR}")
 444     set(libdir "${CMAKE_INSTALL_LIBDIR}")
 445 else()
 446     set(libdir "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}")
 447 endif()
 448 list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${libdir}" is_systemdir)
 449 if ("${is_systemdir}" STREQUAL "-1")
 450    set(CMAKE_INSTALL_RPATH "${libdir}")
 451 endif()
 452
 453 # Various config-dependent checks and settings
 454 #####################################################################
 455
 456 # Check for syslog support
 457 if (NOT WIN32)
 458     check_include_file_cxx(syslog.h HAVE_SYSLOG)
 459     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 460 endif()
 461
 462 if (NOT WIN32)
 463     check_function_exists(umask HAVE_UMASK)
 464 endif()
 465
 466 if (EMBED_DATA)
 467     message(STATUS "Embedding data files into the binary")
 468 else()
 469     message(STATUS "Installing data files separately")
 470 endif()
 471
 472 # Windows-specific stuff
 473 #####################################################################
 474
 475 if (WIN32)
 476     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 477     if (MSVC)
 478         link_libraries(Version dwmapi shlwapi)
 479     endif()
 480 endif()
 481
 482 # Prepare the build
 483 #####################################################################
 484
 485 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 486 add_subdirectory(data)
 487 add_subdirectory(icons)
 488 add_subdirectory(pics)
 489 add_subdirectory(po)
 490
 491 # Set up and display feature summary
 492 #####################################################################
 493
 494 feature_summary(WHAT ALL
 495                 INCLUDE_QUIET_PACKAGES
 496                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 497 )
 498
 499 # Finally, compile the sources
 500 # We want this after displaying the feature summary to avoid ugly
 501 # CMake backtraces in case a required Qt5 module is missing
 502 #####################################################################
 503
 504 add_subdirectory(src)
 505
 506 # Build tests if so desired
 507 if (BUILD_TESTING)
 508     add_subdirectory(tests)
 509 endif()