CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   5 #                     : select binaries to build
   6 # -DWITH_OPENSSL=OFF  : Disable OpenSSL support
   7 # -DWITH_DBUS=OFF     : Disable D-Bus support (dbus notifications)
   8 # -DWITH_WEBKIT=OFF   : Disable WebKit support (link previews)
   9 # -DWITH_PHONON=OFF   : Disable Phonon support (audio notifications)
  10 # -DWITH_KDE=ON       : Enable KDE4 support
  11 #
  12 # -DEMBED_DATA=ON     : Embed all data files in icons the binary, rather than installing them separately
  13 #
  14 # -DQT=/path/to/qt    : Choose a Qt4 installation to use instead of the system Qt4
  15 # -DSTATIC=ON         : Enable static building of Quassel. Use with care.
  16 # -DDEPLOY=ON         : Mac OS X only. Use only for creating Quassel Packages!
  17 #
  18 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  19
  20 project(QuasselIRC)
  21
  22 cmake_minimum_required(VERSION 2.6.0 FATAL_ERROR)
  23
  24 if(COMMAND cmake_policy)
  25    cmake_policy(SET CMP0003 NEW)
  26 endif(COMMAND cmake_policy)
  27
  28 # Use our own (well, and KDE's) version of some modules
  29 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  30 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  31 include(QuasselMacros)
  32
  33 # Various options and variables that can be set on the command line
  34 option(WANT_CORE     "Build the core (server) binary"           ON)
  35 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  36 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  37
  38 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  39 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  40 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  41 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  42 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  43
  44 # We use icon paths from KDE 4.3 trunk, which are partially invalid on older and possibly
  45 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  46 # run on a matching KDE version only.
  47 option(WITH_OXYGEN   "Install Oxygen icons. Heavily recommended unless you use KDE 4.3" ON)
  48
  49 option(STATIC        "Enable static building (might not be portable)" OFF)
  50
  51 if(APPLE)
  52   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  53 endif(APPLE)
  54
  55 # Default to embedding data in the static case
  56 if(STATIC OR WIN32)
  57   set(EMBED_DEFAULT ON)
  58 else(STATIC OR WIN32)
  59   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  60 endif(STATIC OR WIN32)
  61
  62 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  63
  64 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  65 set(LINGUAS "" CACHE STRING "Comma-separated list of locales specifying languages that should be compiled")
  66
  67 # Some settings imply others
  68 if(STATIC)
  69   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  70 endif(STATIC)
  71
  72 if(WIN32)
  73   # We don't support separately installed resources yet on Win32
  74   set(EMBED_DATA ON)
  75 endif(WIN32)
  76
  77 # Build Type
  78 # We need to make sure it's not empty
  79 # Supported: Release, RelWithDebugInfo, Debug, Debugfull
  80
  81 # On WIN32, only Release seems to work correctly (?)
  82 if(WIN32)
  83   set(DEFAULT_BUILD_TYPE "Release")
  84 else(WIN32)
  85   set(DEFAULT_BUILD_TYPE "RelWithDebugInfo")
  86 endif(WIN32)
  87
  88 set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type")
  89 if(NOT CMAKE_BUILD_TYPE)
  90   set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type" FORCE)
  91 endif(NOT CMAKE_BUILD_TYPE)
  92
  93 # Enable various flags on gcc
  94 if(CMAKE_COMPILER_IS_GNUCXX)
  95   # Let's just hope that all gccs support these options and skip the tests...
  96   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor")
  97   set(CMAKE_CXX_FLAGS_RELWITHDEBUGINFO "-O2")
  98   set(CMAKE_CXX_FLAGS_DEBUG "-g -fno-reorder-blocks -fno-schedule-insns -fno-inline")
  99   set(CMAKE_CXX_FLAGS_DEBUGFULL "-g3")
 100 endif(CMAKE_COMPILER_IS_GNUCXX)
 101
 102 set(QT_MIN_VERSION "4.4.0")
 103
 104 if(APPLE AND DEPLOY)
 105   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
 106   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
 107   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
 108   add_definitions(-DMAC_10_4_SDK)
 109 endif(APPLE AND DEPLOY)
 110
 111 # Execinfo is needed for generating backtraces
 112 find_package(ExecInfo)
 113 if(EXECINFO_FOUND)
 114   add_definitions(-DHAVE_EXECINFO)
 115   include_directories(${EXECINFO_INCLUDES})
 116   link_libraries(${EXECINFO_LIBRARIES})
 117 endif(EXECINFO_FOUND)
 118
 119 # Select a Qt installation here, if you don't want to use system Qt
 120 if(QT)
 121   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 122   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 123 endif(QT)
 124
 125 # Now that we have the correct $PATH, lets find Qt!
 126 find_package(Qt4 REQUIRED)
 127
 128 set(QT_DONT_USE_QTGUI 1)
 129 include(${QT_USE_FILE})
 130 include_directories(${QT_INCLUDES})
 131
 132 # Setup OpenSSL
 133 if(WITH_OPENSSL)
 134   find_package(OpenSSL)
 135 else(WITH_OPENSSL)
 136   message(STATUS "Disabling OpenSSL support")
 137 endif(WITH_OPENSSL)
 138
 139 if(OPENSSL_FOUND)
 140   if(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 141     message(STATUS "Found OpenSSL support in Qt")
 142     add_definitions(-DHAVE_SSL)
 143     set(HAVE_SSL true)
 144     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_SSL)
 145   else(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 146     message(STATUS "No OpenSSL support found in Qt, disabling")
 147   endif(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 148 else(OPENSSL_FOUND)
 149   add_definitions(-DQT_NO_OPENSSL)
 150 endif(OPENSSL_FOUND)
 151
 152 # Setup D-Bus support
 153 if(WITH_DBUS)
 154   if(QT_QTDBUS_FOUND)
 155     message(STATUS "Found QtDBus, enabling D-Bus support")
 156     add_definitions(-DHAVE_DBUS)
 157     set(LINK_DBUS DBUS)
 158     set(HAVE_DBUS true)
 159     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_DBUS)
 160   else(QT_QTDBUS_FOUND)
 161     message(STATUS "QtDBus not found, disabling D-Bus support")
 162   endif(QT_QTDBUS_FOUND)
 163 else(WITH_DBUS)
 164   message(STATUS "Disabling D-Bus support")
 165 endif(WITH_DBUS)
 166
 167 # Setup QtWebKit support
 168 if(WITH_WEBKIT)
 169   if(QT_QTWEBKIT_FOUND)
 170     message(STATUS "Found QtWebKit, enabling WebKit support")
 171     add_definitions(-DHAVE_WEBKIT)
 172     set(LINK_WEBKIT WEBKIT)
 173     set(HAVE_WEBKIT true)
 174     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_WEBKIT)
 175   else(QT_QTWEBKIT_FOUND)
 176     message(STATUS "QtWebKit not found, disabling WebKit support")
 177   endif(QT_QTWEBKIT_FOUND)
 178 else(WITH_WEBKIT)
 179   message(STATUS "Disabling WebKit support")
 180 endif(WITH_WEBKIT)
 181
 182 # Setup KDE4 support
 183 if(WITH_KDE)
 184   find_package(KDE4)
 185   if(KDE4_FOUND)
 186     message(STATUS "Enabling KDE4 integration")
 187     include_directories(${KDE4_INCLUDES})
 188     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 189     set(HAVE_KDE 1)
 190     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_KDE)
 191     set(QUASSEL_KDE_LIBRARIES ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} knotifyconfig)
 192     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 193     set(EMBED_DATA OFF)
 194   else(KDE4_FOUND)
 195     message(STATUS "KDE4 not found, disabling KDE integration")
 196   endif(KDE4_FOUND)
 197 else(WITH_KDE)
 198   message(STATUS "Disabling KDE4 integration")
 199 endif(WITH_KDE)
 200
 201 # Setup Phonon support - we only need this if we don't have or want KDE4
 202 if(NOT HAVE_KDE)
 203   if(WITH_PHONON)
 204     find_package(Phonon)
 205     if(PHONON_FOUND)
 206       message(STATUS "Enabling Phonon support")
 207       add_definitions(-DHAVE_PHONON)
 208       set(HAVE_PHONON true)
 209       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_PHONON)
 210     else(PHONON_FOUND)
 211       message(STATUS "Phonon not found, disabling audio notifications")
 212     endif(PHONON_FOUND)
 213   else(WITH_PHONON)
 214     message(STATUS "Disabling Phonon support")
 215   endif(WITH_PHONON)
 216 endif(NOT HAVE_KDE)
 217
 218 # Now set up install locations; those are set by KDE if integration is enabled
 219 if(NOT HAVE_KDE)
 220   if(WIN32)
 221     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 222     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 223     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 224     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 225   else(WIN32)
 226     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 227     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 228     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 229     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 230   endif(WIN32)
 231 endif(NOT HAVE_KDE)
 232
 233 # RPATH needs to be set correctly
 234 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 235 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 236 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 237
 238 # Set global buildflags
 239 # This is very much non-portable, so don't use -DSTATIC until you know what
 240 # you do.
 241 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 242   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 243   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 244   if(HAVE_SSL)
 245     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 246   endif(HAVE_SSL)
 247 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 248
 249 if(WIN32)
 250   #if(STATIC)
 251   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 252   #endif(STATIC)
 253   if(HAVE_SSL)
 254      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 255   endif(HAVE_SSL)
 256 endif(WIN32)
 257
 258 if(WIN32)
 259   set(RC_WIN32 ../pics/win32.rc)  # for app icons on windows
 260 endif(WIN32)
 261
 262 # We need to create a version.gen
 263 # For this, we create our genversion binary and make sure it is run every time.
 264 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 265 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
 266
 267 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 268 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 269                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 270 add_dependencies(genversion_run genversion)
 271
 272 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 273 set(COMMON_DEPS ${RC_WIN32})
 274 set(CORE_DEPS )
 275 set(CLIENT_DEPS )
 276
 277 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 278 add_subdirectory(data)
 279 add_subdirectory(icons)
 280 add_subdirectory(pics)
 281 add_subdirectory(i18n)
 282 add_subdirectory(src)