CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 # Versions
  10 set(QUASSEL_MAJOR  0)
  11 set(QUASSEL_MINOR 13)
  12 set(QUASSEL_PATCH 50)
  13 set(QUASSEL_VERSION_STRING "0.14-pre")
  14
  15 # Build type
  16 if (CMAKE_CONFIGURATION_TYPES)
  17     set(CMAKE_CONFIGURATION_TYPES Release RelWithDebInfo Debug Debugfull Profile)
  18     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING "These are the configuration types we support" FORCE)
  19 endif()
  20
  21 if(NOT CMAKE_BUILD_TYPE)
  22     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build, options are: Release RelWithDebInfo Debug Debugfull Profile None" FORCE)
  23 endif()
  24
  25 # Output CMake and Quassel versions as well as build type for debug reasons
  26 message(STATUS "Building Quassel ${QUASSEL_VERSION_STRING}...")
  27 message(STATUS "Using CMake ${CMAKE_VERSION}")
  28 message(STATUS "CMake build type: ${CMAKE_BUILD_TYPE}")
  29
  30 # Support ccache if found
  31 # This should happen before calling project(), so compiler settings are validated.
  32 option(USE_CCACHE "Enable support for ccache if available" ON)
  33 if (USE_CCACHE)
  34     message(STATUS "Checking for ccache")
  35     find_program(CCACHE_PROGRAM ccache)
  36     if (CCACHE_PROGRAM)
  37         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  38         message(STATUS "Checking for ccache - enabled")
  39     else()
  40         message(STATUS "Checking for ccache - not found")
  41     endif()
  42 endif()
  43
  44 # Set up project
  45 project(Quassel C CXX)
  46
  47 # General conveniences
  48 set(CMAKE_AUTOMOC ON)
  49 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  50
  51 # Include various CMake modules
  52 include(CMakePushCheckState)
  53 include(CheckFunctionExists)
  54 include(CheckIncludeFile)
  55 include(CheckCXXSourceCompiles)
  56 include(CMakeDependentOption)
  57 include(FeatureSummary)
  58
  59 # Tell CMake about or own modules
  60 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  61 include(QuasselCompileSettings)
  62 include(QuasselMacros)
  63
  64
  65 # Options and variables that can be set on the command line
  66 #####################################################################
  67
  68 # Select the binaries to build
  69 option(WANT_CORE     "Build the core (server) binary"           ON)
  70 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  71 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  72 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  73 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  74 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  75
  76 # Whether to enable integration with higher-tier KDE frameworks that require runtime support.
  77 # We still optionally make use of certain Tier 1 frameworks even if WITH_KDE is disabled.
  78 option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  79 add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  80
  81 # Icon theme support. By default, install the Breeze icon theme (may be disabled if a system installation is present)
  82 option(WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme" ON)
  83 add_feature_info(WITH_BUNDLED_ICONS WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme")
  84
  85 option(WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)" OFF)
  86 add_feature_info(WITH_OXYGEN_ICONS WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)")
  87
  88 if (WITH_BUNDLED_ICONS)
  89     add_definitions(-DWITH_BUNDLED_ICONS)
  90 endif()
  91 if (WITH_OXYGEN_ICONS)
  92     add_definitions(-DWITH_OXYGEN_ICONS)
  93 endif()
  94
  95 # For this, the feature info is added after we know if QtWebkit is installed
  96 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  97
  98 # For this, the feature info is added after we know if QtWebEngine is installed
  99 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
 100
 101 if (APPLE)
 102     # Notification Center is only available in > 10.8, which is Darwin v12
 103     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
 104         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
 105         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
 106     endif()
 107     find_library(CARBON_LIBRARY Carbon)
 108     mark_as_advanced(CARBON_LIBRARY)
 109     link_libraries(${CARBON_LIBRARY})
 110 endif()
 111
 112 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
 113 set(EMBED_DEFAULT OFF)
 114 if (STATIC OR WIN32 OR APPLE)
 115     set(EMBED_DEFAULT ON)
 116 endif()
 117 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 118                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 119 if (NOT EMBED_DEFAULT)
 120     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 121 endif()
 122
 123 # The following options are not for end-user consumption, so don't list them in the feature summary
 124 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 125
 126 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 127 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 128
 129 # For static builds, arbitrary extra libs might need to be linked
 130 # Define a comma-separated list here
 131 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 132 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 133 if (LINK_EXTRA)
 134     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 135     link_libraries(${LINK_EXTRA})
 136 endif()
 137
 138
 139 # List of authenticators and the cmake flags to build them
 140 # (currently that's just LDAP, but more can be added here).
 141 ####################################################################
 142 option(WITH_LDAP "Enable LDAP authentication support if present on system" ON)
 143
 144 # Setup CMake
 145 #####################################################################
 146
 147 if (WITH_KDE)
 148     cmake_minimum_required(VERSION 2.8.12)
 149 else()
 150     cmake_minimum_required(VERSION 2.8.9)
 151 endif()
 152
 153 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 154 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 155 if (POLICY CMP0043)
 156     cmake_policy(SET CMP0043 OLD)
 157 endif()
 158
 159 # Honor visibility settings for all target types
 160 if (POLICY CMP0063)
 161     cmake_policy(SET CMP0063 NEW)
 162 endif()
 163
 164 # Don't automoc generated files
 165 if (POLICY CMP0071)
 166     cmake_policy(SET CMP0071 OLD)
 167 endif()
 168
 169
 170 # Simplify later checks
 171 #####################################################################
 172
 173 if (WANT_MONO OR WANT_QTCLIENT)
 174     set(BUILD_GUI true)
 175 endif()
 176 if (WANT_MONO OR WANT_CORE)
 177     set(BUILD_CORE true)
 178 endif()
 179
 180
 181 # Set up Qt
 182 #####################################################################
 183
 184 # Find package dependencies
 185 #
 186 # Note that you can forcefully disable optional packages
 187 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 188 #####################################################################
 189
 190 set(QT_MIN_VERSION "5.5.0")
 191 add_definitions(-DHAVE_QT5)
 192
 193 find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 194 set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 195     URL "https://www.qt.io/"
 196     DESCRIPTION "contains core functionality for Qt"
 197 )
 198
 199 # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 200 # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 201 if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 202     message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 203 endif()
 204
 205 find_package(Qt5Network QUIET)
 206 set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 207     DESCRIPTION "the network module for Qt5"
 208 )
 209
 210 if (BUILD_GUI)
 211     find_package(Qt5Gui QUIET)
 212     set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 213         DESCRIPTION "the GUI module for Qt5"
 214     )
 215     find_package(Qt5Widgets QUIET)
 216     set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 217         DESCRIPTION "the widgets module for Qt5"
 218     )
 219
 220     if (NOT WIN32)
 221         find_package(Qt5DBus QUIET)
 222         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 223             URL "https://www.qt.io/"
 224             DESCRIPTION "D-Bus support for Qt5"
 225             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 226         )
 227         if (Qt5DBus_FOUND)
 228             find_package(dbusmenu-qt5 QUIET CONFIG)
 229             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 230                 URL "https://launchpad.net/libdbusmenu-qt"
 231                 DESCRIPTION "a library implementing the DBusMenu specification"
 232                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 233             )
 234         endif()
 235     endif()
 236
 237     find_package(Qt5Multimedia QUIET)
 238     set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 239         URL "https://www.qt.io/"
 240         DESCRIPTION "Multimedia support for Qt5"
 241         PURPOSE     "Required for audio notifications"
 242     )
 243
 244     find_package(LibsnoreQt5 0.7.0 QUIET)
 245     set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 246         URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 247         DESCRIPTION "a cross-platform notification framework"
 248         PURPOSE     "Enable support for the snorenotify framework"
 249     )
 250     if(LibsnoreQt5_FOUND)
 251         find_package(LibsnoreSettingsQt5)
 252         set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 253             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 254             DESCRIPTION "a cross-platform notification framework"
 255             PURPOSE     "Enable support for the snorenotify framework"
 256         )
 257     endif()
 258
 259     if (WITH_WEBKIT)
 260         find_package(Qt5WebKit QUIET)
 261         set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 262             URL "https://www.qt.io/"
 263             DESCRIPTION "a WebKit implementation for Qt"
 264             PURPOSE     "Needed for displaying previews for URLs in chat"
 265         )
 266         if (Qt5WebKit_FOUND)
 267             find_package(Qt5WebKitWidgets QUIET)
 268             set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 269                 URL "https://www.qt.io/"
 270                 DESCRIPTION "widgets for Qt's WebKit implementation"
 271                 PURPOSE     "Needed for displaying previews for URLs in chat"
 272             )
 273         endif()
 274     endif()
 275
 276     if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 277         set(HAVE_WEBKIT true)
 278     endif()
 279     add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 280
 281     if (WITH_WEBENGINE)
 282         find_package(Qt5WebEngine QUIET)
 283         set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 284             URL "https://www.qt.io/"
 285             DESCRIPTION "a WebEngine implementation for Qt"
 286             PURPOSE     "Needed for displaying previews for URLs in chat"
 287         )
 288         if (Qt5WebEngine_FOUND)
 289             find_package(Qt5WebEngineWidgets QUIET)
 290             set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 291                 URL "https://www.qt.io/"
 292                 DESCRIPTION "widgets for Qt's WebEngine implementation"
 293                 PURPOSE     "Needed for displaying previews for URLs in chat"
 294             )
 295         endif()
 296     endif()
 297
 298     if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 299         set(HAVE_WEBENGINE true)
 300     endif()
 301     add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 302
 303     # KDE Frameworks
 304     ################
 305
 306     if (WITH_KDE)
 307         set(ecm_find_type "REQUIRED")
 308     else()
 309         # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 310         set(ecm_find_type "RECOMMENDED")
 311     endif()
 312
 313     # extra-cmake-modules
 314     find_package(ECM NO_MODULE QUIET)
 315     set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 316         URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 317         DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 318         PURPOSE     "Required to find KDE Frameworks components"
 319     )
 320
 321     if (ECM_FOUND)
 322         list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 323         if (WITH_KDE)
 324             find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig Sonnet TextWidgets WidgetsAddons XmlGui QUIET)
 325             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 326                 URL "http://www.kde.org"
 327                 DESCRIPTION "KDE Frameworks"
 328                 PURPOSE     "Required for integration into the Plasma desktop"
 329             )
 330         else()
 331             find_package(KF5Sonnet QUIET)
 332             set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 333                 URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 334                 DESCRIPTION "framework for providing spell-checking capabilities"
 335                 PURPOSE "Enables spell-checking support in input widgets"
 336             )
 337         endif()
 338     endif()
 339
 340 endif()
 341
 342 if (BUILD_CORE)
 343     find_package(Qt5Script QUIET)
 344     set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 345         DESCRIPTION "provides scripting support for Qt5"
 346     )
 347     find_package(Qt5Sql QUIET)
 348     set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 349         DESCRIPTION "the database support module for Qt5"
 350     )
 351
 352     find_package(QCA2-QT5)
 353     set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 354         URL "https://projects.kde.org/projects/kdesupport/qca"
 355         DESCRIPTION "Qt Cryptographic Architecture"
 356         PURPOSE "Required for encryption support"
 357     )
 358
 359 endif()
 360
 361 find_package(Qt5LinguistTools QUIET)
 362 set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 363     DESCRIPTION "contains tools for handling translation files"
 364     PURPOSE "Required for having translations"
 365 )
 366
 367 # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 368 if (Qt5LinguistTools_FOUND)
 369     if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 370         get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 371         get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 372         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 373     elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 374         # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 375         get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 376     endif()
 377
 378     # Compatibility with the Qt4 variables
 379     set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 380     set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 381     if (Qt5_LCONVERT_EXECUTABLE)
 382         set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 383     endif()
 384 endif()
 385
 386 # Non-Qt-based packages
 387
 388 find_package(ZLIB REQUIRED)
 389 set_package_properties(ZLIB PROPERTIES TYPE REQUIRED
 390     URL "http://www.zlib.net"
 391     DESCRIPTION "a popular compression library"
 392     PURPOSE     "Used for protocol compression"
 393 )
 394
 395 if (NOT WIN32)
 396     # Execinfo is needed for generating backtraces
 397     find_package(ExecInfo QUIET)
 398     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 399         DESCRIPTION "a library for inspecting backtraces"
 400         PURPOSE "Used for generating backtraces in case of a crash"
 401     )
 402 endif()
 403
 404 # Check for SSL support in Qt
 405 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 406 # a small test program checking the defines. This works for both Qt4 and Qt5.
 407 cmake_push_check_state(RESET)
 408 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 409 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 410
 411 if (Qt5_POSITION_INDEPENDENT_CODE)
 412     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 413 endif()
 414
 415 check_cxx_source_compiles("
 416     #include \"qglobal.h\"
 417     #if defined QT_NO_SSL
 418     #  error \"No SSL support\"
 419     #endif
 420     int main() {}"
 421     HAVE_SSL)
 422 cmake_pop_check_state()
 423
 424 # Additional compile settings
 425 #####################################################################
 426
 427 # This sets -fPIC and friends if required by the installed Qt5 library
 428 if (Qt5_POSITION_INDEPENDENT_CODE)
 429     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 430     set(CMAKE_REQUIRED_FLAGS "-DQT_NO_VERSION_TAGGING")
 431 endif()
 432
 433 # Needed to compile with mingw without kde
 434 if (MINGW AND NOT WITH_KDE)
 435     add_definitions(-D_WIN32_WINNT=0x0500)
 436     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 437     # workaround for bug in mingw gcc 4.0
 438     add_definitions(-U__STRICT_ANSI__)
 439 endif()
 440
 441 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 442 if (CMAKE_COMPILER_IS_GNUCXX)
 443     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 444 endif()
 445
 446 # Setup LDAP Authentication support.
 447 #####################################################################
 448 if (WITH_LDAP)
 449     find_package(Ldap)
 450     if (LDAP_FOUND)
 451         message(STATUS "Enabling LDAP authentication support")
 452         set(HAVE_LDAP true)
 453         add_definitions(-DHAVE_LDAP)
 454     else()
 455         message(STATUS "Disabling LDAP authentication support")
 456     endif()
 457 else()
 458     message(STATUS "Not enabling LDAP authentication support")
 459 endif()
 460
 461 # Setup support for KDE Frameworks
 462 #####################################################################
 463
 464 # We want to do this up here, so we have the necessary variables and defines set before
 465 # compiling anything
 466
 467 if (WITH_KDE)
 468     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 469     set(EMBED_DATA OFF)
 470
 471     include(KDEInstallDirs)
 472     include(KDECompilerSettings)
 473     include(KDECMakeSettings)
 474
 475     kde_enable_exceptions()
 476     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 477     set(WITH_KF5 TRUE)
 478 endif()
 479
 480 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 481 include(QuasselInstallDirs)
 482
 483 # Various config-dependent checks and settings
 484 #####################################################################
 485
 486 if (HAVE_SSL)
 487     add_definitions(-DHAVE_SSL)
 488 endif()
 489 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 490
 491 # Check for syslog support
 492 if (NOT WIN32)
 493     check_include_file(syslog.h HAVE_SYSLOG)
 494     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 495 endif()
 496
 497 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 498
 499 if (EMBED_DATA)
 500     message(STATUS "Embedding data files into the binary")
 501 else()
 502     message(STATUS "Installing data files separately")
 503 endif()
 504
 505 if (NOT WIN32)
 506     check_function_exists(umask HAVE_UMASK)
 507     if(HAVE_UMASK)
 508         add_definitions(-DHAVE_UMASK)
 509     endif()
 510 endif()
 511
 512
 513 # Windows-specific stuff
 514 #####################################################################
 515
 516 if (WIN32)
 517     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 518     if (MSVC)
 519         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 520         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 521         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 522         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 523         link_libraries(Version dwmapi shlwapi)
 524         set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 525     endif()
 526     if(HAVE_SSL AND STATIC)
 527         find_package(OpenSSL REQUIRED)
 528         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 529     endif()
 530 endif()
 531
 532
 533 # Static builds (very much non-portable, so don't use -DSTATIC
 534 # unless you know what you do!)
 535 #####################################################################
 536
 537 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 538     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 539     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 540     if (HAVE_SSL)
 541         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 542     endif()
 543 endif()
 544
 545
 546 # Generate version information from Git
 547 #####################################################################
 548
 549 include(GetGitRevisionDescription)
 550 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 551 git_describe(GIT_DESCRIBE --long)
 552
 553 # If in a Git repo we can get the commit-date from a git command
 554 if (GIT_HEAD)
 555     execute_process(
 556         COMMAND git -c log.showsignature=false show -s --format=%ct
 557         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 558         OUTPUT_VARIABLE GIT_COMMIT_DATE
 559         OUTPUT_STRIP_TRAILING_WHITESPACE
 560     )
 561 endif()
 562
 563 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 564 # enviroment
 565 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 566   if (DEFINED ENV{GIT_HEAD})
 567       set(GIT_HEAD $ENV{GIT_HEAD})
 568   endif()
 569   if (DEFINED ENV{GIT_DESCRIBE})
 570      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 571   endif()
 572 endif()
 573
 574 # Sanitize things if we're not in a Git repo
 575 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 576     set(GIT_HEAD "")
 577     set(GIT_DESCRIBE "")
 578     set(GIT_COMMIT_DATE 0)
 579 endif()
 580
 581 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 582
 583 # Prepare the build
 584 #####################################################################
 585
 586 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 587 set(COMMON_DEPS ${RC_WIN32})
 588 set(CORE_DEPS )
 589 set(CLIENT_DEPS )
 590
 591 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 592 add_subdirectory(data)
 593 add_subdirectory(icons)
 594 add_subdirectory(pics)
 595 add_subdirectory(po)
 596
 597
 598 # Set up and display feature summary
 599 #####################################################################
 600
 601 feature_summary(WHAT ALL
 602                 INCLUDE_QUIET_PACKAGES
 603                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 604 )
 605
 606 # Finally, compile the sources
 607 # We want this after displaying the feature summary to avoid ugly
 608 # CMake backtraces in case a required Qt5 module is missing
 609 #####################################################################
 610
 611 add_subdirectory(src)