CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 project(QuasselIRC)
  29
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32 include(CheckCXXCompilerFlag)
  33
  34 # For building against Qt5, we check for an even newer cmake version below!
  35 cmake_minimum_required(VERSION 2.8.1 FATAL_ERROR)
  36
  37 if(CMAKE_MAJOR_VERSION GREATER 2)
  38    cmake_policy(SET CMP0026 OLD)
  39    cmake_policy(SET CMP0043 OLD)
  40 endif()
  41
  42 # Use our own (well, and KDE's) version of some modules
  43 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  44 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  45 include(QuasselMacros)
  46
  47 # Various options and variables that can be set on the command line
  48 option(WANT_CORE     "Build the core (server) binary"           ON)
  49 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  50 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  51
  52 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  53 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  54 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  55 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  56 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  57 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  58 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  59 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  60
  61 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  62 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  63 # run on a matching KDE version only.
  64 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  65
  66 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  67 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  68
  69 option(STATIC        "Enable static building (might not be portable)" OFF)
  70
  71 if(APPLE)
  72   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  73   # Notification Center is only available in > 10.8, which is Darwin v12
  74   if(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  75     option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  76   endif(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  77 endif(APPLE)
  78
  79 # Default to embedding data in the static case
  80 if(STATIC OR WIN32)
  81   set(EMBED_DEFAULT ON)
  82 else(STATIC OR WIN32)
  83   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  84 endif(STATIC OR WIN32)
  85
  86 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  87
  88 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  89
  90 # Some settings imply others
  91 if(STATIC)
  92   add_definitions(-DSTATIC)
  93   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  94 endif(STATIC)
  95
  96 if(WIN32)
  97   # We don't support separately installed resources yet on Win32
  98   set(EMBED_DATA ON)
  99 endif(WIN32)
 100
 101 # For static builds, arbitrary extra libs might need to be linked
 102 # Define a comma-separated list here
 103 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 104 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 105 if(LINK_EXTRA)
 106   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 107   link_libraries(${LINK_EXTRA})
 108 endif(LINK_EXTRA)
 109
 110 # Build Types
 111
 112 if(CMAKE_CONFIGURATION_TYPES)
 113    set(CMAKE_CONFIGURATION_TYPES Release RelWithDebInfo Debug Debugfull Profile MinSizeRel)
 114    set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 115      "Reset the configurations to what we need"
 116      FORCE)
 117 endif()
 118
 119 if(NOT CMAKE_BUILD_TYPE)
 120   SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 121      "Choose the type of build, options are: None Debug Release RelWithDebInfo Debug Debugfull Profile MinSizeRel."
 122      FORCE)
 123 endif()
 124
 125 # Qt debug flags
 126 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 127 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUGFULL QT_DEBUG)
 128 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 129 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 130 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_PROFILE QT_NO_DEBUG NDEBUG)
 131 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 132
 133 if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 134   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 135 endif()
 136
 137 # Enable various flags on gcc
 138 if(CMAKE_COMPILER_IS_GNUCXX)
 139   # Let's just hope that all gccs support these options and skip the tests...
 140   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 141   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 142 #  set(CMAKE_CXX_FLAGS_RELEASE          "-O2")   # use CMake default
 143 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-g -O2")  # use CMake default
 144   set(CMAKE_CXX_FLAGS_DEBUG             "-g -ggdb -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 145   set(CMAKE_CXX_FLAGS_DEBUGFULL         "-g3 -ggdb -fno-inline")
 146   set(CMAKE_CXX_FLAGS_PROFILE           "-g3 -ggdb -fno-inline -ftest-coverage -fprofile-arcs")
 147
 148   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -W -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing -Wundef -Wcast-align -Wpointer-arith -Wformat-security -fno-check-new -fno-common")
 149
 150   check_cxx_compiler_flag(-Woverloaded-virtual CXX_W_OVERLOADED_VIRTUAL)
 151   if(CXX_W_OVERLOADED_VIRTUAL)
 152     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Woverloaded-virtual")
 153   endif()
 154
 155   # Just for miniz
 156   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-unused-function -Wno-undef -fno-strict-aliasing")
 157 endif(CMAKE_COMPILER_IS_GNUCXX)
 158
 159 # ... and for Clang
 160 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 161   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor -Wno-long-long -Wundef -Wcast-align -Wchar-subscripts -Wall -W -Wextra -Wpointer-arith -Wformat-security -Woverloaded-virtual -fno-common -Werror=return-type")
 162 #  set(CMAKE_CXX_FLAGS_RELEASE        "-O2 -DNDEBUG -DQT_NO_DEBUG")     # Use CMake default
 163 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g -DNDEBUG -DQT_NO_DEBUG")  # Use CMake default
 164   set(CMAKE_CXX_FLAGS_DEBUG          "-g -O2 -fno-inline")
 165   set(CMAKE_CXX_FLAGS_DEBUGFULL      "-g3 -fno-inline")
 166   set(CMAKE_CXX_FLAGS_PROFILE        "-g3 -fno-inline -ftest-coverage -fprofile-arcs")
 167
 168   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-unused-function -Wno-undef -fno-strict-aliasing")
 169 endif()
 170
 171 # Mac build stuff
 172 if(APPLE AND DEPLOY)
 173   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 174   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 175   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 176   add_definitions(-DMAC_10_6_SDK)
 177 endif(APPLE AND DEPLOY)
 178
 179 # Simplify checks
 180 if(WANT_MONO OR WANT_QTCLIENT)
 181   set(BUILD_GUI true)
 182 endif(WANT_MONO OR WANT_QTCLIENT)
 183 if(WANT_MONO OR WANT_CORE)
 184   set(BUILD_CORE true)
 185 endif(WANT_MONO OR WANT_CORE)
 186
 187
 188 # Version checks
 189 ################
 190
 191 if(WITH_QT5)
 192   set(QT_MIN_VERSION "5.0.0")
 193   add_definitions(-DHAVE_QT5)
 194
 195   # Qt5 needs a new enough cmake...
 196   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 197
 198   # ... for automoc
 199   set(CMAKE_AUTOMOC ON)
 200 else(WITH_QT5)
 201
 202   # GUI stuff needs some new features
 203   if(BUILD_GUI)
 204     set(QT_MIN_VERSION "4.6.0")
 205   else(BUILD_GUI)
 206     set(QT_MIN_VERSION "4.4.0")
 207   endif(BUILD_GUI)
 208 endif(WITH_QT5)
 209
 210
 211 # Dependencies
 212 ##############
 213
 214 if(WITH_QT5)
 215   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 216   # We need QtWidgets
 217   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 218
 219   # Setup the i18n-related variables
 220   find_package(Qt5LinguistTools)
 221
 222 else(WITH_QT5)
 223   # Select a Qt installation here, if you don't want to use system Qt
 224   if(QT)
 225     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 226     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 227   endif(QT)
 228
 229   # Now that we have the correct $PATH, lets find Qt!
 230   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 231 endif(WITH_QT5)
 232
 233
 234 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 235 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 236 if(QT_LRELEASE_EXECUTABLE)
 237   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 238   if(WITH_QT5)
 239     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 240   else(WITH_QT5)
 241     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 242   endif(WITH_QT5)
 243 endif(QT_LRELEASE_EXECUTABLE)
 244
 245
 246 # zlib for compression, however we can always fall back to miniz
 247 find_package(ZLIB)
 248 if(ZLIB_FOUND)
 249   message(STATUS "Using system zlib for compression")
 250   add_definitions(-DHAVE_ZLIB)
 251   include_directories(${ZLIB_INCLUDE_DIRS})
 252   set(COMMON_LIBRARIES ${COMMON_LIBRARIES} ${ZLIB_LIBRARIES})
 253 else()
 254   message(STATUS "zlib NOT found, using bundled miniz for compression")
 255   if(${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 256     message(STATUS "WARNING: This may be slow on 32 bit systems!")
 257   endif()
 258 endif()
 259
 260
 261 # Execinfo is needed for generating backtraces
 262 find_package(ExecInfo)
 263 if(EXECINFO_FOUND)
 264   add_definitions(-DHAVE_EXECINFO)
 265   include_directories(${EXECINFO_INCLUDES})
 266   link_libraries(${EXECINFO_LIBRARIES})
 267 endif(EXECINFO_FOUND)
 268
 269
 270 # PkgConfig isn't strictly required.
 271 # However, some optional deps might not be found if it's not present, so warn!
 272 find_package(PkgConfig)
 273 if(NOT PKG_CONFIG_FOUND)
 274   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 275   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 276 endif(NOT PKG_CONFIG_FOUND)
 277
 278
 279 # Setup OpenSSL
 280 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 281 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 282 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 283 if(WITH_OPENSSL)
 284   if(QT_QCONFIG MATCHES "openssl")
 285     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 286     add_definitions(-DHAVE_SSL)
 287     set(HAVE_SSL true)
 288   else(QT_QCONFIG MATCHES "openssl")
 289     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 290     add_definitions(-DQT_NO_OPENSSL)
 291   endif(QT_QCONFIG MATCHES "openssl")
 292 else(WITH_OPENSSL)
 293   message(STATUS "Not enabling OpenSSL support")
 294 endif(WITH_OPENSSL)
 295
 296
 297 # Check for GUI specific stuff
 298 if(BUILD_GUI)
 299
 300   # Setup D-Bus support
 301   if(WITH_DBUS)
 302     if(WITH_QT5)
 303       find_package(Qt5DBus ${QT_MIN_VERSION})
 304       find_package(Qt5DBusTools)
 305     endif(WITH_QT5)
 306
 307     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 308       message(STATUS "Found QtDBus, enabling D-Bus support")
 309       add_definitions(-DHAVE_DBUS)
 310       set(HAVE_DBUS true)
 311       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 312
 313       # check if we have dbusmenu as well
 314       if(NOT WITH_QT5)
 315         find_package(DBusMenuQt)
 316         if(DBUSMENUQT_FOUND)
 317           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 318           add_definitions(-DHAVE_DBUSMENU)
 319           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 320           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 321           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 322         else(DBUSMENUQT_FOUND)
 323           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 324         endif(DBUSMENUQT_FOUND)
 325       endif(NOT WITH_QT5)
 326
 327     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 328       message(STATUS "QtDBus not found, disabling D-Bus support")
 329     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 330   else(WITH_DBUS)
 331     message(STATUS "Not enabling D-Bus support")
 332   endif(WITH_DBUS)
 333
 334   # Setup QtWebkit support
 335   if(WITH_WEBKIT)
 336     if(WITH_QT5)
 337       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 338     endif(WITH_QT5)
 339     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 340       message(STATUS "Found QtWebKit, enabling WebKit support")
 341       add_definitions(-DHAVE_WEBKIT)
 342       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 343       set(HAVE_WEBKIT true)
 344     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 345       message(STATUS "QtWebkit not found, disabling Webkit support")
 346     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 347   else(WITH_WEBKIT)
 348     message(STATUS "Not enabling Webkit support")
 349   endif(WITH_WEBKIT)
 350
 351   # Setup KDE4 support
 352   if(WITH_KDE AND NOT WITH_QT5)
 353     # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 354     set(_cflags ${CMAKE_C_FLAGS})
 355     find_package(KDE4)
 356     if(KDE4_FOUND)
 357       message(STATUS "Enabling KDE4 integration")
 358       include_directories(${KDE4_INCLUDES})
 359       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 360       set(HAVE_KDE 1)
 361       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
 362       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 363       set(EMBED_DATA OFF)
 364       # Restore our old CFLAGS
 365       set(CMAKE_C_FLAGS ${_cflags})
 366     else(KDE4_FOUND)
 367       message(STATUS "KDE4 not found, disabling KDE integration")
 368     endif(KDE4_FOUND)
 369   else(WITH_KDE AND NOT WITH_QT5)
 370     message(STATUS "Not enabling KDE4 integration")
 371   endif(WITH_KDE AND NOT WITH_QT5)
 372
 373   # Setup Phonon support - we only need this if we don't have or want KDE4
 374   if(NOT HAVE_KDE)
 375     if(WITH_PHONON)
 376       if(WITH_QT5)
 377         find_package(Qt5phonon)
 378         if(Qt5phonon_FOUND)
 379           message(STATUS "Enabling Phonon support")
 380           add_definitions(-DHAVE_PHONON)
 381           set(HAVE_PHONON true)
 382           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 383         else(Qt5phonon_FOUND)
 384           message(STATUS "Phonon not found, disabling audio notifications")
 385         endif(Qt5phonon_FOUND)
 386       else(WITH_QT5)
 387         find_package(Phonon)
 388         if(PHONON_FOUND)
 389           message(STATUS "Enabling Phonon support")
 390           add_definitions(-DHAVE_PHONON)
 391           include_directories(${PHONON_INCLUDES})
 392           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 393           set(HAVE_PHONON true)
 394         else(PHONON_FOUND)
 395           message(STATUS "Phonon not found, disabling audio notifications")
 396         endif(PHONON_FOUND)
 397       endif(WITH_QT5)
 398     else(WITH_PHONON)
 399       message(STATUS "Not enabling Phonon support")
 400     endif(WITH_PHONON)
 401
 402     find_package(Libsnore)
 403     if(LIBSNORE_FOUND)
 404         add_definitions(-DHAVE_LIBSNORE)
 405         set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
 406         set(HAVE_SNORENOTIFY true)
 407     endif(LIBSNORE_FOUND)
 408   endif(NOT HAVE_KDE)
 409
 410   # Setup libindicate-qt support
 411   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 412     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 413     if(INDICATEQT_FOUND)
 414       message(STATUS "Enabling Ayatana notification support")
 415       set(HAVE_INDICATEQT true)
 416       add_definitions(-DHAVE_INDICATEQT)
 417       link_directories(${INDICATEQT_LIBRARY_DIRS})
 418       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 419     else(INDICATEQT_FOUND)
 420       message(STATUS "Disabling Ayatana notification support")
 421     endif(INDICATEQT_FOUND)
 422   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 423     message(STATUS "Not enabling Ayatana notification support")
 424     # We don't want to link against it even if another package has found it
 425     set(INDICATEQT_LIBRARIES "")
 426   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 427
 428   # Setup OS X notification center support
 429   if(WITH_NOTIFICATION_CENTER AND APPLE)
 430     set(HAVE_NOTIFICATION_CENTER true)
 431     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 432     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 433       /System/Library/Frameworks/Foundation.framework
 434     )
 435   endif()
 436 endif(BUILD_GUI)
 437
 438 # Core-only deps
 439 if(BUILD_CORE)
 440
 441   # Setup encryption support
 442   if(WITH_CRYPT AND NOT WITH_QT5)
 443     find_package(QCA2)
 444     if(QCA2_FOUND)
 445       message(STATUS "Enabling encryption support")
 446       add_definitions(-DHAVE_QCA2)
 447       set(LINK_QCA2 QCA2)
 448       set(HAVE_QCA2 true)
 449       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 450     else(QCA2_FOUND)
 451       message(STATUS "Disabling encryption support")
 452     endif(QCA2_FOUND)
 453   else(WITH_CRYPT AND NOT WITH_QT5)
 454     message(STATUS "Not enabling encryption support")
 455   endif(WITH_CRYPT AND NOT WITH_QT5)
 456
 457   # Setup syslog support
 458   if(WITH_SYSLOG)
 459     check_include_file(syslog.h HAVE_SYSLOG_H)
 460     if(HAVE_SYSLOG_H)
 461       message(STATUS "Enabling syslog support")
 462       set(HAVE_SYSLOG true)
 463       add_definitions(-DHAVE_SYSLOG)
 464     else(HAVE_SYSLOG_H)
 465       message(STATUS "Disabling syslog support")
 466     endif(HAVE_SYSLOG_H)
 467   else(WITH_SYSLOG)
 468     message(STATUS "Not enabling syslog support")
 469   endif(WITH_SYSLOG)
 470
 471 endif(BUILD_CORE)
 472
 473
 474 # Various settings
 475 ##################
 476
 477 # needed to compile with mingw without kde
 478 if(MINGW AND NOT HAVE_KDE)
 479     add_definitions(-D_WIN32_WINNT=0x0500)
 480     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 481 # workaround for bug in mingw gcc 4.0
 482     add_definitions(-U__STRICT_ANSI__)
 483 endif(MINGW AND NOT HAVE_KDE)
 484
 485 # Now set up install locations; those are set by KDE if integration is enabled
 486 if(NOT HAVE_KDE)
 487   if(WIN32)
 488     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 489     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 490     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 491     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 492   else(WIN32)
 493     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 494     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 495     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 496     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 497   endif(WIN32)
 498 endif(NOT HAVE_KDE)
 499
 500 if(EMBED_DATA)
 501   message(STATUS "Embedding data files into the binary")
 502 else(EMBED_DATA)
 503   message(STATUS "Installing data files separately")
 504 endif(EMBED_DATA)
 505
 506 # RPATH needs to be set correctly
 507 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 508 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 509 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 510
 511 # Set global buildflags
 512 # This is very much non-portable, so don't use -DSTATIC until you know what
 513 # you do.
 514 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 515   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 516   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 517   if(HAVE_SSL)
 518     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 519   endif(HAVE_SSL)
 520 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 521
 522 if(WIN32)
 523   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 524   if(MSVC)
 525     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 526     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 527     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 528     link_libraries(Version dwmapi shlwapi)
 529   endif(MSVC)
 530   if(HAVE_SSL AND STATIC)
 531      find_package(OpenSSL REQUIRED)
 532      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 533   endif(HAVE_SSL AND STATIC)
 534 endif(WIN32)
 535
 536 if(HAVE_INDICATEQT)
 537   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 538 endif(HAVE_INDICATEQT)
 539
 540 if(NOT WIN32)
 541   check_function_exists(umask HAVE_UMASK)
 542   if(HAVE_UMASK)
 543     add_definitions(-DHAVE_UMASK)
 544   endif(HAVE_UMASK)
 545 endif(NOT WIN32)
 546
 547 # We need to create a version.gen
 548 # For this, we create our genversion binary and make sure it is run every time.
 549
 550 setup_qt_variables()
 551 include_directories(${QUASSEL_QT_INCLUDES})
 552
 553 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 554 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 555 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 556
 557 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 558 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 559                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 560 add_dependencies(genversion_run genversion)
 561
 562 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 563 set(COMMON_DEPS ${RC_WIN32})
 564 set(CORE_DEPS )
 565 set(CLIENT_DEPS )
 566
 567 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 568 add_subdirectory(data)
 569 add_subdirectory(icons)
 570 add_subdirectory(pics)
 571 add_subdirectory(po)
 572 add_subdirectory(src)