common: Remove the copy assignment operator from DccConfig
[quassel.git] / CMakeLists.txt
1 # Main CMake file for building Quassel IRC
2 #
3 # See INSTALL for possible CMake options (or read the code, Luke)
4 #####################################################################
5
6 # General setup
7 #####################################################################
8
9 cmake_minimum_required(VERSION 3.5)
10
11 # Tell CMake about or own modules
12 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
13
14 include(QuasselVersion)
15
16 message(STATUS "Using CMake ${CMAKE_VERSION}")
17
18 # Set up build type rather early
19 include(BuildType)
20
21 # Support ccache if found
22 # This should happen before calling project(), so compiler settings are validated.
23 option(USE_CCACHE "Enable support for ccache if available" ON)
24 if (USE_CCACHE)
25     message(STATUS "Checking for ccache")
26     find_program(CCACHE_PROGRAM ccache)
27     if (CCACHE_PROGRAM)
28         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
29         message(STATUS "Checking for ccache - enabled")
30     else()
31         message(STATUS "Checking for ccache - not found")
32     endif()
33 endif()
34
35 # Set up project
36 project(Quassel CXX)
37
38 # Let CMake handle file generation for Qt
39 set(CMAKE_AUTOMOC ON)
40 set(CMAKE_AUTORCC ON)
41 set(CMAKE_AUTOUIC ON)
42
43 # Needed, otherwise some .moc files won't be found with older CMake versions
44 set(CMAKE_INCLUDE_CURRENT_DIR ON)
45
46 # Include various CMake modules...
47 include(CMakePushCheckState)
48 include(CheckFunctionExists)
49 include(CheckIncludeFileCXX)
50 include(CheckCXXSourceCompiles)
51 include(CMakeDependentOption)
52 include(FeatureSummary)
53
54 # ... and our own
55 include(QuasselCompileSettings)
56 include(QuasselMacros)
57
58 # Options and variables that can be set on the command line
59 #####################################################################
60
61 # Select the binaries to build
62 option(WANT_CORE     "Build the core (server) binary"           ON)
63 option(WANT_QTCLIENT "Build the client-only binary"             ON)
64 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
65 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
66 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
67 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
68
69 # Whether to enable integration with higher-tier KDE frameworks that require runtime support.
70 # We still optionally make use of certain Tier 1 frameworks even if WITH_KDE is disabled.
71 option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
72 add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
73
74 # Icon theme support. By default, install the Breeze icon theme (may be disabled if a system installation is present)
75 option(WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme" ON)
76 add_feature_info(WITH_BUNDLED_ICONS WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme")
77
78 option(WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)" OFF)
79 add_feature_info(WITH_OXYGEN_ICONS WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)")
80
81 # For this, the feature info is added after we know if QtWebkit is installed
82 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
83
84 # For this, the feature info is added after we know if QtWebEngine is installed
85 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
86
87 if (APPLE)
88     # Notification Center is only available in > 10.8, which is Darwin v12
89     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
90         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
91         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
92     endif()
93     find_library(CARBON_LIBRARY Carbon)
94     mark_as_advanced(CARBON_LIBRARY)
95     link_libraries(${CARBON_LIBRARY})
96 endif()
97
98 # Always embed on Windows or OSX; never embed when enabling KDE integration
99 set(EMBED_DEFAULT OFF)
100 if (WIN32 OR APPLE)
101     set(EMBED_DEFAULT ON)
102 endif()
103 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
104                                    "NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
105 if (NOT EMBED_DEFAULT)
106     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
107 endif()
108
109 # The following options are not for end-user consumption, so don't list them in the feature summary
110 option(FATAL_WARNINGS "Make compile warnings fatal (most useful for CI builds)" OFF)
111 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg" OFF "APPLE" OFF)
112
113 # List of authenticators and the cmake flags to build them
114 # (currently that's just LDAP, but more can be added here).
115 ####################################################################
116 option(WITH_LDAP "Enable LDAP authentication support if present on system" ON)
117
118 # Setup CMake
119 #####################################################################
120
121 # Visibility settings apply to all targets
122 if (POLICY CMP0063)
123     cmake_policy(SET CMP0063 NEW)
124 endif()
125
126 # Let automoc/autouic process generated files
127 if (POLICY CMP0071)
128     cmake_policy(SET CMP0071 NEW)
129 endif()
130
131 set(BUILD_SHARED_LIBS TRUE CACHE BOOL "" FORCE)
132
133 # Don't use X11 on OSX
134 if (APPLE)
135     set(CMAKE_DISABLE_FIND_PACKAGE_X11 true)
136     set(CMAKE_DISABLE_FIND_PACKAGE_XCB true)
137     set(CMAKE_DISABLE_FIND_PACKAGE_Qt5X11Extras true)
138 endif()
139
140 # Simplify later checks
141 #####################################################################
142
143 if (WANT_MONO OR WANT_QTCLIENT)
144     set(BUILD_GUI true)
145 endif()
146 if (WANT_MONO OR WANT_CORE)
147     set(BUILD_CORE true)
148 endif()
149
150 # Set up Qt
151 #####################################################################
152
153 # Find package dependencies
154 #
155 # Note that you can forcefully disable optional packages
156 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
157 #####################################################################
158
159 set(QT_MIN_VERSION "5.5.0")
160
161 # Required Qt components
162 set(qt_components Core Network)
163 if (BUILD_GUI)
164     list(APPEND qt_components Gui Widgets)
165 endif()
166 if (BUILD_CORE)
167     list(APPEND qt_components Script Sql)
168 endif()
169
170 find_package(Qt5 ${QT_MIN_VERSION} REQUIRED COMPONENTS ${qt_components})
171 set_package_properties(Qt5 PROPERTIES TYPE REQUIRED
172     URL "https://www.qt.io/"
173     DESCRIPTION "the Qt libraries"
174 )
175 message(STATUS "Found Qt ${Qt5Core_VERSION}")
176
177 # Optional Qt components
178
179 find_package(Qt5LinguistTools QUIET)
180 set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
181     DESCRIPTION "contains tools for handling translation files"
182     PURPOSE "Required for having translations"
183 )
184
185 if (BUILD_GUI)
186     if (NOT WIN32)
187         find_package(Qt5DBus QUIET)
188         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
189             URL "https://www.qt.io/"
190             DESCRIPTION "D-Bus support for Qt5"
191             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
192         )
193         if (Qt5DBus_FOUND)
194             find_package(dbusmenu-qt5 QUIET CONFIG)
195             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
196                 URL "https://launchpad.net/libdbusmenu-qt"
197                 DESCRIPTION "a library implementing the DBusMenu specification"
198                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
199             )
200         endif()
201     endif()
202
203     find_package(Qt5Multimedia QUIET)
204     set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
205         URL "https://www.qt.io/"
206         DESCRIPTION "Multimedia support for Qt5"
207         PURPOSE     "Required for audio notifications"
208     )
209
210     # snorenotify segfaults on startup on msys2
211     # we don't check for just MSYS to support the Ninja generator
212     if(NOT (WIN32 AND (NOT $ENV{MSYSTEM} STREQUAL "")))
213         find_package(LibsnoreQt5 0.7.0 QUIET)
214         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
215             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
216             DESCRIPTION "a cross-platform notification framework"
217             PURPOSE     "Enable support for the snorenotify framework"
218         )
219         if (LibsnoreQt5_FOUND)
220             find_package(LibsnoreSettingsQt5 QUIET)
221             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE OPTIONAL
222                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
223                 DESCRIPTION "a cross-platform notification framework"
224                 PURPOSE     "Enable support for the snorenotify framework"
225             )
226         endif()
227     endif()
228
229     if (WITH_WEBENGINE)
230         find_package(Qt5WebEngine QUIET)
231         set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
232             URL "https://www.qt.io/"
233             DESCRIPTION "a WebEngine implementation for Qt"
234             PURPOSE     "Needed for displaying previews for URLs in chat"
235         )
236         if (Qt5WebEngine_FOUND)
237             find_package(Qt5WebEngineWidgets QUIET)
238             set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
239                 URL "https://www.qt.io/"
240                 DESCRIPTION "widgets for Qt's WebEngine implementation"
241                 PURPOSE     "Needed for displaying previews for URLs in chat"
242             )
243         endif()
244     endif()
245
246     if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
247         set(HAVE_WEBENGINE true)
248     endif()
249     add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
250
251     if (NOT HAVE_WEBENGINE)
252         if (WITH_WEBKIT)
253             find_package(Qt5WebKit QUIET)
254             set_package_properties(Qt5WebKit PROPERTIES TYPE OPTIONAL
255                 URL "https://www.qt.io/"
256                 DESCRIPTION "a WebKit implementation for Qt"
257                 PURPOSE     "Needed for displaying previews for URLs in chat"
258                 )
259             if (Qt5WebKit_FOUND)
260                 find_package(Qt5WebKitWidgets QUIET)
261                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE OPTIONAL
262                     URL "https://www.qt.io/"
263                     DESCRIPTION "widgets for Qt's WebKit implementation"
264                     PURPOSE     "Needed for displaying previews for URLs in chat"
265                     )
266             endif()
267         endif()
268
269         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
270             set(HAVE_WEBKIT true)
271         endif()
272         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
273     endif()
274
275     # KDE Frameworks
276     ################
277
278     # extra-cmake-modules
279     if (WITH_KDE)
280         set(ecm_find_type "REQUIRED")
281         find_package(ECM NO_MODULE REQUIRED)
282     else()
283         # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
284         set(ecm_find_type "RECOMMENDED")
285         find_package(ECM NO_MODULE QUIET)
286     endif()
287
288     set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
289         URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
290         DESCRIPTION "extra modules for CMake, maintained by the KDE project"
291         PURPOSE     "Required to find KDE Frameworks components"
292     )
293
294     if (ECM_FOUND)
295         list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
296         if (WITH_KDE)
297             find_package(KF5 REQUIRED COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig Sonnet TextWidgets WidgetsAddons XmlGui)
298             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
299                 URL "http://www.kde.org"
300                 DESCRIPTION "KDE Frameworks"
301                 PURPOSE     "Required for integration into the Plasma desktop"
302             )
303             message(STATUS "Found KDE Frameworks ${KF5_VERSION}")
304         endif()
305
306         # Optional KF5 tier1 components
307         find_package(KF5Sonnet QUIET)
308         set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
309             URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
310             DESCRIPTION "framework for providing spell-checking capabilities"
311             PURPOSE "Enables spell-checking support in input widgets"
312         )
313     endif()
314 endif()
315
316 if (BUILD_CORE)
317     find_package(Qca-qt5 2.0 QUIET)
318     set_package_properties(Qca-qt5 PROPERTIES TYPE RECOMMENDED
319         URL "https://projects.kde.org/projects/kdesupport/qca"
320         DESCRIPTION "Qt Cryptographic Architecture"
321         PURPOSE "Required for encryption support"
322     )
323
324     if (WITH_LDAP)
325         find_package(Ldap QUIET)
326         set_package_properties(Ldap PROPERTIES TYPE OPTIONAL
327             URL "http://www.openldap.org/"
328             DESCRIPTION "LDAP (Lightweight Directory Access Protocol) libraries"
329             PURPOSE "Enables core user authentication via LDAP"
330         )
331     endif()
332 endif()
333
334 # Non-Qt-based packages
335 #####################################################################
336
337 find_package(Boost 1.54 REQUIRED)
338 set_package_properties(Boost PROPERTIES TYPE REQUIRED
339     URL "https://www.boost.org/"
340     DESCRIPTION "Boost libraries for C++"
341 )
342 # Older versions don't define the imported target
343 if (NOT TARGET Boost::boost)
344     add_library(Boost::boost INTERFACE IMPORTED GLOBAL)
345     if (Boost_INCLUDE_DIRS)
346         set_target_properties(Boost::boost PROPERTIES
347             INTERFACE_INCLUDE_DIRECTORIES "${Boost_INCLUDE_DIRS}")
348     endif()
349 endif()
350
351 find_package(ZLIB REQUIRED)
352 set_package_properties(ZLIB PROPERTIES TYPE REQUIRED
353     URL "http://www.zlib.net"
354     DESCRIPTION "a popular compression library"
355     PURPOSE     "Used for protocol compression"
356 )
357
358 if (NOT WIN32)
359     # Needed for generating backtraces
360     find_package(Backtrace QUIET)
361     set_package_properties(Backtrace PROPERTIES TYPE RECOMMENDED
362         DESCRIPTION "a header (and possibly library) for inspecting backtraces"
363         PURPOSE "Used for generating backtraces in case of a crash"
364     )
365 endif()
366
367 # Shared library support
368 #####################################################################
369
370 option(ENABLE_SHARED "Build modules as shared libraries" ON)
371 add_feature_info(ENABLE_SHARED ENABLE_SHARED "Build modules as shared libraries")
372
373 # Setup unit testing
374 #####################################################################
375
376 option(BUILD_TESTING "Enable unit tests" OFF)
377 add_feature_info(BUILD_TESTING BUILD_TESTING "Build unit tests")
378
379 if (BUILD_TESTING)
380     find_package(GTest QUIET)
381     set_package_properties(GTest PROPERTIES TYPE REQUIRED
382         DESCRIPTION "Google's unit testing framework"
383         PURPOSE "Required for building unit tests"
384     )
385
386     find_package(Qt5Test QUIET)
387     set_package_properties(Qt5Test PROPERTIES TYPE REQUIRED
388         DESCRIPTION "unit testing library for the Qt5 framework"
389         PURPOSE "Required for building unit tests"
390     )
391     enable_testing()
392
393     # GTest messes with CMAKE_CXX_FLAGS, so process them again
394     process_cmake_cxx_flags()
395 endif()
396
397 # Check for SSL support in Qt
398 #####################################################################
399
400 cmake_push_check_state(RESET)
401 set(CMAKE_REQUIRED_LIBRARIES Qt5::Core)
402 check_cxx_source_compiles("
403     #include \"qglobal.h\"
404     #if defined QT_NO_SSL
405     #  error \"No SSL support\"
406     #endif
407     int main() {}"
408     HAVE_SSL)
409 cmake_pop_check_state()
410
411 if (HAVE_SSL)
412     add_definitions(-DHAVE_SSL)
413 endif()
414 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
415
416 # Setup support for KDE Frameworks
417 #####################################################################
418
419 if (WITH_KDE)
420     add_definitions(-DHAVE_KDE -DHAVE_KF5)
421     set(WITH_KF5 TRUE)
422
423     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
424     set(EMBED_DATA OFF)
425
426     include(KDEInstallDirs)
427 endif()
428
429 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
430 include(QuasselInstallDirs)
431
432 # RPATH and output settings
433 #####################################################################
434
435 # Build artifacts in a well-known location; especially important for Windows DLLs
436 # (which go into RUNTIME_OUTPUT_DIRECTORY and can thus be found by executables)
437 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
438 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
439 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
440
441 # These RPATH settings allow for running directly from the build dir
442 set(CMAKE_SKIP_BUILD_RPATH            FALSE)
443 set(CMAKE_BUILD_WITH_INSTALL_RPATH    FALSE)
444 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE )
445
446 # Set install RPATH only if libdir isn't a system directory
447 if (IS_ABSOLUTE "${CMAKE_INSTALL_LIBDIR}")
448     set(libdir "${CMAKE_INSTALL_LIBDIR}")
449 else()
450     set(libdir "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}")
451 endif()
452 list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${libdir}" is_systemdir)
453 if ("${is_systemdir}" STREQUAL "-1")
454    set(CMAKE_INSTALL_RPATH "${libdir}")
455 endif()
456
457 # Various config-dependent checks and settings
458 #####################################################################
459
460 # Check for syslog support
461 if (NOT WIN32)
462     check_include_file_cxx(syslog.h HAVE_SYSLOG)
463     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
464 endif()
465
466 if (NOT WIN32)
467     check_function_exists(umask HAVE_UMASK)
468 endif()
469
470 if (EMBED_DATA)
471     message(STATUS "Embedding data files into the binary")
472 else()
473     message(STATUS "Installing data files separately")
474 endif()
475
476 # Windows-specific stuff
477 #####################################################################
478
479 if (WIN32)
480     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
481     if (MSVC)
482         link_libraries(Version dwmapi shlwapi)
483     endif()
484 endif()
485
486 # Prepare the build
487 #####################################################################
488
489 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
490 add_subdirectory(data)
491 add_subdirectory(icons)
492 add_subdirectory(pics)
493 add_subdirectory(po)
494
495 # Set up and display feature summary
496 #####################################################################
497
498 feature_summary(WHAT ALL
499                 INCLUDE_QUIET_PACKAGES
500                 FATAL_ON_MISSING_REQUIRED_PACKAGES
501 )
502
503 # Finally, compile the sources
504 # We want this after displaying the feature summary to avoid ugly
505 # CMake backtraces in case a required Qt5 module is missing
506 #####################################################################
507
508 add_subdirectory(src)
509
510 # Build tests if so desired
511 if (BUILD_TESTING)
512     add_subdirectory(tests)
513 endif()