CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 11)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.11-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37
  38 # Options and variables that can be set on the command line
  39 #####################################################################
  40
  41 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  42 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  43 if (USE_QT4) # takes precedence
  44     set(USE_QT5 OFF)
  45 else()
  46     if (NOT USE_QT5)
  47         set(USE_QT4 ON)
  48     endif()
  49 endif()
  50
  51 # Select the binaries to build
  52 option(WANT_CORE     "Build the core (server) binary"           ON)
  53 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  54 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  55 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  56 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  57 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  58
  59 # Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
  60 cmake_dependent_option(WITH_KDE "KDE4 integration" OFF "USE_QT4" OFF)
  61 add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  62
  63 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  64 if (NOT WITH_KDE)
  65     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  66 endif()
  67
  68 # For this, the feature info is added after we know if QtWebkit is installed
  69 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  70
  71 if (APPLE)
  72     # Notification Center is only available in > 10.8, which is Darwin v12
  73     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  75         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  76     endif()
  77 endif()
  78
  79 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  80 set(EMBED_DEFAULT OFF)
  81 if (STATIC OR WIN32 OR APPLE)
  82     set(EMBED_DEFAULT ON)
  83 endif()
  84 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  85                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  86 if (NOT EMBED_DEFAULT)
  87     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  88 endif()
  89
  90 # The following options are not for end-user consumption, so don't list them in the feature summary
  91 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  92
  93 # Handle with care
  94 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
  95
  96 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
  97 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
  98
  99 # For static builds, arbitrary extra libs might need to be linked
 100 # Define a comma-separated list here
 101 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 102 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 103 if (LINK_EXTRA)
 104     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 105     link_libraries(${LINK_EXTRA})
 106 endif()
 107
 108
 109 # Simplify later checks
 110 #####################################################################
 111
 112 if (WANT_MONO OR WANT_QTCLIENT)
 113     set(BUILD_GUI true)
 114 endif()
 115 if (WANT_MONO OR WANT_CORE)
 116     set(BUILD_CORE true)
 117 endif()
 118
 119
 120 # Set up Qt
 121 #####################################################################
 122
 123 if (USE_QT5)
 124     message(STATUS "Building for Qt5...")
 125     set(QT_MIN_VERSION "5.2.0")
 126     add_definitions(-DHAVE_QT5)
 127 else()
 128     message(STATUS "Building for Qt4...")
 129     if (BUILD_GUI)
 130         set(QT_MIN_VERSION "4.6.0")
 131     else()
 132         set(QT_MIN_VERSION "4.4.0")
 133     endif()
 134
 135     # Select a Qt installation here, if you don't want to use system Qt
 136     if(QT_PATH)
 137         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 138         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 139     endif()
 140 endif()
 141
 142 # Find package dependencies
 143 #
 144 # Note that you can forcefully disable optional packages
 145 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 146 #####################################################################
 147
 148 if(USE_QT5)
 149     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 150     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 151         URL "http://qt.digia.com"
 152         DESCRIPTION "contains core functionality for Qt"
 153     )
 154     find_package(Qt5Network QUIET)
 155     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 156         DESCRIPTION "the network module for Qt5"
 157     )
 158
 159     if (BUILD_GUI)
 160         find_package(Qt5Gui QUIET)
 161         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 162             DESCRIPTION "the GUI module for Qt5"
 163         )
 164         find_package(Qt5Widgets QUIET)
 165         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 166             DESCRIPTION "the widgets module for Qt5"
 167         )
 168
 169         find_package(Qt5DBus QUIET)
 170         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 171             URL "http://qt.digia.com"
 172             DESCRIPTION "D-Bus support for Qt5"
 173             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 174         )
 175         if (Qt5DBus_FOUND)
 176             find_package(dbusmenu-qt5 QUIET CONFIG)
 177             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 178                 URL "https://launchpad.net/libdbusmenu-qt"
 179                 DESCRIPTION "a library implementing the DBusMenu specification"
 180                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 181             )
 182         endif()
 183
 184         find_package(Phonon4Qt5 QUIET)
 185         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 186             URL "https://projects.kde.org/projects/kdesupport/phonon"
 187             DESCRIPTION "a multimedia abstraction library"
 188             PURPOSE     "Required for audio notifications"
 189         )
 190
 191         if (WITH_WEBKIT)
 192             find_package(Qt5WebKit QUIET)
 193             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 194                 URL "http://qt.digia.com"
 195                 DESCRIPTION "a WebKit implementation for Qt"
 196                 PURPOSE     "Needed for displaying previews for URLs in chat"
 197             )
 198             if (Qt5WebKit_FOUND)
 199                 find_package(Qt5WebKitWidgets QUIET)
 200                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 201                     URL "http://qt.digia.com"
 202                     DESCRIPTION "widgets for Qt's WebKit implementation"
 203                     PURPOSE     "Needed for displaying previews for URLs in chat"
 204                 )
 205             endif()
 206         endif()
 207         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 208
 209     endif(BUILD_GUI)
 210     if (BUILD_CORE)
 211         find_package(Qt5Script QUIET)
 212         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 213             DESCRIPTION "provides scripting support for Qt5"
 214         )
 215         find_package(Qt5Sql QUIET)
 216         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 217             DESCRIPTION "the database support module for Qt5"
 218         )
 219
 220         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 221         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 222         #find_package(QCA2 QUIET)
 223         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 224         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 225         #    DESCRIPTION "Qt Cryptographic Architecture"
 226         #    PURPOSE "Required for encryption support"
 227         #)
 228
 229     endif(BUILD_CORE)
 230
 231     find_package(Qt5LinguistTools QUIET)
 232     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 233                            DESCRIPTION "contains tools for handling translation files"
 234                            PURPOSE "Required for having translations"
 235     )
 236     # Qt5 does not define a target for lconvert, so we need to find it ourselves
 237     if (Qt5LinguistTools_FOUND)
 238         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 239             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 240             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 241             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 242         endif()
 243         # Compatibility with the Qt4 variables
 244         set (QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 245         set (QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 246     endif()
 247
 248 else(USE_QT5)
 249     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 250
 251     if (BUILD_GUI)
 252         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 253         if (QT_QTDBUS_FOUND)
 254             find_package(dbusmenu-qt QUIET CONFIG)
 255             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 256                 URL "https://launchpad.net/libdbusmenu-qt"
 257                 DESCRIPTION "a library implementing the DBusMenu specification"
 258                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 259             )
 260         endif()
 261
 262         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 263             set(HAVE_WEBKIT true)
 264         endif()
 265         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 266
 267         if (WITH_KDE)
 268             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 269             set(_cflags ${CMAKE_C_FLAGS})
 270             find_package(KDE4 4.4 QUIET)
 271             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 272                 URL "http://www.kde.org"
 273                 DESCRIPTION "a world-class desktop environment"
 274                 PURPOSE "Enables various bits for improving integration with KDE"
 275             )
 276             set(CMAKE_C_FLAGS ${_cflags})
 277
 278         else(WITH_KDE)
 279             find_package(Phonon QUIET)
 280             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 281                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 282                 DESCRIPTION "a multimedia abstraction library"
 283                 PURPOSE     "Required for audio notifications"
 284             )
 285
 286             find_package(Libsnore QUIET)
 287             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 288                 URL "https://github.com/TheOneRing/Snorenotify"
 289                 DESCRIPTION "a cross-platform notification framework"
 290                 PURPOSE     "Enable support for the snorenotify framework"
 291             )
 292         endif(WITH_KDE)
 293
 294         find_package(IndicateQt QUIET)
 295         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 296             URL "https://launchpad.net/libindicate-qt/"
 297             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 298             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 299         )
 300
 301     endif(BUILD_GUI)
 302     if (BUILD_CORE)
 303
 304         find_package(QCA2 QUIET)
 305         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 306             URL "https://projects.kde.org/projects/kdesupport/qca"
 307             DESCRIPTION "Qt Cryptographic Architecture"
 308             PURPOSE     "Required for encryption support"
 309         )
 310
 311
 312     endif()
 313
 314     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 315     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 316     if (QT_LRELEASE_EXECUTABLE)
 317         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 318         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 319     endif()
 320 endif()
 321
 322
 323 # Non-Qt-based packages
 324
 325 # zlib for compression, however we can always fall back to miniz
 326 find_package(ZLIB QUIET)
 327 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 328     URL "http://www.zlib.net"
 329     DESCRIPTION "a popular compression library"
 330     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 331 )
 332
 333
 334 if (NOT WIN32)
 335     # Execinfo is needed for generating backtraces
 336     find_package(ExecInfo QUIET)
 337     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 338         DESCRIPTION "a library for inspecting backtraces"
 339         PURPOSE "Used for generating backtraces in case of a crash"
 340     )
 341 endif()
 342
 343
 344 # Various checks
 345 #####################################################################
 346
 347 if (NOT ZLIB_FOUND)
 348     message(STATUS "zlib NOT found, using bundled miniz for compression")
 349     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 350         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 351     endif()
 352 endif()
 353
 354 if (KDE4_FOUND)
 355     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 356     set(EMBED_DATA OFF)
 357
 358     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 359     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 360 endif()
 361
 362 # Check for SSL support in Qt
 363 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 364 # a small test program checking the defines. This works for both Qt4 and Qt5.
 365 cmake_push_check_state(RESET)
 366 if (Qt5_POSITION_INDEPENDENT_CODE)
 367     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 368 endif()
 369 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 370 check_cxx_source_compiles("
 371     #include \"qglobal.h\"
 372     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 373     #  error \"No SSL support\"
 374     #endif
 375     int main() {}"
 376     HAVE_SSL)
 377 cmake_pop_check_state()
 378
 379 if (HAVE_SSL)
 380     add_definitions(-DHAVE_SSL)
 381 endif()
 382 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 383
 384 # Check for syslog support
 385 if (NOT WIN32)
 386     check_include_file(syslog.h HAVE_SYSLOG)
 387     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 388 endif()
 389
 390 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 391
 392 # Various settings
 393 ##################
 394
 395 # needed to compile with mingw without kde
 396 if (MINGW AND NOT KDE4_FOUND)
 397     add_definitions(-D_WIN32_WINNT=0x0500)
 398     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 399 # workaround for bug in mingw gcc 4.0
 400     add_definitions(-U__STRICT_ANSI__)
 401 endif()
 402
 403 # Now set up install locations; those are set by KDE if integration is enabled
 404 if(NOT KDE4_FOUND)
 405   if(WIN32)
 406     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 407     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 408     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 409     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 410   else(WIN32)
 411     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 412     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 413     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 414     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 415   endif(WIN32)
 416 endif()
 417
 418 if(EMBED_DATA)
 419   message(STATUS "Embedding data files into the binary")
 420 else(EMBED_DATA)
 421   message(STATUS "Installing data files separately")
 422 endif(EMBED_DATA)
 423
 424 # RPATH needs to be set correctly
 425 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 426 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 427 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 428
 429 # Set global buildflags
 430 # This is very much non-portable, so don't use -DSTATIC until you know what
 431 # you do.
 432 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 433   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 434   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 435   if(HAVE_SSL)
 436     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 437   endif(HAVE_SSL)
 438 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 439
 440 if(WIN32)
 441   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 442   if(MSVC)
 443     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 444     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 445     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 446     link_libraries(Version dwmapi shlwapi)
 447   endif(MSVC)
 448   if(HAVE_SSL AND STATIC)
 449      find_package(OpenSSL REQUIRED)
 450      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 451   endif(HAVE_SSL AND STATIC)
 452 endif(WIN32)
 453
 454 if(INDICATEQT_FOUND)
 455   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 456 endif()
 457
 458 if(NOT WIN32)
 459   check_function_exists(umask HAVE_UMASK)
 460   if(HAVE_UMASK)
 461     add_definitions(-DHAVE_UMASK)
 462   endif(HAVE_UMASK)
 463 endif(NOT WIN32)
 464
 465 # Generate version information from Git
 466 include(GetGitRevisionDescription)
 467 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 468 git_describe(GIT_DESCRIBE --long)
 469
 470 # Sanitize things if we're not in a Git repo
 471 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 472     set(GIT_HEAD "")
 473     set(GIT_DESCRIBE "")
 474 endif()
 475
 476 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 477
 478 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 479 set(COMMON_DEPS ${RC_WIN32})
 480 set(CORE_DEPS )
 481 set(CLIENT_DEPS )
 482
 483 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 484 add_subdirectory(data)
 485 add_subdirectory(icons)
 486 add_subdirectory(pics)
 487 add_subdirectory(po)
 488
 489 # Set up and display feature summary
 490 #####################################################################
 491
 492 feature_summary(WHAT ALL
 493                 INCLUDE_QUIET_PACKAGES
 494                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 495 )
 496
 497 # Finally, compile the sources
 498 # We want this after displaying the feature summary to avoid ugly
 499 # CMake backtraces in case a required Qt5 modules misses
 500 #####################################################################
 501
 502 add_subdirectory(src)