CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 3.5)
  10
  11 # Tell CMake about or own modules
  12 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  13
  14 include(QuasselVersion)
  15
  16 message(STATUS "Using CMake ${CMAKE_VERSION}")
  17
  18 # Set up build type rather early
  19 include(BuildType)
  20
  21 # Support ccache if found
  22 # This should happen before calling project(), so compiler settings are validated.
  23 option(USE_CCACHE "Enable support for ccache if available" ON)
  24 if (USE_CCACHE)
  25     message(STATUS "Checking for ccache")
  26     find_program(CCACHE_PROGRAM ccache)
  27     if (CCACHE_PROGRAM)
  28         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  29         message(STATUS "Checking for ccache - enabled")
  30     else()
  31         message(STATUS "Checking for ccache - not found")
  32     endif()
  33 endif()
  34
  35 # Set up project
  36 project(Quassel CXX)
  37
  38 # Let CMake handle file generation for Qt
  39 set(CMAKE_AUTOMOC ON)
  40 set(CMAKE_AUTORCC ON)
  41 set(CMAKE_AUTOUIC ON)
  42
  43 # Needed, otherwise some .moc files won't be found with older CMake versions
  44 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  45
  46 # Include various CMake modules...
  47 include(CMakePushCheckState)
  48 include(CheckFunctionExists)
  49 include(CheckIncludeFileCXX)
  50 include(CheckCXXSourceCompiles)
  51 include(CMakeDependentOption)
  52 include(FeatureSummary)
  53
  54 # ... and our own
  55 include(QuasselCompileSettings)
  56 include(QuasselMacros)
  57
  58 # Options and variables that can be set on the command line
  59 #####################################################################
  60
  61 # Select the binaries to build
  62 option(WANT_CORE     "Build the core (server) binary"           ON)
  63 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  64 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  65 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  66 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  67 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  68
  69 # Whether to enable integration with higher-tier KDE frameworks that require runtime support.
  70 # We still optionally make use of certain Tier 1 frameworks even if WITH_KDE is disabled.
  71 option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  72 add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  73
  74 # Icon theme support. By default, install the Breeze icon theme (may be disabled if a system installation is present)
  75 option(WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme" ON)
  76 add_feature_info(WITH_BUNDLED_ICONS WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme")
  77
  78 option(WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)" OFF)
  79 add_feature_info(WITH_OXYGEN_ICONS WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)")
  80
  81 # For this, the feature info is added after we know if QtWebkit is installed
  82 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  83
  84 # For this, the feature info is added after we know if QtWebEngine is installed
  85 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  86
  87 if (APPLE)
  88     # Notification Center is only available in > 10.8, which is Darwin v12
  89     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
  90         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  91         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  92     endif()
  93     find_library(CARBON_LIBRARY Carbon)
  94     mark_as_advanced(CARBON_LIBRARY)
  95     link_libraries(${CARBON_LIBRARY})
  96 endif()
  97
  98 # Always embed on Windows or OSX; never embed when enabling KDE integration
  99 set(EMBED_DEFAULT OFF)
 100 if (WIN32 OR APPLE)
 101     set(EMBED_DEFAULT ON)
 102 endif()
 103 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 104                                    "NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 105 if (NOT EMBED_DEFAULT)
 106     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 107 endif()
 108
 109 # The following options are not for end-user consumption, so don't list them in the feature summary
 110 option(FATAL_WARNINGS "Make compile warnings fatal (most useful for CI builds)" OFF)
 111 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg" OFF "APPLE" OFF)
 112
 113 # List of authenticators and the cmake flags to build them
 114 # (currently that's just LDAP, but more can be added here).
 115 ####################################################################
 116 option(WITH_LDAP "Enable LDAP authentication support if present on system" ON)
 117
 118 # Setup CMake
 119 #####################################################################
 120
 121 # Visibility settings apply to all targets
 122 if (POLICY CMP0063)
 123     cmake_policy(SET CMP0063 NEW)
 124 endif()
 125
 126 # Let automoc/autouic process generated files
 127 if (POLICY CMP0071)
 128     cmake_policy(SET CMP0071 NEW)
 129 endif()
 130
 131 set(BUILD_SHARED_LIBS TRUE CACHE BOOL "" FORCE)
 132
 133 # Don't use X11 on OSX
 134 if (APPLE)
 135     set(CMAKE_DISABLE_FIND_PACKAGE_X11 true)
 136     set(CMAKE_DISABLE_FIND_PACKAGE_XCB true)
 137     set(CMAKE_DISABLE_FIND_PACKAGE_Qt5X11Extras true)
 138 endif()
 139
 140 # Simplify later checks
 141 #####################################################################
 142
 143 if (WANT_MONO OR WANT_QTCLIENT)
 144     set(BUILD_GUI true)
 145 endif()
 146 if (WANT_MONO OR WANT_CORE)
 147     set(BUILD_CORE true)
 148 endif()
 149
 150 # Set up Qt
 151 #####################################################################
 152
 153 set(QT_MIN_VERSION "5.5.0")
 154
 155 # Enable Qt deprecation warnings for Qt < 5.13 (on by default in newer versions)
 156 add_definitions(-DQT_DEPRECATED_WARNINGS)
 157
 158 # Disable all Qt APIs that were deprecated in 5.5 and before
 159 add_definitions(-DQT_DISABLE_DEPRECATED_BEFORE=0x050500)
 160
 161 # Find package dependencies
 162 #
 163 # Note that you can forcefully disable optional packages
 164 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 165 #####################################################################
 166
 167 # Required Qt components
 168 set(qt_components Core Network)
 169 if (BUILD_GUI)
 170     list(APPEND qt_components Gui Widgets)
 171 endif()
 172 if (BUILD_CORE)
 173     list(APPEND qt_components Sql)
 174 endif()
 175
 176 find_package(Qt5 ${QT_MIN_VERSION} REQUIRED COMPONENTS ${qt_components})
 177 set_package_properties(Qt5 PROPERTIES TYPE REQUIRED
 178     URL "https://www.qt.io/"
 179     DESCRIPTION "the Qt libraries"
 180 )
 181 message(STATUS "Found Qt ${Qt5Core_VERSION}")
 182
 183 # Check for SSL support in Qt
 184 cmake_push_check_state(RESET)
 185 set(CMAKE_REQUIRED_LIBRARIES Qt5::Core)
 186 check_cxx_source_compiles("
 187     #include \"qglobal.h\"
 188     #if defined QT_NO_SSL
 189     #  error \"No SSL support\"
 190     #endif
 191     int main() {}"
 192     HAVE_SSL)
 193 cmake_pop_check_state()
 194
 195 if (NOT HAVE_SSL)
 196     message(FATAL_ERROR "Quassel requires SSL support, but Qt is built with QT_NO_SSL")
 197 endif()
 198
 199 # Optional Qt components
 200
 201 find_package(Qt5LinguistTools QUIET)
 202 set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 203     DESCRIPTION "contains tools for handling translation files"
 204     PURPOSE "Required for having translations"
 205 )
 206
 207 if (BUILD_GUI)
 208     if (NOT WIN32)
 209         find_package(Qt5DBus QUIET)
 210         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 211             URL "https://www.qt.io/"
 212             DESCRIPTION "D-Bus support for Qt5"
 213             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 214         )
 215         if (Qt5DBus_FOUND)
 216             find_package(dbusmenu-qt5 QUIET CONFIG)
 217             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 218                 URL "https://launchpad.net/libdbusmenu-qt"
 219                 DESCRIPTION "a library implementing the DBusMenu specification"
 220                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 221             )
 222         endif()
 223     endif()
 224
 225     find_package(Qt5Multimedia QUIET)
 226     set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 227         URL "https://www.qt.io/"
 228         DESCRIPTION "Multimedia support for Qt5"
 229         PURPOSE     "Required for audio notifications"
 230     )
 231
 232     # snorenotify segfaults on startup on msys2
 233     # we don't check for just MSYS to support the Ninja generator
 234     if(NOT (WIN32 AND (NOT $ENV{MSYSTEM} STREQUAL "")))
 235         find_package(LibsnoreQt5 0.7.0 QUIET)
 236         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 237             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 238             DESCRIPTION "a cross-platform notification framework"
 239             PURPOSE     "Enable support for the snorenotify framework"
 240         )
 241         if (LibsnoreQt5_FOUND)
 242             find_package(LibsnoreSettingsQt5 QUIET)
 243             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE OPTIONAL
 244                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 245                 DESCRIPTION "a cross-platform notification framework"
 246                 PURPOSE     "Enable support for the snorenotify framework"
 247             )
 248         endif()
 249     endif()
 250
 251     if (WITH_WEBENGINE)
 252         find_package(Qt5WebEngine QUIET)
 253         set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 254             URL "https://www.qt.io/"
 255             DESCRIPTION "a WebEngine implementation for Qt"
 256             PURPOSE     "Needed for displaying previews for URLs in chat"
 257         )
 258         if (Qt5WebEngine_FOUND)
 259             find_package(Qt5WebEngineWidgets QUIET)
 260             set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 261                 URL "https://www.qt.io/"
 262                 DESCRIPTION "widgets for Qt's WebEngine implementation"
 263                 PURPOSE     "Needed for displaying previews for URLs in chat"
 264             )
 265         endif()
 266     endif()
 267
 268     if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 269         set(HAVE_WEBENGINE true)
 270     endif()
 271     add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 272
 273     if (NOT HAVE_WEBENGINE)
 274         if (WITH_WEBKIT)
 275             find_package(Qt5WebKit QUIET)
 276             set_package_properties(Qt5WebKit PROPERTIES TYPE OPTIONAL
 277                 URL "https://www.qt.io/"
 278                 DESCRIPTION "a WebKit implementation for Qt"
 279                 PURPOSE     "Needed for displaying previews for URLs in chat"
 280                 )
 281             if (Qt5WebKit_FOUND)
 282                 find_package(Qt5WebKitWidgets QUIET)
 283                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE OPTIONAL
 284                     URL "https://www.qt.io/"
 285                     DESCRIPTION "widgets for Qt's WebKit implementation"
 286                     PURPOSE     "Needed for displaying previews for URLs in chat"
 287                     )
 288             endif()
 289         endif()
 290
 291         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 292             set(HAVE_WEBKIT true)
 293         endif()
 294         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 295     endif()
 296
 297     # KDE Frameworks
 298     ################
 299
 300     # extra-cmake-modules
 301     if (WITH_KDE)
 302         set(ecm_find_type "REQUIRED")
 303         find_package(ECM NO_MODULE REQUIRED)
 304     else()
 305         # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 306         set(ecm_find_type "RECOMMENDED")
 307         find_package(ECM NO_MODULE QUIET)
 308     endif()
 309
 310     set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 311         URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 312         DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 313         PURPOSE     "Required to find KDE Frameworks components"
 314     )
 315
 316     if (ECM_FOUND)
 317         list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 318         if (WITH_KDE)
 319             find_package(KF5 REQUIRED COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig Sonnet TextWidgets WidgetsAddons XmlGui)
 320             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 321                 URL "http://www.kde.org"
 322                 DESCRIPTION "KDE Frameworks"
 323                 PURPOSE     "Required for integration into the Plasma desktop"
 324             )
 325             message(STATUS "Found KDE Frameworks ${KF5_VERSION}")
 326         endif()
 327
 328         # Optional KF5 tier1 components
 329         find_package(KF5Sonnet QUIET)
 330         set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 331             URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 332             DESCRIPTION "framework for providing spell-checking capabilities"
 333             PURPOSE "Enables spell-checking support in input widgets"
 334         )
 335     endif()
 336 endif()
 337
 338 if (BUILD_CORE)
 339     find_package(Qca-qt5 2.0 QUIET)
 340     set_package_properties(Qca-qt5 PROPERTIES TYPE RECOMMENDED
 341         URL "https://projects.kde.org/projects/kdesupport/qca"
 342         DESCRIPTION "Qt Cryptographic Architecture"
 343         PURPOSE "Required for encryption support"
 344     )
 345
 346     if (WITH_LDAP)
 347         find_package(Ldap QUIET)
 348         set_package_properties(Ldap PROPERTIES TYPE OPTIONAL
 349             URL "http://www.openldap.org/"
 350             DESCRIPTION "LDAP (Lightweight Directory Access Protocol) libraries"
 351             PURPOSE "Enables core user authentication via LDAP"
 352         )
 353     endif()
 354 endif()
 355
 356 # Non-Qt-based packages
 357 #####################################################################
 358
 359 find_package(Boost 1.54 REQUIRED)
 360 set_package_properties(Boost PROPERTIES TYPE REQUIRED
 361     URL "https://www.boost.org/"
 362     DESCRIPTION "Boost libraries for C++"
 363 )
 364 # Older versions don't define the imported target
 365 if (NOT TARGET Boost::boost)
 366     add_library(Boost::boost INTERFACE IMPORTED GLOBAL)
 367     if (Boost_INCLUDE_DIRS)
 368         set_target_properties(Boost::boost PROPERTIES
 369             INTERFACE_INCLUDE_DIRECTORIES "${Boost_INCLUDE_DIRS}")
 370     endif()
 371 endif()
 372
 373 find_package(ZLIB REQUIRED)
 374 set_package_properties(ZLIB PROPERTIES TYPE REQUIRED
 375     URL "http://www.zlib.net"
 376     DESCRIPTION "a popular compression library"
 377     PURPOSE     "Used for protocol compression"
 378 )
 379
 380 if (NOT WIN32)
 381     # Needed for generating backtraces
 382     find_package(Backtrace QUIET)
 383     set_package_properties(Backtrace PROPERTIES TYPE RECOMMENDED
 384         DESCRIPTION "a header (and possibly library) for inspecting backtraces"
 385         PURPOSE "Used for generating backtraces in case of a crash"
 386     )
 387 endif()
 388
 389 # Shared library support
 390 #####################################################################
 391
 392 option(ENABLE_SHARED "Build modules as shared libraries" ON)
 393 add_feature_info(ENABLE_SHARED ENABLE_SHARED "Build modules as shared libraries")
 394
 395 # Setup unit testing
 396 #####################################################################
 397
 398 option(BUILD_TESTING "Enable unit tests" OFF)
 399 add_feature_info(BUILD_TESTING BUILD_TESTING "Build unit tests")
 400
 401 if (BUILD_TESTING)
 402     find_package(GTest QUIET)
 403     set_package_properties(GTest PROPERTIES TYPE REQUIRED
 404         DESCRIPTION "Google's unit testing framework"
 405         PURPOSE "Required for building unit tests"
 406     )
 407
 408     find_package(Qt5Test QUIET)
 409     set_package_properties(Qt5Test PROPERTIES TYPE REQUIRED
 410         DESCRIPTION "unit testing library for the Qt5 framework"
 411         PURPOSE "Required for building unit tests"
 412     )
 413     enable_testing()
 414
 415     # GTest messes with CMAKE_CXX_FLAGS, so process them again
 416     process_cmake_cxx_flags()
 417 endif()
 418
 419 # Setup support for KDE Frameworks
 420 #####################################################################
 421
 422 if (WITH_KDE)
 423     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 424     set(WITH_KF5 TRUE)
 425
 426     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 427     set(EMBED_DATA OFF)
 428
 429     include(KDEInstallDirs)
 430 endif()
 431
 432 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 433 include(QuasselInstallDirs)
 434
 435 # RPATH and output settings
 436 #####################################################################
 437
 438 # Build artifacts in a well-known location; especially important for Windows DLLs
 439 # (which go into RUNTIME_OUTPUT_DIRECTORY and can thus be found by executables)
 440 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
 441 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
 442 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
 443
 444 # These RPATH settings allow for running directly from the build dir
 445 set(CMAKE_SKIP_BUILD_RPATH            FALSE)
 446 set(CMAKE_BUILD_WITH_INSTALL_RPATH    FALSE)
 447 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE )
 448
 449 # Set install RPATH only if libdir isn't a system directory
 450 if (IS_ABSOLUTE "${CMAKE_INSTALL_LIBDIR}")
 451     set(libdir "${CMAKE_INSTALL_LIBDIR}")
 452 else()
 453     set(libdir "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}")
 454 endif()
 455 list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${libdir}" is_systemdir)
 456 if ("${is_systemdir}" STREQUAL "-1")
 457    set(CMAKE_INSTALL_RPATH "${libdir}")
 458 endif()
 459
 460 # Various config-dependent checks and settings
 461 #####################################################################
 462
 463 # Check for syslog support
 464 if (NOT WIN32)
 465     check_include_file_cxx(syslog.h HAVE_SYSLOG)
 466     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 467 endif()
 468
 469 if (NOT WIN32)
 470     check_function_exists(umask HAVE_UMASK)
 471 endif()
 472
 473 if (EMBED_DATA)
 474     message(STATUS "Embedding data files into the binary")
 475 else()
 476     message(STATUS "Installing data files separately")
 477 endif()
 478
 479 # Windows-specific stuff
 480 #####################################################################
 481
 482 if (WIN32)
 483     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 484     if (MSVC)
 485         link_libraries(Version dwmapi shlwapi)
 486     endif()
 487 endif()
 488
 489 # Prepare the build
 490 #####################################################################
 491
 492 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 493 add_subdirectory(data)
 494 add_subdirectory(icons)
 495 add_subdirectory(pics)
 496 add_subdirectory(po)
 497
 498 # Set up and display feature summary
 499 #####################################################################
 500
 501 feature_summary(WHAT ALL
 502                 INCLUDE_QUIET_PACKAGES
 503                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 504 )
 505
 506 # Finally, compile the sources
 507 # We want this after displaying the feature summary to avoid ugly
 508 # CMake backtraces in case a required Qt5 module is missing
 509 #####################################################################
 510
 511 add_subdirectory(src)
 512
 513 # Build tests if so desired
 514 if (BUILD_TESTING)
 515     add_subdirectory(tests)
 516 endif()