CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 11)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.11-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37
  38 # Options and variables that can be set on the command line
  39 #####################################################################
  40
  41 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  42 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  43 if (USE_QT4) # takes precedence
  44     set(USE_QT5 OFF)
  45 else()
  46     if (NOT USE_QT5)
  47         set(USE_QT4 ON)
  48     endif()
  49 endif()
  50
  51 # Select the binaries to build
  52 option(WANT_CORE     "Build the core (server) binary"           ON)
  53 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  54 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  55 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  56 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  57 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  58
  59 # Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
  60 cmake_dependent_option(WITH_KDE "KDE4 integration" OFF "USE_QT4" OFF)
  61 add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  62
  63 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  64 if (NOT WITH_KDE)
  65     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  66 endif()
  67
  68 # For this, the feature info is added after we know if QtWebkit is installed
  69 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  70
  71 if (APPLE)
  72     # Notification Center is only available in > 10.8, which is Darwin v12
  73     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  75         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  76     endif()
  77 endif()
  78
  79 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  80 set(EMBED_DEFAULT OFF)
  81 if (STATIC OR WIN32 OR APPLE)
  82     set(EMBED_DEFAULT ON)
  83 endif()
  84 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  85                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  86 if (NOT EMBED_DEFAULT)
  87     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  88 endif()
  89
  90 # The following options are not for end-user consumption, so don't list them in the feature summary
  91 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  92
  93 # Handle with care
  94 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
  95
  96 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
  97 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
  98
  99 # For static builds, arbitrary extra libs might need to be linked
 100 # Define a comma-separated list here
 101 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 102 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 103 if (LINK_EXTRA)
 104     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 105     link_libraries(${LINK_EXTRA})
 106 endif()
 107
 108
 109 # Simplify later checks
 110 #####################################################################
 111
 112 if (WANT_MONO OR WANT_QTCLIENT)
 113     set(BUILD_GUI true)
 114 endif()
 115 if (WANT_MONO OR WANT_CORE)
 116     set(BUILD_CORE true)
 117 endif()
 118
 119
 120 # Set up Qt
 121 #####################################################################
 122
 123 if (USE_QT5)
 124     message(STATUS "Building for Qt5...")
 125     set(QT_MIN_VERSION "5.2.0")
 126     add_definitions(-DHAVE_QT5)
 127 else()
 128     message(STATUS "Building for Qt4...")
 129     if (BUILD_GUI)
 130         set(QT_MIN_VERSION "4.6.0")
 131     else()
 132         set(QT_MIN_VERSION "4.4.0")
 133     endif()
 134
 135     # Select a Qt installation here, if you don't want to use system Qt
 136     if(QT_PATH)
 137         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 138         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 139     endif()
 140 endif()
 141
 142 # Find package dependencies
 143 #
 144 # Note that you can forcefully disable optional packages
 145 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 146 #####################################################################
 147
 148 if(USE_QT5)
 149     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 150     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 151         URL "http://qt.digia.com"
 152         DESCRIPTION "contains core functionality for Qt"
 153     )
 154     find_package(Qt5Network QUIET)
 155     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 156         DESCRIPTION "the network module for Qt5"
 157     )
 158
 159     if (BUILD_GUI)
 160         find_package(Qt5Gui QUIET)
 161         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 162             DESCRIPTION "the GUI module for Qt5"
 163         )
 164         find_package(Qt5Widgets QUIET)
 165         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 166             DESCRIPTION "the widgets module for Qt5"
 167         )
 168
 169         find_package(Qt5DBus QUIET)
 170         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 171             URL "http://qt.digia.com"
 172             DESCRIPTION "D-Bus support for Qt5"
 173             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 174         )
 175         if (Qt5DBus_FOUND)
 176             find_package(dbusmenu-qt5 QUIET CONFIG)
 177             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 178                 URL "https://launchpad.net/libdbusmenu-qt"
 179                 DESCRIPTION "a library implementing the DBusMenu specification"
 180                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 181             )
 182         endif()
 183
 184         find_package(Phonon4Qt5 QUIET)
 185         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 186             URL "https://projects.kde.org/projects/kdesupport/phonon"
 187             DESCRIPTION "a multimedia abstraction library"
 188             PURPOSE     "Required for audio notifications"
 189         )
 190
 191         if (WITH_WEBKIT)
 192             find_package(Qt5Webkit QUIET)
 193             set_package_properties(Qt5Webkit PROPERTIES TYPE RECOMMENDED
 194                 URL "http://qt.digia.com"
 195                 DESCRIPTION "a Webkit implementation for Qt"
 196                 PURPOSE     "Needed for displaying previews for URLs in chat"
 197             )
 198         endif()
 199         add_feature_info("WITH_WEBKIT and QtWebkit module" Qt5Webkit_FOUND "Support showing previews for URLs in chat")
 200
 201     endif(BUILD_GUI)
 202     if (BUILD_CORE)
 203         find_package(Qt5Script QUIET)
 204         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 205             DESCRIPTION "provides scripting support for Qt5"
 206         )
 207         find_package(Qt5Sql QUIET)
 208         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 209             DESCRIPTION "the database support module for Qt5"
 210         )
 211
 212         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 213         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 214         #find_package(QCA2 QUIET)
 215         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 216         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 217         #    DESCRIPTION "Qt Cryptographic Architecture"
 218         #    PURPOSE "Required for encryption support"
 219         #)
 220
 221     endif(BUILD_CORE)
 222
 223     find_package(Qt5LinguistTools QUIET)
 224     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 225                            DESCRIPTION "contains tools for handling translation files"
 226                            PURPOSE "Required for having translations"
 227     )
 228     # Qt5 does not define a target for lconvert, so we need to find it ourselves
 229     if (Qt5LinguistTools_FOUND)
 230         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 231             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 232             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 233             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 234         endif()
 235         # Compatibility with the Qt4 variables
 236         set (QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 237         set (QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 238     endif()
 239
 240 else(USE_QT5)
 241     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 242
 243     if (BUILD_GUI)
 244         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 245         if (QT_QTDBUS_FOUND)
 246             find_package(dbusmenu-qt QUIET CONFIG)
 247             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 248                 URL "https://launchpad.net/libdbusmenu-qt"
 249                 DESCRIPTION "a library implementing the DBusMenu specification"
 250                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 251             )
 252         endif()
 253
 254         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 255             set(HAVE_WEBKIT true)
 256         endif()
 257         add_feature_info("WITH_WEBKIT and QtWebkit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 258
 259         if (WITH_KDE)
 260             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 261             set(_cflags ${CMAKE_C_FLAGS})
 262             find_package(KDE4 4.4 QUIET)
 263             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 264                 URL "http://www.kde.org"
 265                 DESCRIPTION "a world-class desktop environment"
 266                 PURPOSE "Enables various bits for improving integration with KDE"
 267             )
 268             set(CMAKE_C_FLAGS ${_cflags})
 269
 270         else(WITH_KDE)
 271             find_package(Phonon QUIET)
 272             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 273                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 274                 DESCRIPTION "a multimedia abstraction library"
 275                 PURPOSE     "Required for audio notifications"
 276             )
 277
 278             find_package(Libsnore QUIET)
 279             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 280                 URL "https://github.com/TheOneRing/Snorenotify"
 281                 DESCRIPTION "a cross-platform notification framework"
 282                 PURPOSE     "Enable support for the snorenotify framework"
 283             )
 284         endif(WITH_KDE)
 285
 286         find_package(IndicateQt QUIET)
 287         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 288             URL "https://launchpad.net/libindicate-qt/"
 289             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 290             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 291         )
 292
 293     endif(BUILD_GUI)
 294     if (BUILD_CORE)
 295
 296         find_package(QCA2 QUIET)
 297         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 298             URL "https://projects.kde.org/projects/kdesupport/qca"
 299             DESCRIPTION "Qt Cryptographic Architecture"
 300             PURPOSE     "Required for encryption support"
 301         )
 302
 303
 304     endif()
 305
 306     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 307     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 308     if (QT_LRELEASE_EXECUTABLE)
 309         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 310         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 311     endif()
 312 endif()
 313
 314
 315 # Non-Qt-based packages
 316
 317 # zlib for compression, however we can always fall back to miniz
 318 find_package(ZLIB QUIET)
 319 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 320     URL "http://www.zlib.net"
 321     DESCRIPTION "a popular compression library"
 322     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 323 )
 324
 325
 326 if (NOT WIN32)
 327     # Execinfo is needed for generating backtraces
 328     find_package(ExecInfo QUIET)
 329     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 330         DESCRIPTION "a library for inspecting backtraces"
 331         PURPOSE "Used for generating backtraces in case of a crash"
 332     )
 333 endif()
 334
 335
 336 # Various checks
 337 #####################################################################
 338
 339 if (NOT ZLIB_FOUND)
 340     message(STATUS "zlib NOT found, using bundled miniz for compression")
 341     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 342         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 343     endif()
 344 endif()
 345
 346 if (KDE4_FOUND)
 347     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 348     set(EMBED_DATA OFF)
 349
 350     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 351     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 352 endif()
 353
 354 # Check for SSL support in Qt
 355 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 356 # a small test program checking the defines. This works for both Qt4 and Qt5.
 357 cmake_push_check_state(RESET)
 358 if (Qt5_POSITION_INDEPENDENT_CODE)
 359     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 360 endif()
 361 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 362 check_cxx_source_compiles("
 363     #include \"qglobal.h\"
 364     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 365     #  error \"No SSL support\"
 366     #endif
 367     int main() {}"
 368     HAVE_SSL)
 369 cmake_pop_check_state()
 370
 371 if (HAVE_SSL)
 372     add_definitions(-DHAVE_SSL)
 373 endif()
 374 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 375
 376 # Check for syslog support
 377 if (NOT WIN32)
 378     check_include_file(syslog.h HAVE_SYSLOG)
 379     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 380 endif()
 381
 382 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 383
 384 # Various settings
 385 ##################
 386
 387 # needed to compile with mingw without kde
 388 if (MINGW AND NOT KDE4_FOUND)
 389     add_definitions(-D_WIN32_WINNT=0x0500)
 390     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 391 # workaround for bug in mingw gcc 4.0
 392     add_definitions(-U__STRICT_ANSI__)
 393 endif()
 394
 395 # Now set up install locations; those are set by KDE if integration is enabled
 396 if(NOT KDE4_FOUND)
 397   if(WIN32)
 398     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 399     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 400     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 401     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 402   else(WIN32)
 403     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 404     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 405     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 406     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 407   endif(WIN32)
 408 endif()
 409
 410 if(EMBED_DATA)
 411   message(STATUS "Embedding data files into the binary")
 412 else(EMBED_DATA)
 413   message(STATUS "Installing data files separately")
 414 endif(EMBED_DATA)
 415
 416 # RPATH needs to be set correctly
 417 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 418 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 419 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 420
 421 # Set global buildflags
 422 # This is very much non-portable, so don't use -DSTATIC until you know what
 423 # you do.
 424 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 425   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 426   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 427   if(HAVE_SSL)
 428     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 429   endif(HAVE_SSL)
 430 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 431
 432 if(WIN32)
 433   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 434   if(MSVC)
 435     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 436     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 437     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 438     link_libraries(Version dwmapi shlwapi)
 439   endif(MSVC)
 440   if(HAVE_SSL AND STATIC)
 441      find_package(OpenSSL REQUIRED)
 442      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 443   endif(HAVE_SSL AND STATIC)
 444 endif(WIN32)
 445
 446 if(INDICATEQT_FOUND)
 447   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 448 endif()
 449
 450 if(NOT WIN32)
 451   check_function_exists(umask HAVE_UMASK)
 452   if(HAVE_UMASK)
 453     add_definitions(-DHAVE_UMASK)
 454   endif(HAVE_UMASK)
 455 endif(NOT WIN32)
 456
 457 # Generate version information from Git
 458 include(GetGitRevisionDescription)
 459 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 460 git_describe(GIT_DESCRIBE --long)
 461
 462 # Sanitize things if we're not in a Git repo
 463 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 464     set(GIT_HEAD "")
 465     set(GIT_DESCRIBE "")
 466 endif()
 467
 468 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 469
 470 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 471 set(COMMON_DEPS ${RC_WIN32})
 472 set(CORE_DEPS )
 473 set(CLIENT_DEPS )
 474
 475 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 476 add_subdirectory(data)
 477 add_subdirectory(icons)
 478 add_subdirectory(pics)
 479 add_subdirectory(po)
 480
 481 # Set up and display feature summary
 482 #####################################################################
 483
 484 feature_summary(WHAT ALL
 485                 INCLUDE_QUIET_PACKAGES
 486                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 487 )
 488
 489 # Finally, compile the sources
 490 # We want this after displaying the feature summary to avoid ugly
 491 # CMake backtraces in case a required Qt5 modules misses
 492 #####################################################################
 493
 494 add_subdirectory(src)