CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 13)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.13-pre")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  44 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  45 if (USE_QT4) # takes precedence
  46     set(USE_QT5 OFF)
  47 else()
  48     if (NOT USE_QT5)
  49         set(USE_QT4 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 if (NOT WITH_KDE)
  75     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  76 endif()
  77
  78 # For this, the feature info is added after we know if QtWebkit is installed
  79 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" ON)
  80
  81 # For this, the feature info is added after we know if QtWebEngine is installed
  82 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  83
  84 if (APPLE)
  85     # Notification Center is only available in > 10.8, which is Darwin v12
  86     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  87         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  88         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  89     endif()
  90 endif()
  91
  92 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  93 set(EMBED_DEFAULT OFF)
  94 if (STATIC OR WIN32 OR APPLE)
  95     set(EMBED_DEFAULT ON)
  96 endif()
  97 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  98                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  99 if (NOT EMBED_DEFAULT)
 100     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 101 endif()
 102
 103 # The following options are not for end-user consumption, so don't list them in the feature summary
 104 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 105
 106 # Handle with care
 107 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 108
 109 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 110 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 111
 112 # For static builds, arbitrary extra libs might need to be linked
 113 # Define a comma-separated list here
 114 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 115 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 116 if (LINK_EXTRA)
 117     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 118     link_libraries(${LINK_EXTRA})
 119 endif()
 120
 121
 122 # Setup CMake
 123 #####################################################################
 124
 125 if (USE_QT5 AND WITH_KDE)
 126     cmake_minimum_required(VERSION 2.8.12)
 127 else()
 128     cmake_minimum_required(VERSION 2.8.9)
 129 endif()
 130
 131 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 132 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 133 if (POLICY CMP0043)
 134     cmake_policy(SET CMP0043 OLD)
 135 endif()
 136
 137 # Honor visibility settings for all target types
 138 if (POLICY CMP0063)
 139     cmake_policy(SET CMP0063 NEW)
 140 endif()
 141
 142
 143 # Simplify later checks
 144 #####################################################################
 145
 146 if (WANT_MONO OR WANT_QTCLIENT)
 147     set(BUILD_GUI true)
 148 endif()
 149 if (WANT_MONO OR WANT_CORE)
 150     set(BUILD_CORE true)
 151 endif()
 152
 153
 154 # Set up Qt
 155 #####################################################################
 156
 157 if (USE_QT5)
 158     message(STATUS "Building for Qt5...")
 159     set(QT_MIN_VERSION "5.2.0")
 160     add_definitions(-DHAVE_QT5)
 161 else()
 162     message(STATUS "Building for Qt4...")
 163     set(QT_MIN_VERSION "4.8.0")
 164
 165     # Select a Qt installation here, if you don't want to use system Qt
 166     if(QT_PATH)
 167         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 168         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 169     endif()
 170 endif()
 171
 172
 173 # Find package dependencies
 174 #
 175 # Note that you can forcefully disable optional packages
 176 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 177 #####################################################################
 178
 179 if (USE_QT5)
 180     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 181     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 182         URL "http://qt.digia.com"
 183         DESCRIPTION "contains core functionality for Qt"
 184     )
 185     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 186     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 187     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 188         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 189     endif()
 190
 191     find_package(Qt5Network QUIET)
 192     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 193         DESCRIPTION "the network module for Qt5"
 194     )
 195
 196     if (BUILD_GUI)
 197         find_package(Qt5Gui QUIET)
 198         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 199             DESCRIPTION "the GUI module for Qt5"
 200         )
 201         find_package(Qt5Widgets QUIET)
 202         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 203             DESCRIPTION "the widgets module for Qt5"
 204         )
 205
 206         if (NOT WIN32)
 207             find_package(Qt5DBus QUIET)
 208             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 209                 URL "http://qt.digia.com"
 210                 DESCRIPTION "D-Bus support for Qt5"
 211                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 212             )
 213             if (Qt5DBus_FOUND)
 214                 find_package(dbusmenu-qt5 QUIET CONFIG)
 215                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 216                     URL "https://launchpad.net/libdbusmenu-qt"
 217                     DESCRIPTION "a library implementing the DBusMenu specification"
 218                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 219                 )
 220             endif()
 221         endif()
 222
 223         find_package(Qt5Multimedia QUIET)
 224         set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 225             URL "http://qt.digia.com"
 226             DESCRIPTION "Multimedia support for Qt5"
 227             PURPOSE     "Required for audio notifications"
 228         )
 229
 230         if (NOT Qt5Multimedia_FOUND)
 231             find_package(Phonon4Qt5 QUIET)
 232             set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 233                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 234                 DESCRIPTION "a multimedia abstraction library"
 235                 PURPOSE     "Required for audio notifications"
 236             )
 237         endif()
 238
 239         find_package(LibsnoreQt5 0.7.0 QUIET)
 240         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 241             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 242             DESCRIPTION "a cross-platform notification framework"
 243             PURPOSE     "Enable support for the snorenotify framework"
 244         )
 245         if(LibsnoreQt5_FOUND)
 246             find_package(LibsnoreSettingsQt5)
 247             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 248                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 249                 DESCRIPTION "a cross-platform notification framework"
 250                 PURPOSE     "Enable support for the snorenotify framework"
 251             )
 252         endif()
 253
 254
 255         if (WITH_WEBKIT)
 256             find_package(Qt5WebKit QUIET)
 257             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 258                 URL "http://qt.digia.com"
 259                 DESCRIPTION "a WebKit implementation for Qt"
 260                 PURPOSE     "Needed for displaying previews for URLs in chat"
 261             )
 262             if (Qt5WebKit_FOUND)
 263                 find_package(Qt5WebKitWidgets QUIET)
 264                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 265                     URL "http://qt.digia.com"
 266                     DESCRIPTION "widgets for Qt's WebKit implementation"
 267                     PURPOSE     "Needed for displaying previews for URLs in chat"
 268                 )
 269             endif()
 270         endif()
 271
 272         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 273             set(HAVE_WEBKIT true)
 274         endif()
 275         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 276
 277         if (WITH_WEBENGINE)
 278             find_package(Qt5WebEngine QUIET)
 279             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 280                 URL "http://qt.digia.com"
 281                 DESCRIPTION "a WebEngine implementation for Qt"
 282                 PURPOSE     "Needed for displaying previews for URLs in chat"
 283             )
 284             if (Qt5WebEngine_FOUND)
 285                 find_package(Qt5WebEngineWidgets QUIET)
 286                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 287                     URL "http://qt.digia.com"
 288                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 289                     PURPOSE     "Needed for displaying previews for URLs in chat"
 290                 )
 291             endif()
 292         endif()
 293
 294         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 295             set(HAVE_WEBENGINE true)
 296         endif()
 297         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 298
 299         # KDE Frameworks
 300         ################
 301
 302         if (WITH_KDE)
 303             set(ecm_find_type "REQUIRED")
 304         else()
 305             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 306             set(ecm_find_type "RECOMMENDED")
 307         endif()
 308
 309         # extra-cmake-modules
 310         find_package(ECM NO_MODULE QUIET)
 311         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 312             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 313             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 314             PURPOSE     "Required to find KDE Frameworks components"
 315         )
 316
 317         if (ECM_FOUND)
 318             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 319             if (WITH_KDE)
 320                 find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 321                 set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 322                     URL "http://www.kde.org"
 323                     DESCRIPTION "KDE Frameworks"
 324                     PURPOSE     "Required for integration into the Plasma desktop"
 325                 )
 326             else(WITH_KDE)
 327                 find_package(KF5Sonnet QUIET)
 328                 set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 329                     URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 330                     DESCRIPTION "framework for providing spell-checking capabilities"
 331                     PURPOSE "Enables spell-checking support in input widgets"
 332                 )
 333             endif(WITH_KDE)
 334         endif(ECM_FOUND)
 335
 336     endif(BUILD_GUI)
 337
 338     if (BUILD_CORE)
 339         find_package(Qt5Script QUIET)
 340         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 341             DESCRIPTION "provides scripting support for Qt5"
 342         )
 343         find_package(Qt5Sql QUIET)
 344         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 345             DESCRIPTION "the database support module for Qt5"
 346         )
 347
 348         find_package(QCA2-QT5)
 349         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 350             URL "https://projects.kde.org/projects/kdesupport/qca"
 351             DESCRIPTION "Qt Cryptographic Architecture"
 352             PURPOSE "Required for encryption support"
 353         )
 354
 355     endif(BUILD_CORE)
 356
 357     find_package(Qt5LinguistTools QUIET)
 358     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 359                            DESCRIPTION "contains tools for handling translation files"
 360                            PURPOSE "Required for having translations"
 361     )
 362
 363     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 364     if (Qt5LinguistTools_FOUND)
 365         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 366             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 367             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 368             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 369         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 370             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 371             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 372         endif()
 373
 374         # Compatibility with the Qt4 variables
 375         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 376         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 377         if (Qt5_LCONVERT_EXECUTABLE)
 378             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 379         endif()
 380     endif()
 381
 382 else(USE_QT5)
 383     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 384
 385     if (BUILD_GUI)
 386         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 387         if (QT_QTDBUS_FOUND)
 388             find_package(dbusmenu-qt QUIET CONFIG)
 389             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 390                 URL "https://launchpad.net/libdbusmenu-qt"
 391                 DESCRIPTION "a library implementing the DBusMenu specification"
 392                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 393             )
 394         endif()
 395
 396         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 397             set(HAVE_WEBKIT true)
 398         endif()
 399         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 400
 401         if (WITH_KDE)
 402             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 403             set(_cflags ${CMAKE_C_FLAGS})
 404             find_package(KDE4 4.4 QUIET)
 405             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 406                 URL "http://www.kde.org"
 407                 DESCRIPTION "a world-class desktop environment"
 408                 PURPOSE "Enables various bits for improving integration with KDE"
 409             )
 410             set(CMAKE_C_FLAGS ${_cflags})
 411
 412         else(WITH_KDE)
 413             find_package(Phonon QUIET)
 414             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 415                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 416                 DESCRIPTION "a multimedia abstraction library"
 417                 PURPOSE     "Required for audio notifications"
 418             )
 419         endif(WITH_KDE)
 420
 421         find_package(IndicateQt QUIET)
 422         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 423             URL "https://launchpad.net/libindicate-qt/"
 424             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 425             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 426         )
 427
 428     endif(BUILD_GUI)
 429
 430     if (BUILD_CORE)
 431
 432         find_package(QCA2 QUIET)
 433         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 434             URL "https://projects.kde.org/projects/kdesupport/qca"
 435             DESCRIPTION "Qt Cryptographic Architecture"
 436             PURPOSE     "Required for encryption support"
 437         )
 438
 439
 440     endif()
 441
 442     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 443     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 444     if (QT_LRELEASE_EXECUTABLE)
 445         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 446         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 447     endif()
 448 endif()
 449
 450
 451 # Non-Qt-based packages
 452
 453 # zlib for compression, however we can always fall back to miniz
 454 find_package(ZLIB QUIET)
 455 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 456     URL "http://www.zlib.net"
 457     DESCRIPTION "a popular compression library"
 458     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 459 )
 460
 461
 462 if (NOT WIN32)
 463     # Execinfo is needed for generating backtraces
 464     find_package(ExecInfo QUIET)
 465     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 466         DESCRIPTION "a library for inspecting backtraces"
 467         PURPOSE "Used for generating backtraces in case of a crash"
 468     )
 469 endif()
 470
 471 # Check for SSL support in Qt
 472 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 473 # a small test program checking the defines. This works for both Qt4 and Qt5.
 474 cmake_push_check_state(RESET)
 475 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 476 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 477
 478 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 479     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 480 endif()
 481
 482 check_cxx_source_compiles("
 483     #include \"qglobal.h\"
 484     #if defined QT_NO_SSL
 485     #  error \"No SSL support\"
 486     #endif
 487     int main() {}"
 488     HAVE_SSL)
 489 cmake_pop_check_state()
 490
 491 # Additional compile settings
 492 #####################################################################
 493
 494 # This sets -fPIC and friends if required by the installed Qt5 library
 495 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 496     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 497 endif()
 498
 499 # Needed to compile with mingw without kde
 500 if (MINGW AND NOT KDE4_FOUND)
 501     add_definitions(-D_WIN32_WINNT=0x0500)
 502     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 503     # workaround for bug in mingw gcc 4.0
 504     add_definitions(-U__STRICT_ANSI__)
 505 endif()
 506
 507 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 508 if (CMAKE_COMPILER_IS_GNUCXX)
 509     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 510 endif()
 511
 512
 513 # Setup KDE / KDE Frameworks
 514 #####################################################################
 515
 516 # We want to do this up here, so we have the necessary variables and defines set before
 517 # compiling anything
 518
 519 if (KDE4_FOUND)
 520     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 521     set(EMBED_DATA OFF)
 522
 523     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 524     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 525     set(WITH_KDE4 TRUE)
 526 endif()
 527
 528 if (USE_QT5 AND WITH_KDE)
 529     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 530     set(EMBED_DATA OFF)
 531
 532     include(KDEInstallDirs)
 533     include(KDECompilerSettings)
 534     include(KDECMakeSettings)
 535
 536     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 537     set(WITH_KF5 TRUE)
 538 endif()
 539
 540 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 541 include(QuasselInstallDirs)
 542
 543 # Various config-dependent checks and settings
 544 #####################################################################
 545
 546 if (NOT ZLIB_FOUND)
 547     message(STATUS "zlib NOT found, using bundled miniz for compression")
 548     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 549         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 550     endif()
 551 endif()
 552
 553 if (HAVE_SSL)
 554     add_definitions(-DHAVE_SSL)
 555 endif()
 556 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 557
 558 # Check for syslog support
 559 if (NOT WIN32)
 560     check_include_file(syslog.h HAVE_SYSLOG)
 561     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 562 endif()
 563
 564 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 565
 566 if (EMBED_DATA)
 567     message(STATUS "Embedding data files into the binary")
 568 else()
 569     message(STATUS "Installing data files separately")
 570 endif()
 571
 572 if (INDICATEQT_FOUND)
 573     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 574 endif()
 575
 576 if (NOT WIN32)
 577     check_function_exists(umask HAVE_UMASK)
 578     if(HAVE_UMASK)
 579         add_definitions(-DHAVE_UMASK)
 580     endif(HAVE_UMASK)
 581 endif()
 582
 583
 584 # Windows-specific stuff
 585 #####################################################################
 586
 587 if (WIN32)
 588     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 589     if (MSVC)
 590         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 591         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 592         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 593         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 594         link_libraries(Version dwmapi shlwapi)
 595         if (USE_QT5)
 596             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 597         endif()
 598     endif()
 599     if(HAVE_SSL AND STATIC)
 600         find_package(OpenSSL REQUIRED)
 601         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 602     endif()
 603 endif()
 604
 605
 606 # Static builds (very much non-portable, so don't use -DSTATIC
 607 # unless you know what you do!)
 608 #####################################################################
 609
 610 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 611     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 612     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 613     if (HAVE_SSL)
 614         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 615     endif()
 616 endif()
 617
 618
 619 # Generate version information from Git
 620 #####################################################################
 621
 622 include(GetGitRevisionDescription)
 623 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 624 git_describe(GIT_DESCRIBE --long)
 625
 626 # If in a Git repo we can get the commit-date from a git command
 627 if (GIT_HEAD)
 628     execute_process(
 629         COMMAND git show -s --format=%ct
 630         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 631         OUTPUT_VARIABLE GIT_COMMIT_DATE
 632         OUTPUT_STRIP_TRAILING_WHITESPACE
 633     )
 634 endif()
 635
 636 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 637 # enviroment
 638 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 639   if (DEFINED ENV{GIT_HEAD})
 640       set(GIT_HEAD $ENV{GIT_HEAD})
 641   endif ()
 642   if (DEFINED ENV{GIT_DESCRIBE})
 643      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 644   endif()
 645 endif()
 646
 647 # Sanitize things if we're not in a Git repo
 648 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 649     set(GIT_HEAD "")
 650     set(GIT_DESCRIBE "")
 651     set(GIT_COMMIT_DATE 0)
 652 endif()
 653
 654 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 655
 656 # Prepare the build
 657 #####################################################################
 658
 659 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 660 set(COMMON_DEPS ${RC_WIN32})
 661 set(CORE_DEPS )
 662 set(CLIENT_DEPS )
 663
 664 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 665 add_subdirectory(data)
 666 add_subdirectory(icons)
 667 add_subdirectory(pics)
 668 add_subdirectory(po)
 669
 670
 671 # Set up and display feature summary
 672 #####################################################################
 673
 674 feature_summary(WHAT ALL
 675                 INCLUDE_QUIET_PACKAGES
 676                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 677 )
 678
 679 # Finally, compile the sources
 680 # We want this after displaying the feature summary to avoid ugly
 681 # CMake backtraces in case a required Qt5 module is missing
 682 #####################################################################
 683
 684 add_subdirectory(src)