CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 # You may pass various options to cmake:
   3 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   4 #                  : select binaries to build
   5 # -DQT=/path/to/qt : Choose a Qt4 installation to use instead of the system Qt4
   6 # -DSTATIC=ON      : Enable static building of Quassel. Use with care.
   7 # -DSPUTDEV=ON     : Do not use.
   8 # -DDEPLOY=ON      : Mac OS X only. Use only fore redistribution Quassel Packages!!
   9 #
  10 # NOTE: You need to remove CMakeCache.txt if you plan to change any of these values!
  11
  12 project(QuasselIRC)
  13
  14 # Target scopes don't work in older versions
  15 cmake_minimum_required(VERSION 2.4.7 FATAL_ERROR)
  16
  17 if(COMMAND cmake_policy)
  18    cmake_policy(SET CMP0003 OLD)  # suppress linker warnings
  19 endif(COMMAND cmake_policy)
  20
  21 # Use our own (well, KDE's) version of some modules
  22 # In particular cmake's FindQt4 and FindOpenSSL are quite buggy
  23 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  24
  25 # Various options and variables that can be set on the command line
  26 option(WANT_CORE     "Build the core (server) binary"           ON)
  27 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  28 option(WANT_MONO     "Build the monolithic (all-in-one) binary" OFF)
  29
  30 option(STATIC        "Enable static building (might not be portable)" OFF)
  31 option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  32 option(SPUTDEV       "Do not use!" OFF)
  33
  34 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt")
  35
  36 if(STATIC)
  37   set(CMAKE_BUILD_TYPE Release)
  38 endif(STATIC)
  39
  40 # Enable various flags on gcc
  41 if(CMAKE_COMPILER_IS_GNUCXX)
  42   include(CheckCXXCompilerFlag)
  43   check_cxx_compiler_flag(-Wall HAVE_WALL)
  44   if(HAVE_WALL)
  45     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
  46   endif(HAVE_WALL)
  47   check_cxx_compiler_flag(-Wextra HAVE_WEXTRA)
  48   if(HAVE_WEXTRA)
  49     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wextra")
  50   endif(HAVE_WEXTRA)
  51   check_cxx_compiler_flag(-ansi HAVE_ANSI)
  52   if(HAVE_ANSI)
  53     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi")
  54   endif(HAVE_ANSI)
  55 endif(CMAKE_COMPILER_IS_GNUCXX)
  56
  57 set(QT_MIN_VERSION "4.3.0")
  58
  59 if(APPLE AND DEPLOY)
  60   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
  61   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
  62   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
  63 endif(APPLE AND DEPLOY)
  64
  65 # Enable mostly b0rked stuff (new ChatView), do not enable this unless you know what you do...
  66 if(SPUTDEV)
  67   add_definitions(-DSPUTDEV)
  68 endif(SPUTDEV)
  69
  70 # Set up OpenSSL
  71 find_package(OpenSSL)
  72 if(NOT OPENSSL_FOUND)
  73   add_definitions(-DQT_NO_OPENSSL)
  74 endif(NOT OPENSSL_FOUND)
  75
  76 # Select a Qt installation here, if you don't want to use system Qt
  77 if(QT)
  78   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
  79   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
  80 endif(QT)
  81
  82 # Now that we have the correct $PATH, lets find Qt!
  83 find_package(Qt4 REQUIRED)
  84
  85 set(QT_DONT_USE_QTGUI 1)
  86 include(${QT_USE_FILE})
  87 include_directories(${QT_INCLUDES})
  88
  89 # We need to create a version.gen
  90 # For this, we create our genversion binary and make sure it is run every time.
  91 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
  92 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
  93
  94 add_custom_target(genversion_run ALL ${CMAKE_BINARY_DIR}/genversion
  95                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/common/version.gen)
  96 add_dependencies(genversion_run genversion)
  97
  98 # Add needed subdirs
  99 add_subdirectory(src/common)
 100 include_directories(src/common)
 101 if(WANT_CORE OR WANT_MONO)
 102   add_subdirectory(src/core)
 103   include_directories(src/core)
 104 endif(WANT_CORE OR WANT_MONO)
 105 if(WANT_QTCLIENT OR WANT_MONO)
 106   add_subdirectory(src/client)
 107   add_subdirectory(src/uisupport)
 108   add_subdirectory(src/qtui)
 109   include_directories(src/client)
 110   include_directories(src/uisupport)
 111   include_directories(src/qtui)
 112 endif(WANT_QTCLIENT OR WANT_MONO)
 113
 114 # Make sure version.gen exists before building mod_common
 115 add_dependencies(mod_common genversion_run)
 116
 117 # Add resources
 118 qt4_add_resources(RC_I18N i18n/i18n.qrc)
 119 qt4_add_resources(RC_ICONS src/icons/icons.qrc)
 120 qt4_add_resources(RC_QUASSEL_ICONS src/icons/quassel-icons.qrc)
 121 qt4_add_resources(RC_SQL src/core/sql.qrc)
 122
 123 # Set global buildflags
 124 # This is very much non-portable, so don't use -DSTATICGCC until you know what
 125 # you do.
 126 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 127   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 128   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 129   if(OPENSSL_FOUND)
 130     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 131   endif(OPENSSL_FOUND)
 132 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 133
 134 if(STATIC AND WIN32)
 135   link_libraries(imm32 winmm)  # missing by default :/
 136    if(OPENSSL_FOUND)
 137      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 138    endif(OPENSSL_FOUND)
 139 endif(STATIC AND WIN32)
 140
 141 if(WIN32)
 142   set(WIN32_RC src/icons/win32.rc)  # for app icons on windows
 143 endif(WIN32)
 144
 145 # Here comes the dirty part. Our targets need different Qt4 modules, i.e. different libs
 146 # and defines. We can't simply include UseQt4 several times, since definitions add up.
 147 # We workaround this by using our own macro to figure out what to add.
 148
 149 # This macro sets variables for additional Qt modules.
 150 macro(setup_qt4_variables)
 151   set(QUASSEL_QT_LIBRARIES )
 152   IF(WIN32)
 153     set(MAIN MAIN)
 154   ENDIF(WIN32)
 155   foreach(qtmod CORE ${ARGV} ${MAIN})
 156     set(QUASSEL_QT_LIBRARIES ${QUASSEL_QT_LIBRARIES} ${QT_QT${qtmod}_LIBRARY} ${QT_${qtmod}_LIB_DEPENDENCIES})
 157   endforeach(qtmod ${ARGV})
 158   set(QUASSEL_QT_LIBRARIES ${QUASSEL_QT_LIBRARIES} ${QT_LIBRARIES})
 159 endmacro(setup_qt4_variables)
 160
 161 # Now we have everything, so just glue the right pieces together :)
 162 if(WANT_CORE)
 163   setup_qt4_variables(NETWORK SCRIPT SQL)
 164   add_executable(quasselcore ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 165                              ${RC_SQL} ${RC_I18N} ${WIN32_RC})
 166   set_target_properties(quasselcore PROPERTIES
 167                                     COMPILE_FLAGS "-DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_CORE")
 168   target_link_libraries(quasselcore mod_core mod_common
 169                                     ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 170 endif(WANT_CORE)
 171
 172 if(WANT_QTCLIENT)
 173   setup_qt4_variables(GUI NETWORK)
 174   add_executable(quasselclient WIN32 ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 175                                      ${RC_ICONS} ${RC_QUASSEL_ICONS} ${RC_I18N} ${WIN32_RC})
 176   set_target_properties(quasselclient PROPERTIES
 177                                       COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DBUILD_QTUI")
 178   target_link_libraries(quasselclient mod_qtui mod_uisupport mod_client mod_common
 179                                       ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 180 endif(WANT_QTCLIENT)
 181
 182 if(WANT_MONO)
 183   setup_qt4_variables(GUI NETWORK SCRIPT SQL)
 184   add_executable(quassel WIN32 ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 185                                ${RC_ICONS} ${RC_QUASSEL_ICONS} ${RC_SQL} ${RC_I18N} ${WIN32_RC})
 186   set_target_properties(quassel PROPERTIES
 187                                 COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_MONO")
 188   target_link_libraries(quassel mod_qtui mod_uisupport mod_client mod_core mod_common
 189                                 ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 190 endif(WANT_MONO)
 191
 192 # Build bundles for MacOSX
 193 if(APPLE)
 194   add_custom_command(TARGET quasselclient POST_BUILD
 195                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
 196                              ${CMAKE_SOURCE_DIR} "Quassel Client" quasselclient)
 197   add_custom_command(TARGET quassel POST_BUILD
 198                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
 199                              ${CMAKE_SOURCE_DIR} "Quassel" quassel)
 200   if(DEPLOY)
 201     add_custom_command(TARGET quasselclient POST_BUILD
 202                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Client)
 203     add_custom_command(TARGET quasselcore POST_BUILD
 204                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Core)
 205   endif(DEPLOY)
 206 endif(APPLE)
 207
 208 # Install rules
 209 if(WANT_CORE)
 210   install(TARGETS quasselcore
 211           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 212 endif(WANT_CORE)
 213
 214 if(WANT_QTCLIENT)
 215   install(TARGETS quasselclient
 216           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 217
 218   install(FILES quasselclient.desktop
 219           DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications)
 220 endif(WANT_QTCLIENT)
 221
 222 if(WANT_MONO)
 223   install(TARGETS quassel
 224           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 225
 226   install(FILES quassel.desktop
 227           DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications)
 228 endif(WANT_MONO)