CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 # You may pass various options to cmake:
   3 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   4 #                     : select binaries to build
   5 # -DWITH_OPENSSL=OFF  : Disable OpenSSL support
   6 # -DWITH_DBUS=OFF     : Disable D-Bus support
   7 # -DQT=/path/to/qt    : Choose a Qt4 installation to use instead of the system Qt4
   8 # -DSTATIC=ON         : Enable static building of Quassel. Use with care.
   9 # -DSPUTDEV=ON        : Do not use.
  10 # -DDEPLOY=ON         : Mac OS X only. Use only fore redistribution Quassel Packages!!
  11 #
  12 # NOTE: You need to remove CMakeCache.txt if you plan to change any of these values!
  13
  14 project(QuasselIRC)
  15
  16 # Target scopes don't work in older versions
  17 cmake_minimum_required(VERSION 2.4.7 FATAL_ERROR)
  18
  19 if(COMMAND cmake_policy)
  20    cmake_policy(SET CMP0003 NEW)
  21 endif(COMMAND cmake_policy)
  22
  23 # Use our own (well, KDE's) version of some modules
  24 # In particular cmake's FindQt4 and FindOpenSSL are quite buggy
  25 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  26
  27 # Various options and variables that can be set on the command line
  28 option(WANT_CORE     "Build the core (server) binary"           ON)
  29 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  30 option(WANT_MONO     "Build the monolithic (all-in-one) binary" OFF)
  31
  32 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  33 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  34
  35 option(STATIC        "Enable static building (might not be portable)" OFF)
  36 option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  37 option(SPUTDEV       "Do not use!" OFF)
  38
  39 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt")
  40 set(LINGUAS "" CACHE STRING "Space-separated List of locales specifying languages that should be compiled")
  41
  42 if(STATIC)
  43   set(CMAKE_BUILD_TYPE Release)
  44 endif(STATIC)
  45
  46 # RPATH needs to be set correctly
  47 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
  48 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
  49
  50 # Enable various flags on gcc
  51 if(CMAKE_COMPILER_IS_GNUCXX)
  52   include(CheckCXXCompilerFlag)
  53   check_cxx_compiler_flag(-Wall HAVE_WALL)
  54   if(HAVE_WALL)
  55     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
  56   endif(HAVE_WALL)
  57   check_cxx_compiler_flag(-Wextra HAVE_WEXTRA)
  58   if(HAVE_WEXTRA)
  59     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wextra")
  60   endif(HAVE_WEXTRA)
  61   check_cxx_compiler_flag(-ansi HAVE_ANSI)
  62   if(HAVE_ANSI)
  63     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi")
  64   endif(HAVE_ANSI)
  65 endif(CMAKE_COMPILER_IS_GNUCXX)
  66
  67 set(QT_MIN_VERSION "4.4.0")
  68
  69 if(APPLE AND DEPLOY)
  70   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
  71   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
  72   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
  73   add_definitions(-DMAC_10_4_SDK)
  74 endif(APPLE AND DEPLOY)
  75
  76 # Enable mostly b0rked stuff (new ChatView), do not enable this unless you know what you do...
  77 if(SPUTDEV)
  78   add_definitions(-DSPUTDEV)
  79 endif(SPUTDEV)
  80
  81 # Set up execinfo
  82
  83 # The problem with this library is that it is built-in in the Linux glib,
  84 # while on systems like FreeBSD, it is installed separately and thus needs to be linked to.
  85 # Therefore, we search for the header to see if the it's available in the first place.
  86 # If it is available, we try to locate the library to figure out whether it is built-in or not.
  87
  88 find_path(EXECINFO_H_DIR "execinfo.h")
  89
  90 if(NOT EXECINFO_H_DIR STREQUAL "EXECINFO_H_DIR-NOTFOUND")
  91   # We found the header file's include dir.
  92   # Let's add it so the compiler finds it as well.
  93   include_directories(${EXECINFO_H_DIR})
  94
  95   # Now determine if it's built-in or not, by searching the library file.
  96   find_library(EXECINFO_LIB_PATH "execinfo")
  97
  98   if(EXECINFO_LIB_PATH STREQUAL "EXECINFO_LIB_PATH-NOTFOUND")
  99     # Built-in, no further action is needed
 100     message(STATUS "Found execinfo")
 101   else(EXECINFO_LIB_PATH STREQUAL "EXECINFO_LIB_PATH-NOTFOUND")
 102     # It's an external library, link it.
 103     link_libraries(${EXECINFO_LIB_PATH})
 104     message(STATUS "Found execinfo: ${EXECINFO_LIB_PATH}")
 105   endif(EXECINFO_LIB_PATH STREQUAL "EXECINFO_LIB_PATH-NOTFOUND")
 106
 107   set(HAVE_EXECINFO true)
 108
 109 endif(NOT EXECINFO_H_DIR STREQUAL "EXECINFO_H_DIR-NOTFOUND")
 110
 111 if(HAVE_EXECINFO)
 112   add_definitions(-DHAVE_EXECINFO)
 113 endif(HAVE_EXECINFO)
 114
 115
 116 # Select a Qt installation here, if you don't want to use system Qt
 117 if(QT)
 118   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 119   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 120 endif(QT)
 121
 122 # Now that we have the correct $PATH, lets find Qt!
 123 find_package(Qt4 REQUIRED)
 124
 125 set(QT_DONT_USE_QTGUI 1)
 126 include(${QT_USE_FILE})
 127 include_directories(${QT_INCLUDES})
 128
 129 # Set up OpenSSL
 130 if(WITH_OPENSSL)
 131   find_package(OpenSSL)
 132 endif(WITH_OPENSSL)
 133 if(OPENSSL_FOUND)
 134   if(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 135     add_definitions(-DHAVE_SSL)
 136     set(HAVE_SSL true)
 137   endif(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 138 else(OPENSSL_FOUND)
 139   add_definitions(-DQT_NO_OPENSSL)
 140 endif(OPENSSL_FOUND)
 141
 142 if(WITH_DBUS AND QT_QTDBUS_FOUND)
 143   add_definitions(-DHAVE_DBUS)
 144   set(LINK_DBUS DBUS)
 145   set(HAVE_DBUS true)
 146 endif(WITH_DBUS AND QT_QTDBUS_FOUND)
 147
 148 # We need to create a version.gen
 149 # For this, we create our genversion binary and make sure it is run every time.
 150 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 151 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
 152
 153 add_custom_target(genversion_run ALL ${CMAKE_BINARY_DIR}/genversion
 154                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/common/version.gen)
 155 add_dependencies(genversion_run genversion)
 156
 157 # Add needed subdirs
 158 add_subdirectory(src/common)
 159 include_directories(src/common)
 160 if(WANT_CORE OR WANT_MONO)
 161   add_subdirectory(src/core)
 162   include_directories(src/core)
 163 endif(WANT_CORE OR WANT_MONO)
 164 if(WANT_QTCLIENT OR WANT_MONO)
 165   add_subdirectory(src/client)
 166   add_subdirectory(src/uisupport)
 167   add_subdirectory(src/qtui)
 168   include_directories(src/client)
 169   include_directories(src/uisupport)
 170   include_directories(src/qtui)
 171 endif(WANT_QTCLIENT OR WANT_MONO)
 172
 173 # Make sure version.gen exists before building mod_common
 174 add_dependencies(mod_common genversion_run)
 175
 176 # Generate binary translation files
 177 include(QuasselGenerateTranslations)
 178 quassel_generate_i18n_resource(RC_I18N ${LINGUAS})
 179
 180 # Add resources
 181 qt4_add_resources(RC_ICONS src/icons/icons.qrc)
 182 qt4_add_resources(RC_QUASSEL_ICONS src/icons/quassel-icons.qrc)
 183 qt4_add_resources(RC_SQL src/core/sql.qrc)
 184
 185 # Set global buildflags
 186 # This is very much non-portable, so don't use -DSTATICGCC until you know what
 187 # you do.
 188 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 189   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 190   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 191   if(HAVE_SSL)
 192     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 193   endif(HAVE_SSL)
 194 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 195
 196 if(STATIC AND WIN32)
 197   link_libraries(imm32 winmm)  # missing by default :/
 198    if(HAVE_SSL)
 199      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 200    endif(HAVE_SSL)
 201 endif(STATIC AND WIN32)
 202
 203 if(WIN32)
 204   set(WIN32_RC src/icons/win32.rc)  # for app icons on windows
 205 endif(WIN32)
 206
 207 # Here comes the dirty part. Our targets need different Qt4 modules, i.e. different libs
 208 # and defines. We can't simply include UseQt4 several times, since definitions add up.
 209 # We workaround this by using our own macro to figure out what to add.
 210
 211 # This macro sets variables for additional Qt modules.
 212 macro(setup_qt4_variables)
 213   set(QUASSEL_QT_LIBRARIES )
 214   IF(WIN32)
 215     set(MAIN MAIN)
 216   ENDIF(WIN32)
 217   foreach(qtmod CORE ${ARGV} ${MAIN})
 218     set(QUASSEL_QT_LIBRARIES ${QUASSEL_QT_LIBRARIES} ${QT_QT${qtmod}_LIBRARY} ${QT_${qtmod}_LIB_DEPENDENCIES})
 219   endforeach(qtmod ${ARGV})
 220   set(QUASSEL_QT_LIBRARIES ${QUASSEL_QT_LIBRARIES} ${QT_LIBRARIES})
 221 endmacro(setup_qt4_variables)
 222
 223 # Now we have everything, so just glue the right pieces together :)
 224 if(WANT_CORE)
 225   setup_qt4_variables(NETWORK SCRIPT SQL)
 226   add_executable(quasselcore ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 227                              ${RC_SQL} ${RC_I18N} ${WIN32_RC})
 228   set_target_properties(quasselcore PROPERTIES
 229                                     COMPILE_FLAGS "-DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_CORE")
 230   target_link_libraries(quasselcore mod_core mod_common
 231                                     ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 232 endif(WANT_CORE)
 233
 234 if(WANT_QTCLIENT)
 235   setup_qt4_variables(${LINK_DBUS} GUI NETWORK)
 236   add_executable(quasselclient WIN32 ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 237                                      ${RC_ICONS} ${RC_QUASSEL_ICONS} ${RC_I18N} ${WIN32_RC})
 238   set_target_properties(quasselclient PROPERTIES
 239                                       COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DBUILD_QTUI")
 240   target_link_libraries(quasselclient mod_qtui mod_uisupport mod_client mod_common
 241                                       ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 242 endif(WANT_QTCLIENT)
 243
 244 if(WANT_MONO)
 245   setup_qt4_variables(${LINK_DBUS} GUI NETWORK SCRIPT SQL)
 246   add_executable(quassel WIN32 ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 247                                ${RC_ICONS} ${RC_QUASSEL_ICONS} ${RC_SQL} ${RC_I18N} ${WIN32_RC})
 248   set_target_properties(quassel PROPERTIES
 249                                 COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_MONO")
 250   target_link_libraries(quassel mod_qtui mod_uisupport mod_client mod_core mod_common
 251                                 ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 252 endif(WANT_MONO)
 253
 254 # Build bundles for MacOSX
 255 if(APPLE)
 256   add_custom_command(TARGET quasselclient POST_BUILD
 257                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
 258                              ${CMAKE_SOURCE_DIR} "Quassel Client" quasselclient)
 259   add_custom_command(TARGET quassel POST_BUILD
 260                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
 261                              ${CMAKE_SOURCE_DIR} "Quassel" quassel)
 262   if(DEPLOY)
 263     add_custom_command(TARGET quasselclient POST_BUILD
 264                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Client)
 265     add_custom_command(TARGET quasselcore POST_BUILD
 266                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Core)
 267   endif(DEPLOY)
 268 endif(APPLE)
 269
 270 # Install rules
 271 if(WANT_CORE)
 272   install(TARGETS quasselcore
 273           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 274 endif(WANT_CORE)
 275
 276 if(WANT_QTCLIENT)
 277   install(TARGETS quasselclient
 278           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 279
 280   install(FILES quasselclient.desktop
 281           DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications)
 282 endif(WANT_QTCLIENT)
 283
 284 if(WANT_MONO)
 285   install(TARGETS quassel
 286           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 287
 288   install(FILES quassel.desktop
 289           DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications)
 290 endif(WANT_MONO)