CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)  # You'll need at least 2.8.12 for KDE Frameworks integration
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 12)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.12-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
  38 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
  39 if (CMAKE_MAJOR_VERSION GREATER 2)
  40     cmake_policy(SET CMP0043 OLD)
  41 endif()
  42
  43 # Options and variables that can be set on the command line
  44 #####################################################################
  45
  46 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  47 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  48 if (USE_QT4) # takes precedence
  49     set(USE_QT5 OFF)
  50 else()
  51     if (NOT USE_QT5)
  52         set(USE_QT4 ON)
  53     endif()
  54 endif()
  55
  56 # Select the binaries to build
  57 option(WANT_CORE     "Build the core (server) binary"           ON)
  58 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  59 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  60 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  61 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  62 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  63
  64 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  65 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  66 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  67 # is disabled.
  68 if (USE_QT4)
  69     option(WITH_KDE "KDE4 integration" OFF)
  70     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  71 else()
  72     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  73     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  74 endif()
  75
  76 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  77 if (NOT WITH_KDE)
  78     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  79 endif()
  80
  81 # For this, the feature info is added after we know if QtWebkit is installed
  82 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  83
  84 if (APPLE)
  85     # Notification Center is only available in > 10.8, which is Darwin v12
  86     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  87         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  88         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  89     endif()
  90 endif()
  91
  92 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  93 set(EMBED_DEFAULT OFF)
  94 if (STATIC OR WIN32 OR APPLE)
  95     set(EMBED_DEFAULT ON)
  96 endif()
  97 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  98                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  99 if (NOT EMBED_DEFAULT)
 100     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 101 endif()
 102
 103 # The following options are not for end-user consumption, so don't list them in the feature summary
 104 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 105
 106 # Handle with care
 107 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 108
 109 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 110 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 111
 112 # For static builds, arbitrary extra libs might need to be linked
 113 # Define a comma-separated list here
 114 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 115 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 116 if (LINK_EXTRA)
 117     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 118     link_libraries(${LINK_EXTRA})
 119 endif()
 120
 121
 122 # Simplify later checks
 123 #####################################################################
 124
 125 if (WANT_MONO OR WANT_QTCLIENT)
 126     set(BUILD_GUI true)
 127 endif()
 128 if (WANT_MONO OR WANT_CORE)
 129     set(BUILD_CORE true)
 130 endif()
 131
 132
 133 # Set up Qt
 134 #####################################################################
 135
 136 if (USE_QT5)
 137     message(STATUS "Building for Qt5...")
 138     set(QT_MIN_VERSION "5.2.0")
 139     add_definitions(-DHAVE_QT5)
 140 else()
 141     message(STATUS "Building for Qt4...")
 142     set(QT_MIN_VERSION "4.8.0")
 143
 144     # Select a Qt installation here, if you don't want to use system Qt
 145     if(QT_PATH)
 146         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 147         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 148     endif()
 149 endif()
 150
 151
 152 # Find package dependencies
 153 #
 154 # Note that you can forcefully disable optional packages
 155 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 156 #####################################################################
 157
 158 if (USE_QT5)
 159     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 160     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 161         URL "http://qt.digia.com"
 162         DESCRIPTION "contains core functionality for Qt"
 163     )
 164     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 165     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 166     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 167         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 168     endif()
 169
 170     find_package(Qt5Network QUIET)
 171     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 172         DESCRIPTION "the network module for Qt5"
 173     )
 174
 175     if (BUILD_GUI)
 176         find_package(Qt5Gui QUIET)
 177         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 178             DESCRIPTION "the GUI module for Qt5"
 179         )
 180         find_package(Qt5Widgets QUIET)
 181         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 182             DESCRIPTION "the widgets module for Qt5"
 183         )
 184
 185         find_package(Qt5DBus QUIET)
 186         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 187             URL "http://qt.digia.com"
 188             DESCRIPTION "D-Bus support for Qt5"
 189             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 190         )
 191         if (Qt5DBus_FOUND)
 192             find_package(dbusmenu-qt5 QUIET CONFIG)
 193             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 194                 URL "https://launchpad.net/libdbusmenu-qt"
 195                 DESCRIPTION "a library implementing the DBusMenu specification"
 196                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 197             )
 198         endif()
 199
 200         find_package(Phonon4Qt5 QUIET)
 201         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 202             URL "https://projects.kde.org/projects/kdesupport/phonon"
 203             DESCRIPTION "a multimedia abstraction library"
 204             PURPOSE     "Required for audio notifications"
 205         )
 206
 207         find_package(LibsnoreQt5 QUIET)
 208         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 209             URL "https://github.com/TheOneRing/Snorenotify"
 210             DESCRIPTION "a cross-platform notification framework"
 211             PURPOSE     "Enable support for the snorenotify framework"
 212         )
 213
 214         if (WITH_WEBKIT)
 215             find_package(Qt5WebKit QUIET)
 216             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 217                 URL "http://qt.digia.com"
 218                 DESCRIPTION "a WebKit implementation for Qt"
 219                 PURPOSE     "Needed for displaying previews for URLs in chat"
 220             )
 221             if (Qt5WebKit_FOUND)
 222                 find_package(Qt5WebKitWidgets QUIET)
 223                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 224                     URL "http://qt.digia.com"
 225                     DESCRIPTION "widgets for Qt's WebKit implementation"
 226                     PURPOSE     "Needed for displaying previews for URLs in chat"
 227                 )
 228             endif()
 229         endif()
 230         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 231
 232         # KDE Frameworks
 233         ################
 234
 235         if (WITH_KDE)
 236             set(ecm_find_type "REQUIRED")
 237         else()
 238             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 239             set(ecm_find_type "RECOMMENDED")
 240         endif()
 241
 242         # extra-cmake-modules
 243         find_package(ECM NO_MODULE QUIET)
 244         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 245             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 246             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 247             PURPOSE     "Required to find KDE Frameworks components"
 248         )
 249
 250         if (ECM_FOUND)
 251             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 252         endif()
 253
 254         if (WITH_KDE)
 255             find_package(KF5TextWidgets QUIET)
 256             set_package_properties(KF5TextWidgets PROPERTIES TYPE REQUIRED
 257                 URL "http://inqlude.org/libraries/ktextwidgets.html"
 258                 DESCRIPTION "framework providing an assortment of widgets for displaying and editing text"
 259                 PURPOSE     "Allows to use extra features provided by KDE Frameworks in input widgets"
 260             )
 261
 262         endif()
 263
 264     endif(BUILD_GUI)
 265     if (BUILD_CORE)
 266         find_package(Qt5Script QUIET)
 267         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 268             DESCRIPTION "provides scripting support for Qt5"
 269         )
 270         find_package(Qt5Sql QUIET)
 271         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 272             DESCRIPTION "the database support module for Qt5"
 273         )
 274
 275         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 276         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 277         #find_package(QCA2 QUIET)
 278         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 279         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 280         #    DESCRIPTION "Qt Cryptographic Architecture"
 281         #    PURPOSE "Required for encryption support"
 282         #)
 283
 284     endif(BUILD_CORE)
 285
 286     find_package(Qt5LinguistTools QUIET)
 287     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 288                            DESCRIPTION "contains tools for handling translation files"
 289                            PURPOSE "Required for having translations"
 290     )
 291     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 292     if (Qt5LinguistTools_FOUND)
 293         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 294             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 295             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 296             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 297         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 298             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 299             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 300         endif()
 301
 302         # Compatibility with the Qt4 variables
 303         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 304         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 305         if (Qt5_LCONVERT_EXECUTABLE)
 306             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 307         endif()
 308     endif()
 309
 310 else(USE_QT5)
 311     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 312
 313     if (BUILD_GUI)
 314         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 315         if (QT_QTDBUS_FOUND)
 316             find_package(dbusmenu-qt QUIET CONFIG)
 317             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 318                 URL "https://launchpad.net/libdbusmenu-qt"
 319                 DESCRIPTION "a library implementing the DBusMenu specification"
 320                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 321             )
 322         endif()
 323
 324         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 325             set(HAVE_WEBKIT true)
 326         endif()
 327         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 328
 329         if (WITH_KDE)
 330             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 331             set(_cflags ${CMAKE_C_FLAGS})
 332             find_package(KDE4 4.4 QUIET)
 333             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 334                 URL "http://www.kde.org"
 335                 DESCRIPTION "a world-class desktop environment"
 336                 PURPOSE "Enables various bits for improving integration with KDE"
 337             )
 338             set(CMAKE_C_FLAGS ${_cflags})
 339
 340         else(WITH_KDE)
 341             find_package(Phonon QUIET)
 342             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 343                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 344                 DESCRIPTION "a multimedia abstraction library"
 345                 PURPOSE     "Required for audio notifications"
 346             )
 347
 348             find_package(Libsnore QUIET)
 349             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 350                 URL "https://github.com/TheOneRing/Snorenotify"
 351                 DESCRIPTION "a cross-platform notification framework"
 352                 PURPOSE     "Enable support for the snorenotify framework"
 353             )
 354         endif(WITH_KDE)
 355
 356         find_package(IndicateQt QUIET)
 357         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 358             URL "https://launchpad.net/libindicate-qt/"
 359             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 360             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 361         )
 362
 363     endif(BUILD_GUI)
 364
 365     if (BUILD_CORE)
 366
 367         find_package(QCA2 QUIET)
 368         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 369             URL "https://projects.kde.org/projects/kdesupport/qca"
 370             DESCRIPTION "Qt Cryptographic Architecture"
 371             PURPOSE     "Required for encryption support"
 372         )
 373
 374
 375     endif()
 376
 377     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 378     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 379     if (QT_LRELEASE_EXECUTABLE)
 380         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 381         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 382     endif()
 383 endif()
 384
 385
 386 # Non-Qt-based packages
 387
 388 # zlib for compression, however we can always fall back to miniz
 389 find_package(ZLIB QUIET)
 390 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 391     URL "http://www.zlib.net"
 392     DESCRIPTION "a popular compression library"
 393     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 394 )
 395
 396
 397 if (NOT WIN32)
 398     # Execinfo is needed for generating backtraces
 399     find_package(ExecInfo QUIET)
 400     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 401         DESCRIPTION "a library for inspecting backtraces"
 402         PURPOSE "Used for generating backtraces in case of a crash"
 403     )
 404 endif()
 405
 406
 407 # Additional compile settings
 408 #####################################################################
 409
 410 # This sets -fPIC and friends if required by the installed Qt5 library
 411 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 412     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 413 endif()
 414
 415 # Needed to compile with mingw without kde
 416 if (MINGW AND NOT KDE4_FOUND)
 417     add_definitions(-D_WIN32_WINNT=0x0500)
 418     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 419     # workaround for bug in mingw gcc 4.0
 420     add_definitions(-U__STRICT_ANSI__)
 421 endif()
 422
 423
 424 # Setup KDE / KDE Frameworks
 425 #####################################################################
 426
 427 # We want to do this up here, so we have the necessary variables and defines set before
 428 # compiling anything
 429
 430 if (KDE4_FOUND)
 431     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 432     set(EMBED_DATA OFF)
 433
 434     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 435     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 436     set(WITH_KDE4 TRUE)
 437 endif()
 438
 439 if (USE_QT5 AND WITH_KDE)
 440     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 441     set(EMBED_DATA OFF)
 442
 443     include(KDEInstallDirs)
 444     include(KDECompilerSettings)
 445     include(KDECMakeSettings)
 446
 447     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 448     set(WITH_KF5 TRUE)
 449 endif()
 450
 451 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 452 include(QuasselInstallDirs)
 453
 454 # Various config-dependent checks and settings
 455 #####################################################################
 456
 457 if (NOT ZLIB_FOUND)
 458     message(STATUS "zlib NOT found, using bundled miniz for compression")
 459     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 460         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 461     endif()
 462 endif()
 463
 464 # Check for SSL support in Qt
 465 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 466 # a small test program checking the defines. This works for both Qt4 and Qt5.
 467 cmake_push_check_state(RESET)
 468 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 469 check_cxx_source_compiles("
 470     #include \"qglobal.h\"
 471     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 472     #  error \"No SSL support\"
 473     #endif
 474     int main() {}"
 475     HAVE_SSL)
 476 cmake_pop_check_state()
 477
 478 if (HAVE_SSL)
 479     add_definitions(-DHAVE_SSL)
 480 endif()
 481 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 482
 483 # Check for syslog support
 484 if (NOT WIN32)
 485     check_include_file(syslog.h HAVE_SYSLOG)
 486     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 487 endif()
 488
 489 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 490
 491 if (EMBED_DATA)
 492     message(STATUS "Embedding data files into the binary")
 493 else()
 494     message(STATUS "Installing data files separately")
 495 endif()
 496
 497 if (INDICATEQT_FOUND)
 498     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 499 endif()
 500
 501 if (NOT WIN32)
 502     check_function_exists(umask HAVE_UMASK)
 503     if(HAVE_UMASK)
 504         add_definitions(-DHAVE_UMASK)
 505     endif(HAVE_UMASK)
 506 endif()
 507
 508
 509 # Windows-specific stuff
 510 #####################################################################
 511
 512 if (WIN32)
 513     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 514     if (MSVC)
 515         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 516         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 517         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 518         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 519         link_libraries(Version dwmapi shlwapi)
 520         if (USE_QT5)
 521             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 522         endif()
 523     endif()
 524     if(HAVE_SSL AND STATIC)
 525         find_package(OpenSSL REQUIRED)
 526         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 527     endif()
 528 endif()
 529
 530
 531 # Static builds (very much non-portable, so don't use -DSTATIC
 532 # unless you know what you do!)
 533 #####################################################################
 534
 535 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 536     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 537     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 538     if (HAVE_SSL)
 539         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 540     endif()
 541 endif()
 542
 543
 544 # Generate version information from Git
 545 #####################################################################
 546
 547 include(GetGitRevisionDescription)
 548 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 549 git_describe(GIT_DESCRIBE --long)
 550
 551 # Sanitize things if we're not in a Git repo
 552 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 553     set(GIT_HEAD "")
 554     set(GIT_DESCRIBE "")
 555 endif()
 556
 557 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 558
 559 # Prepare the build
 560 #####################################################################
 561
 562 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 563 set(COMMON_DEPS ${RC_WIN32})
 564 set(CORE_DEPS )
 565 set(CLIENT_DEPS )
 566
 567 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 568 add_subdirectory(data)
 569 add_subdirectory(icons)
 570 add_subdirectory(pics)
 571 add_subdirectory(po)
 572
 573
 574 # Set up and display feature summary
 575 #####################################################################
 576
 577 feature_summary(WHAT ALL
 578                 INCLUDE_QUIET_PACKAGES
 579                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 580 )
 581
 582 # Finally, compile the sources
 583 # We want this after displaying the feature summary to avoid ugly
 584 # CMake backtraces in case a required Qt5 module is missing
 585 #####################################################################
 586
 587 add_subdirectory(src)