CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 # You may pass various options to cmake:
   3 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   4 #                  : select binaries to build
   5 # -DQT=/path/to/qt : Choose a Qt4 installation to use instead of the system Qt4
   6 # -DSTATIC=ON      : Enable static building of Quassel. Use with care.
   7 # -DSPUTDEV=ON     : Do not use.
   8 # -DDEPLOY=ON      : Mac OS X only. Use only fore redistribution Quassel Packages!!
   9 #
  10 # NOTE: You need to remove CMakeCache.txt if you plan to change any of these values!
  11
  12 project(QuasselIRC)
  13
  14 # Target scopes don't work in older versions
  15 cmake_minimum_required(VERSION 2.4.7 FATAL_ERROR)
  16
  17 # This would suppress annoying warnings on cmake-2.6, but we can't use it
  18 # with 2.4, so... DUH!
  19 # cmake_policy(SET CMP0003 OLD)  # suppress linker warnings
  20
  21 # Use our own (well, KDE's) version of some modules
  22 # In particular cmake's FindQt4 and FindOpenSSL are quite buggy
  23 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  24
  25 # Various options and variables that can be set on the command line
  26 option(WANT_CORE     "Build the core (server) binary"           ON)
  27 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  28 option(WANT_MONO     "Build the monolithic (all-in-one) binary" OFF)
  29
  30 option(STATIC        "Enable static building (might not be portable)" OFF)
  31 option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  32 option(SPUTDEV       "Do not use!" OFF)
  33
  34 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt")
  35 set(LINGUAS "" CACHE STRING "Space-separated List of locales specifying languages that should be compiled")
  36
  37 if(STATIC)
  38   set(CMAKE_BUILD_TYPE Release)
  39 endif(STATIC)
  40
  41 # Enable various flags on gcc
  42 if(CMAKE_COMPILER_IS_GNUCXX)
  43   include(CheckCXXCompilerFlag)
  44   check_cxx_compiler_flag(-Wall HAVE_WALL)
  45   if(HAVE_WALL)
  46     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
  47   endif(HAVE_WALL)
  48   check_cxx_compiler_flag(-Wextra HAVE_WEXTRA)
  49   if(HAVE_WEXTRA)
  50     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wextra")
  51   endif(HAVE_WEXTRA)
  52   check_cxx_compiler_flag(-ansi HAVE_ANSI)
  53   if(HAVE_ANSI)
  54     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi")
  55   endif(HAVE_ANSI)
  56 endif(CMAKE_COMPILER_IS_GNUCXX)
  57
  58 set(QT_MIN_VERSION "4.3.0")
  59
  60 if(APPLE AND DEPLOY)
  61   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
  62   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
  63   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
  64 endif(APPLE AND DEPLOY)
  65
  66 # Enable mostly b0rked stuff (new ChatView), do not enable this unless you know what you do...
  67 if(SPUTDEV)
  68   add_definitions(-DSPUTDEV)
  69 endif(SPUTDEV)
  70
  71 # Set up OpenSSL
  72 find_package(OpenSSL)
  73
  74 # Select a Qt installation here, if you don't want to use system Qt
  75 if(QT)
  76   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
  77   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
  78 endif(QT)
  79
  80 # Now that we have the correct $PATH, lets find Qt!
  81 find_package(Qt4 REQUIRED)
  82
  83 set(QT_DONT_USE_QTGUI 1)
  84 include(${QT_USE_FILE})
  85 include_directories(${QT_INCLUDES})
  86
  87 # We need to create a version.gen
  88 # For this, we create our genversion binary and make sure it is run every time.
  89 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
  90 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
  91
  92 add_custom_target(genversion_run ALL ${CMAKE_BINARY_DIR}/genversion
  93                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/common/version.gen)
  94 add_dependencies(genversion_run genversion)
  95
  96 # Add needed subdirs
  97 add_subdirectory(src/common)
  98 include_directories(src/common)
  99 if(WANT_CORE OR WANT_MONO)
 100   add_subdirectory(src/core)
 101   include_directories(src/core)
 102 endif(WANT_CORE OR WANT_MONO)
 103 if(WANT_QTCLIENT OR WANT_MONO)
 104   add_subdirectory(src/client)
 105   add_subdirectory(src/uisupport)
 106   add_subdirectory(src/qtui)
 107   include_directories(src/client)
 108   include_directories(src/uisupport)
 109   include_directories(src/qtui)
 110 endif(WANT_QTCLIENT OR WANT_MONO)
 111
 112 # Make sure version.gen exists before building mod_common
 113 add_dependencies(mod_common genversion_run)
 114
 115 # Generate binary translation files
 116 include(QuasselGenerateTranslations)
 117 quassel_generate_i18n_resource(RC_I18N ${LINGUAS})
 118
 119 # Add resources
 120 qt4_add_resources(RC_ICONS src/icons/icons.qrc)
 121 qt4_add_resources(RC_QUASSEL_ICONS src/icons/quassel-icons.qrc)
 122 qt4_add_resources(RC_SQL src/core/sql.qrc)
 123
 124 # Set global buildflags
 125 # This is very much non-portable, so don't use -DSTATICGCC until you know what
 126 # you do.
 127 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 128   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 129   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 130   if(OPENSSL_FOUND)
 131     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 132   endif(OPENSSL_FOUND)
 133 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 134
 135 if(STATIC AND WIN32)
 136   link_libraries(imm32 winmm)  # missing by default :/
 137    if(OPENSSL_FOUND)
 138      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 139    endif(OPENSSL_FOUND)
 140 endif(STATIC AND WIN32)
 141
 142 if(WIN32)
 143   set(WIN32_RC src/icons/win32.rc)  # for app icons on windows
 144 endif(WIN32)
 145
 146 # Here comes the dirty part. Our targets need different Qt4 modules, i.e. different libs
 147 # and defines. We can't simply include UseQt4 several times, since definitions add up.
 148 # We workaround this by using our own macro to figure out what to add.
 149
 150 # This macro sets variables for additional Qt modules.
 151 macro(setup_qt4_variables)
 152   set(QUASSEL_QT_LIBRARIES )
 153   IF(WIN32)
 154     set(MAIN MAIN)
 155   ENDIF(WIN32)
 156   foreach(qtmod CORE ${ARGV} ${MAIN})
 157     set(QUASSEL_QT_LIBRARIES ${QUASSEL_QT_LIBRARIES} ${QT_QT${qtmod}_LIBRARY} ${QT_${qtmod}_LIB_DEPENDENCIES})
 158   endforeach(qtmod ${ARGV})
 159   set(QUASSEL_QT_LIBRARIES ${QUASSEL_QT_LIBRARIES} ${QT_LIBRARIES})
 160 endmacro(setup_qt4_variables)
 161
 162 # Now we have everything, so just glue the right pieces together :)
 163 if(WANT_CORE)
 164   setup_qt4_variables(NETWORK SCRIPT SQL)
 165   add_executable(quasselcore ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 166                              ${RC_SQL} ${RC_I18N} ${WIN32_RC})
 167   set_target_properties(quasselcore PROPERTIES
 168                                     COMPILE_FLAGS "-DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_CORE")
 169   target_link_libraries(quasselcore mod_core mod_common
 170                                     ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 171 endif(WANT_CORE)
 172
 173 if(WANT_QTCLIENT)
 174   setup_qt4_variables(GUI NETWORK)
 175   add_executable(quasselclient WIN32 ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 176                                      ${RC_ICONS} ${RC_QUASSEL_ICONS} ${RC_I18N} ${WIN32_RC})
 177   set_target_properties(quasselclient PROPERTIES
 178                                       COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DBUILD_QTUI")
 179   target_link_libraries(quasselclient mod_qtui mod_uisupport mod_client mod_common
 180                                       ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 181 endif(WANT_QTCLIENT)
 182
 183 if(WANT_MONO)
 184   setup_qt4_variables(GUI NETWORK SCRIPT SQL)
 185   add_executable(quassel WIN32 ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 186                                ${RC_ICONS} ${RC_QUASSEL_ICONS} ${RC_SQL} ${RC_I18N} ${WIN32_RC})
 187   set_target_properties(quassel PROPERTIES
 188                                 COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_MONO")
 189   target_link_libraries(quassel mod_qtui mod_uisupport mod_client mod_core mod_common
 190                                 ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 191 endif(WANT_MONO)
 192
 193 # Build bundles for MacOSX
 194 if(APPLE)
 195   add_custom_command(TARGET quasselclient POST_BUILD
 196                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
 197                              ${CMAKE_SOURCE_DIR} "Quassel Client" quasselclient)
 198   add_custom_command(TARGET quassel POST_BUILD
 199                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
 200                              ${CMAKE_SOURCE_DIR} "Quassel" quassel)
 201   if(DEPLOY)
 202     add_custom_command(TARGET quasselclient POST_BUILD
 203                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Client)
 204     add_custom_command(TARGET quasselcore POST_BUILD
 205                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Core)
 206   endif(DEPLOY)
 207 endif(APPLE)
 208
 209 # Install rules
 210 if(WANT_CORE)
 211   install(TARGETS quasselcore
 212           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 213 endif(WANT_CORE)
 214
 215 if(WANT_QTCLIENT)
 216   install(TARGETS quasselclient
 217           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 218
 219   install(FILES quasselclient.desktop
 220           DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications)
 221 endif(WANT_QTCLIENT)
 222
 223 if(WANT_MONO)
 224   install(TARGETS quassel
 225           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 226
 227   install(FILES quassel.desktop
 228           DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications)
 229 endif(WANT_MONO)