CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 11)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.11-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37
  38 # Options and variables that can be set on the command line
  39 #####################################################################
  40
  41 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  42 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  43 if (USE_QT4) # takes precedence
  44     set(USE_QT5 OFF)
  45 else()
  46     if (NOT USE_QT5)
  47         set(USE_QT4 ON)
  48     endif()
  49 endif()
  50
  51 # Select the binaries to build
  52 option(WANT_CORE     "Build the core (server) binary"           ON)
  53 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  54 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  55 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  56 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  57 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  58
  59 # Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
  60 cmake_dependent_option(WITH_KDE "KDE4 integration" OFF "USE_QT4" OFF)
  61 add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  62
  63 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  64 if (NOT WITH_KDE)
  65     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  66 endif()
  67
  68 # For this, the feature info is added after we know if QtWebkit is installed
  69 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  70
  71 if (APPLE)
  72     # Notification Center is only available in > 10.8, which is Darwin v12
  73     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  75         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  76     endif()
  77 endif()
  78
  79 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  80 set(EMBED_DEFAULT OFF)
  81 if (STATIC OR WIN32 OR APPLE)
  82     set(EMBED_DEFAULT ON)
  83 endif()
  84 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  85                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  86 if (NOT EMBED_DEFAULT)
  87     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  88 endif()
  89
  90 # The following options are not for end-user consumption, so don't list them in the feature summary
  91 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  92
  93 # Handle with care
  94 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
  95
  96 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
  97 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
  98
  99 # For static builds, arbitrary extra libs might need to be linked
 100 # Define a comma-separated list here
 101 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 102 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 103 if (LINK_EXTRA)
 104     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 105     link_libraries(${LINK_EXTRA})
 106 endif()
 107
 108
 109 # Simplify later checks
 110 #####################################################################
 111
 112 if (WANT_MONO OR WANT_QTCLIENT)
 113     set(BUILD_GUI true)
 114 endif()
 115 if (WANT_MONO OR WANT_CORE)
 116     set(BUILD_CORE true)
 117 endif()
 118
 119
 120 # Set up Qt
 121 #####################################################################
 122
 123 if (USE_QT5)
 124     message(STATUS "Building for Qt5...")
 125     set(QT_MIN_VERSION "5.2.0")
 126     add_definitions(-DHAVE_QT5)
 127 else()
 128     message(STATUS "Building for Qt4...")
 129     if (BUILD_GUI)
 130         set(QT_MIN_VERSION "4.6.0")
 131     else()
 132         set(QT_MIN_VERSION "4.4.0")
 133     endif()
 134
 135     # Select a Qt installation here, if you don't want to use system Qt
 136     if(QT_PATH)
 137         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 138         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 139     endif()
 140 endif()
 141
 142 # Find package dependencies
 143 #
 144 # Note that you can forcefully disable optional packages
 145 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 146 #####################################################################
 147
 148 if (USE_QT5)
 149     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 150     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 151         URL "http://qt.digia.com"
 152         DESCRIPTION "contains core functionality for Qt"
 153     )
 154     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 155     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 156     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 157         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 158     endif()
 159
 160     find_package(Qt5Network QUIET)
 161     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 162         DESCRIPTION "the network module for Qt5"
 163     )
 164
 165     if (BUILD_GUI)
 166         find_package(Qt5Gui QUIET)
 167         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 168             DESCRIPTION "the GUI module for Qt5"
 169         )
 170         find_package(Qt5Widgets QUIET)
 171         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 172             DESCRIPTION "the widgets module for Qt5"
 173         )
 174
 175         find_package(Qt5DBus QUIET)
 176         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 177             URL "http://qt.digia.com"
 178             DESCRIPTION "D-Bus support for Qt5"
 179             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 180         )
 181         if (Qt5DBus_FOUND)
 182             find_package(dbusmenu-qt5 QUIET CONFIG)
 183             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 184                 URL "https://launchpad.net/libdbusmenu-qt"
 185                 DESCRIPTION "a library implementing the DBusMenu specification"
 186                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 187             )
 188         endif()
 189
 190         find_package(Phonon4Qt5 QUIET)
 191         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 192             URL "https://projects.kde.org/projects/kdesupport/phonon"
 193             DESCRIPTION "a multimedia abstraction library"
 194             PURPOSE     "Required for audio notifications"
 195         )
 196
 197         find_package(LibsnoreQt5 QUIET)
 198         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 199             URL "https://github.com/TheOneRing/Snorenotify"
 200             DESCRIPTION "a cross-platform notification framework"
 201             PURPOSE     "Enable support for the snorenotify framework"
 202         )
 203
 204         if (WITH_WEBKIT)
 205             find_package(Qt5WebKit QUIET)
 206             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 207                 URL "http://qt.digia.com"
 208                 DESCRIPTION "a WebKit implementation for Qt"
 209                 PURPOSE     "Needed for displaying previews for URLs in chat"
 210             )
 211             if (Qt5WebKit_FOUND)
 212                 find_package(Qt5WebKitWidgets QUIET)
 213                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 214                     URL "http://qt.digia.com"
 215                     DESCRIPTION "widgets for Qt's WebKit implementation"
 216                     PURPOSE     "Needed for displaying previews for URLs in chat"
 217                 )
 218             endif()
 219         endif()
 220         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 221
 222     endif(BUILD_GUI)
 223     if (BUILD_CORE)
 224         find_package(Qt5Script QUIET)
 225         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 226             DESCRIPTION "provides scripting support for Qt5"
 227         )
 228         find_package(Qt5Sql QUIET)
 229         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 230             DESCRIPTION "the database support module for Qt5"
 231         )
 232
 233         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 234         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 235         #find_package(QCA2 QUIET)
 236         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 237         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 238         #    DESCRIPTION "Qt Cryptographic Architecture"
 239         #    PURPOSE "Required for encryption support"
 240         #)
 241
 242     endif(BUILD_CORE)
 243
 244     find_package(Qt5LinguistTools QUIET)
 245     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 246                            DESCRIPTION "contains tools for handling translation files"
 247                            PURPOSE "Required for having translations"
 248     )
 249     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 250     if (Qt5LinguistTools_FOUND)
 251         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 252             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 253             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 254             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 255         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 256             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 257             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 258         endif()
 259
 260         # Compatibility with the Qt4 variables
 261         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 262         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 263         if (Qt5_LCONVERT_EXECUTABLE)
 264             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 265         endif()
 266     endif()
 267
 268 else(USE_QT5)
 269     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 270
 271     if (BUILD_GUI)
 272         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 273         if (QT_QTDBUS_FOUND)
 274             find_package(dbusmenu-qt QUIET CONFIG)
 275             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 276                 URL "https://launchpad.net/libdbusmenu-qt"
 277                 DESCRIPTION "a library implementing the DBusMenu specification"
 278                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 279             )
 280         endif()
 281
 282         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 283             set(HAVE_WEBKIT true)
 284         endif()
 285         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 286
 287         if (WITH_KDE)
 288             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 289             set(_cflags ${CMAKE_C_FLAGS})
 290             find_package(KDE4 4.4 QUIET)
 291             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 292                 URL "http://www.kde.org"
 293                 DESCRIPTION "a world-class desktop environment"
 294                 PURPOSE "Enables various bits for improving integration with KDE"
 295             )
 296             set(CMAKE_C_FLAGS ${_cflags})
 297
 298         else(WITH_KDE)
 299             find_package(Phonon QUIET)
 300             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 301                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 302                 DESCRIPTION "a multimedia abstraction library"
 303                 PURPOSE     "Required for audio notifications"
 304             )
 305
 306             find_package(Libsnore QUIET)
 307             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 308                 URL "https://github.com/TheOneRing/Snorenotify"
 309                 DESCRIPTION "a cross-platform notification framework"
 310                 PURPOSE     "Enable support for the snorenotify framework"
 311             )
 312         endif(WITH_KDE)
 313
 314         find_package(IndicateQt QUIET)
 315         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 316             URL "https://launchpad.net/libindicate-qt/"
 317             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 318             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 319         )
 320
 321     endif(BUILD_GUI)
 322     if (BUILD_CORE)
 323
 324         find_package(QCA2 QUIET)
 325         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 326             URL "https://projects.kde.org/projects/kdesupport/qca"
 327             DESCRIPTION "Qt Cryptographic Architecture"
 328             PURPOSE     "Required for encryption support"
 329         )
 330
 331
 332     endif()
 333
 334     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 335     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 336     if (QT_LRELEASE_EXECUTABLE)
 337         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 338         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 339     endif()
 340 endif()
 341
 342
 343 # Non-Qt-based packages
 344
 345 # zlib for compression, however we can always fall back to miniz
 346 find_package(ZLIB QUIET)
 347 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 348     URL "http://www.zlib.net"
 349     DESCRIPTION "a popular compression library"
 350     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 351 )
 352
 353
 354 if (NOT WIN32)
 355     # Execinfo is needed for generating backtraces
 356     find_package(ExecInfo QUIET)
 357     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 358         DESCRIPTION "a library for inspecting backtraces"
 359         PURPOSE "Used for generating backtraces in case of a crash"
 360     )
 361 endif()
 362
 363
 364 # Various checks
 365 #####################################################################
 366
 367 if (NOT ZLIB_FOUND)
 368     message(STATUS "zlib NOT found, using bundled miniz for compression")
 369     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 370         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 371     endif()
 372 endif()
 373
 374 if (KDE4_FOUND)
 375     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 376     set(EMBED_DATA OFF)
 377
 378     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 379     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 380 endif()
 381
 382 # Check for SSL support in Qt
 383 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 384 # a small test program checking the defines. This works for both Qt4 and Qt5.
 385 cmake_push_check_state(RESET)
 386 if (Qt5_POSITION_INDEPENDENT_CODE)
 387     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 388 endif()
 389 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 390 check_cxx_source_compiles("
 391     #include \"qglobal.h\"
 392     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 393     #  error \"No SSL support\"
 394     #endif
 395     int main() {}"
 396     HAVE_SSL)
 397 cmake_pop_check_state()
 398
 399 if (HAVE_SSL)
 400     add_definitions(-DHAVE_SSL)
 401 endif()
 402 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 403
 404 # Check for syslog support
 405 if (NOT WIN32)
 406     check_include_file(syslog.h HAVE_SYSLOG)
 407     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 408 endif()
 409
 410 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 411
 412 # Various settings
 413 ##################
 414
 415 # needed to compile with mingw without kde
 416 if (MINGW AND NOT KDE4_FOUND)
 417     add_definitions(-D_WIN32_WINNT=0x0500)
 418     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 419 # workaround for bug in mingw gcc 4.0
 420     add_definitions(-U__STRICT_ANSI__)
 421 endif()
 422
 423 # Now set up install locations; those are set by KDE if integration is enabled
 424 if(NOT KDE4_FOUND)
 425   if(WIN32)
 426     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 427     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 428     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 429     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 430   else(WIN32)
 431     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 432     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 433     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 434     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 435   endif(WIN32)
 436 endif()
 437
 438 if(EMBED_DATA)
 439   message(STATUS "Embedding data files into the binary")
 440 else(EMBED_DATA)
 441   message(STATUS "Installing data files separately")
 442 endif(EMBED_DATA)
 443
 444 # RPATH needs to be set correctly
 445 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 446 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 447 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 448
 449 # Set global buildflags
 450 # This is very much non-portable, so don't use -DSTATIC until you know what
 451 # you do.
 452 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 453   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 454   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 455   if(HAVE_SSL)
 456     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 457   endif(HAVE_SSL)
 458 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 459
 460 if(WIN32)
 461   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 462   if(MSVC)
 463     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 464     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 465     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 466     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 467     link_libraries(Version dwmapi shlwapi)
 468     if(USE_QT5)
 469       set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 470     endif(USE_QT5)
 471   endif(MSVC)
 472   if(HAVE_SSL AND STATIC)
 473      find_package(OpenSSL REQUIRED)
 474      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 475   endif(HAVE_SSL AND STATIC)
 476 endif(WIN32)
 477
 478 if(INDICATEQT_FOUND)
 479   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 480 endif()
 481
 482 if(NOT WIN32)
 483   check_function_exists(umask HAVE_UMASK)
 484   if(HAVE_UMASK)
 485     add_definitions(-DHAVE_UMASK)
 486   endif(HAVE_UMASK)
 487 endif(NOT WIN32)
 488
 489 # Generate version information from Git
 490 include(GetGitRevisionDescription)
 491 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 492 git_describe(GIT_DESCRIBE --long)
 493
 494 # Sanitize things if we're not in a Git repo
 495 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 496     set(GIT_HEAD "")
 497     set(GIT_DESCRIBE "")
 498 endif()
 499
 500 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 501
 502 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 503 set(COMMON_DEPS ${RC_WIN32})
 504 set(CORE_DEPS )
 505 set(CLIENT_DEPS )
 506
 507 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 508 add_subdirectory(data)
 509 add_subdirectory(icons)
 510 add_subdirectory(pics)
 511 add_subdirectory(po)
 512
 513 # Set up and display feature summary
 514 #####################################################################
 515
 516 feature_summary(WHAT ALL
 517                 INCLUDE_QUIET_PACKAGES
 518                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 519 )
 520
 521 # Finally, compile the sources
 522 # We want this after displaying the feature summary to avoid ugly
 523 # CMake backtraces in case a required Qt5 modules misses
 524 #####################################################################
 525
 526 add_subdirectory(src)