CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   5 #                     : select binaries to build
   6 # -DWITH_OPENSSL=OFF  : Disable OpenSSL support
   7 # -DWITH_DBUS=OFF     : Disable D-Bus support (dbus notifications)
   8 # -DWITH_WEBKIT=OFF   : Disable WebKit support (link previews)
   9 # -DWITH_PHONON=OFF   : Disable Phonon support (audio notifications)
  10 # -DWITH_KDE=ON       : Enable KDE4 support
  11 #
  12 # -DEMBED_DATA=ON     : Embed all data files in icons the binary, rather than installing them separately
  13 #
  14 # -DQT=/path/to/qt    : Choose a Qt4 installation to use instead of the system Qt4
  15 # -DSTATIC=ON         : Enable static building of Quassel. Use with care.
  16 # -DDEPLOY=ON         : Mac OS X only. Use only for creating Quassel Packages!
  17 #
  18 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  19
  20 project(QuasselIRC)
  21
  22 cmake_minimum_required(VERSION 2.6.0 FATAL_ERROR)
  23
  24 if(COMMAND cmake_policy)
  25    cmake_policy(SET CMP0003 NEW)
  26 endif(COMMAND cmake_policy)
  27
  28 # Use our own (well, and KDE's) version of some modules
  29 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  30 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  31 include(QuasselMacros)
  32
  33 # Various options and variables that can be set on the command line
  34 option(WANT_CORE     "Build the core (server) binary"           ON)
  35 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  36 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  37
  38 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  39 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  40 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  41 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  42 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  43
  44 # We use icon paths from KDE 4.3 trunk, which are partially invalid on older and possibly
  45 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  46 # run on a matching KDE version only.
  47 option(WITH_OXYGEN   "Install Oxygen icons. Heavily recommended unless you use KDE 4.3" ON)
  48
  49 option(STATIC        "Enable static building (might not be portable)" OFF)
  50
  51 if(APPLE)
  52   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  53 endif(APPLE)
  54
  55 # Default to embedding data in the static case
  56 if(STATIC OR WIN32)
  57   set(EMBED_DEFAULT ON)
  58 else(STATIC OR WIN32)
  59   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  60 endif(STATIC OR WIN32)
  61
  62 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  63
  64 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  65 set(LINGUAS "" CACHE STRING "Comma-separated list of locales specifying languages that should be compiled")
  66
  67 # Some settings imply others
  68 if(STATIC)
  69   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  70 endif(STATIC)
  71
  72 if(WIN32)
  73   # We don't support separately installed resources yet on Win32
  74   set(EMBED_DATA ON)
  75 endif(WIN32)
  76
  77 # Build Type
  78 # We need to make sure it's not empty
  79 # Supported: Release, RelWithDebugInfo, Debug, Debugfull
  80 set(CMAKE_BUILD_TYPE "RelWithDebugInfo" CACHE STRING "CMake Build Type")
  81 if(NOT CMAKE_BUILD_TYPE)
  82   set(CMAKE_BUILD_TYPE "RelWithDebugInfo" CACHE STRING "CMake Build Type" FORCE)
  83 endif(NOT CMAKE_BUILD_TYPE)
  84
  85 # Enable various flags on gcc
  86 if(CMAKE_COMPILER_IS_GNUCXX)
  87   # Let's just hope that all gccs support these options and skip the tests...
  88   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor")
  89   set(CMAKE_CXX_FLAGS_RELWITHDEBUGINFO "-O2")
  90   set(CMAKE_CXX_FLAGS_DEBUG "-g -fno-reorder-blocks -fno-schedule-insns -fno-inline")
  91   set(CMAKE_CXX_FLAGS_DEBUGFULL "-g3")
  92 endif(CMAKE_COMPILER_IS_GNUCXX)
  93
  94 set(QT_MIN_VERSION "4.4.0")
  95
  96 if(APPLE AND DEPLOY)
  97   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
  98   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
  99   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
 100   add_definitions(-DMAC_10_4_SDK)
 101 endif(APPLE AND DEPLOY)
 102
 103 # Execinfo is needed for generating backtraces
 104 find_package(ExecInfo)
 105 if(EXECINFO_FOUND)
 106   add_definitions(-DHAVE_EXECINFO)
 107   include_directories(${EXECINFO_INCLUDES})
 108   link_libraries(${EXECINFO_LIBRARIES})
 109 endif(EXECINFO_FOUND)
 110
 111 # Select a Qt installation here, if you don't want to use system Qt
 112 if(QT)
 113   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 114   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 115 endif(QT)
 116
 117 # Now that we have the correct $PATH, lets find Qt!
 118 find_package(Qt4 REQUIRED)
 119
 120 set(QT_DONT_USE_QTGUI 1)
 121 include(${QT_USE_FILE})
 122 include_directories(${QT_INCLUDES})
 123
 124 # Setup OpenSSL
 125 if(WITH_OPENSSL)
 126   find_package(OpenSSL)
 127 else(WITH_OPENSSL)
 128   message(STATUS "Disabling OpenSSL support")
 129 endif(WITH_OPENSSL)
 130
 131 if(OPENSSL_FOUND)
 132   if(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 133     message(STATUS "Found OpenSSL support in Qt")
 134     add_definitions(-DHAVE_SSL)
 135     set(HAVE_SSL true)
 136     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_SSL)
 137   else(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 138     message(STATUS "No OpenSSL support found in Qt, disabling")
 139   endif(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 140 else(OPENSSL_FOUND)
 141   add_definitions(-DQT_NO_OPENSSL)
 142 endif(OPENSSL_FOUND)
 143
 144 # Setup D-Bus support
 145 if(WITH_DBUS)
 146   if(QT_QTDBUS_FOUND)
 147     message(STATUS "Found QtDBus, enabling D-Bus support")
 148     add_definitions(-DHAVE_DBUS)
 149     set(LINK_DBUS DBUS)
 150     set(HAVE_DBUS true)
 151     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_DBUS)
 152   else(QT_QTDBUS_FOUND)
 153     message(STATUS "QtDBus not found, disabling D-Bus support")
 154   endif(QT_QTDBUS_FOUND)
 155 else(WITH_DBUS)
 156   message(STATUS "Disabling D-Bus support")
 157 endif(WITH_DBUS)
 158
 159 # Setup QtWebKit support
 160 if(WITH_WEBKIT)
 161   if(QT_QTWEBKIT_FOUND)
 162     message(STATUS "Found QtWebKit, enabling WebKit support")
 163     add_definitions(-DHAVE_WEBKIT)
 164     set(LINK_WEBKIT WEBKIT)
 165     set(HAVE_WEBKIT true)
 166     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_WEBKIT)
 167   else(QT_QTWEBKIT_FOUND)
 168     message(STATUS "QtWebKit not found, disabling WebKit support")
 169   endif(QT_QTWEBKIT_FOUND)
 170 else(WITH_WEBKIT)
 171   message(STATUS "Disabling WebKit support")
 172 endif(WITH_WEBKIT)
 173
 174 # Setup KDE4 support
 175 if(WITH_KDE)
 176   find_package(KDE4)
 177   if(KDE4_FOUND)
 178     message(STATUS "Enabling KDE4 integration")
 179     include_directories(${KDE4_INCLUDES})
 180     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 181     set(HAVE_KDE 1)
 182     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_KDE)
 183     set(QUASSEL_KDE_LIBRARIES ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} knotifyconfig)
 184     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 185     set(EMBED_DATA OFF)
 186   else(KDE4_FOUND)
 187     message(STATUS "KDE4 not found, disabling KDE integration")
 188   endif(KDE4_FOUND)
 189 else(WITH_KDE)
 190   message(STATUS "Disabling KDE4 integration")
 191 endif(WITH_KDE)
 192
 193 # Setup Phonon support - we only need this if we don't have or want KDE4
 194 if(NOT HAVE_KDE)
 195   if(WITH_PHONON)
 196     find_package(Phonon)
 197     if(PHONON_FOUND)
 198       message(STATUS "Enabling Phonon support")
 199       add_definitions(-DHAVE_PHONON)
 200       set(HAVE_PHONON true)
 201       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_PHONON)
 202     else(PHONON_FOUND)
 203       message(STATUS "Phonon not found, disabling audio notifications")
 204     endif(PHONON_FOUND)
 205   else(WITH_PHONON)
 206     message(STATUS "Disabling Phonon support")
 207   endif(WITH_PHONON)
 208 endif(NOT HAVE_KDE)
 209
 210 # Now set up install locations; those are set by KDE if integration is enabled
 211 if(NOT HAVE_KDE)
 212   if(WIN32)
 213     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 214     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 215     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 216     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 217   else(WIN32)
 218     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 219     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 220     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 221     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 222   endif(WIN32)
 223 endif(NOT HAVE_KDE)
 224
 225 # RPATH needs to be set correctly
 226 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 227 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 228 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 229
 230 # Set global buildflags
 231 # This is very much non-portable, so don't use -DSTATIC until you know what
 232 # you do.
 233 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 234   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 235   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 236   if(HAVE_SSL)
 237     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 238   endif(HAVE_SSL)
 239 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 240
 241 if(WIN32)
 242   #if(STATIC)
 243   link_libraries(imm32 winmm dbghelp)  # missing by default :/
 244   #endif(STATIC)
 245   if(HAVE_SSL)
 246      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 247   endif(HAVE_SSL)
 248 endif(WIN32)
 249
 250 if(WIN32)
 251   set(RC_WIN32 ../pics/win32.rc)  # for app icons on windows
 252 endif(WIN32)
 253
 254 # We need to create a version.gen
 255 # For this, we create our genversion binary and make sure it is run every time.
 256 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 257 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
 258
 259 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 260 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 261                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 262 add_dependencies(genversion_run genversion)
 263
 264 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 265 set(COMMON_DEPS ${RC_WIN32})
 266 set(CORE_DEPS )
 267 set(CLIENT_DEPS )
 268
 269 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 270 add_subdirectory(data)
 271 add_subdirectory(icons)
 272 add_subdirectory(pics)
 273 add_subdirectory(i18n)
 274 add_subdirectory(src)