CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 project(QuasselIRC)
  29
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32 include(CheckCXXCompilerFlag)
  33
  34 # For building against Qt5, we check for an even newer cmake version below!
  35 cmake_minimum_required(VERSION 2.8.1 FATAL_ERROR)
  36
  37 if(COMMAND cmake_policy)
  38    cmake_policy(SET CMP0003 NEW)
  39 endif(COMMAND cmake_policy)
  40
  41 # Use our own (well, and KDE's) version of some modules
  42 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  43 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  44 include(QuasselMacros)
  45
  46 # Various options and variables that can be set on the command line
  47 option(WANT_CORE     "Build the core (server) binary"           ON)
  48 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  49 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  50
  51 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  52 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  53 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  54 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  55 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  56 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  57 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  58 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  59
  60 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  61 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  62 # run on a matching KDE version only.
  63 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  64
  65 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  66 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  67
  68 option(STATIC        "Enable static building (might not be portable)" OFF)
  69
  70 if(APPLE)
  71   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  72   # Notification Center is only available in > 10.8, which is Darwin v12
  73   if(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74     option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  75   endif(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  76 endif(APPLE)
  77
  78 # Default to embedding data in the static case
  79 if(STATIC OR WIN32)
  80   set(EMBED_DEFAULT ON)
  81 else(STATIC OR WIN32)
  82   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  83 endif(STATIC OR WIN32)
  84
  85 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  86
  87 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  88
  89 # Some settings imply others
  90 if(STATIC)
  91   add_definitions(-DSTATIC)
  92   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  93 endif(STATIC)
  94
  95 if(WIN32)
  96   # We don't support separately installed resources yet on Win32
  97   set(EMBED_DATA ON)
  98 endif(WIN32)
  99
 100 # For static builds, arbitrary extra libs might need to be linked
 101 # Define a comma-separated list here
 102 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 103 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 104 if(LINK_EXTRA)
 105   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 106   link_libraries(${LINK_EXTRA})
 107 endif(LINK_EXTRA)
 108
 109 # Build Types
 110
 111 if(CMAKE_CONFIGURATION_TYPES)
 112    set(CMAKE_CONFIGURATION_TYPES Release RelWithDebInfo Debug Debugfull Profile MinSizeRel)
 113    set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 114      "Reset the configurations to what we need"
 115      FORCE)
 116 endif()
 117
 118 if(NOT CMAKE_BUILD_TYPE)
 119   SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 120      "Choose the type of build, options are: None Debug Release RelWithDebInfo Debug Debugfull Profile MinSizeRel."
 121      FORCE)
 122 endif()
 123
 124 # Qt debug flags
 125 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 126 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUGFULL QT_DEBUG)
 127 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 128 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 129 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_PROFILE QT_NO_DEBUG NDEBUG)
 130 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 131
 132 if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 133   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 134 endif()
 135
 136 # Enable various flags on gcc
 137 if(CMAKE_COMPILER_IS_GNUCXX)
 138   # Let's just hope that all gccs support these options and skip the tests...
 139   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 140   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 141 #  set(CMAKE_CXX_FLAGS_RELEASE          "-O2")   # use CMake default
 142 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-g -O2")  # use CMake default
 143   set(CMAKE_CXX_FLAGS_DEBUG             "-g -ggdb -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 144   set(CMAKE_CXX_FLAGS_DEBUGFULL         "-g3 -ggdb -fno-inline")
 145   set(CMAKE_CXX_FLAGS_PROFILE           "-g3 -ggdb -fno-inline -ftest-coverage -fprofile-arcs")
 146
 147   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -W -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing -Wundef -Wcast-align -Wpointer-arith -Wformat-security -fno-check-new -fno-common")
 148
 149   check_cxx_compiler_flag(-Woverloaded-virtual CXX_W_OVERLOADED_VIRTUAL)
 150   if(CXX_W_OVERLOADED_VIRTUAL)
 151     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Woverloaded-virtual")
 152   endif()
 153
 154   # Just for miniz
 155   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-unused-function -Wno-undef -fno-strict-aliasing")
 156 endif(CMAKE_COMPILER_IS_GNUCXX)
 157
 158 # ... and for Clang
 159 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 160   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor -Wno-long-long -Wundef -Wcast-align -Wchar-subscripts -Wall -W -Wextra -Wpointer-arith -Wformat-security -Woverloaded-virtual -fno-common -Werror=return-type")
 161 #  set(CMAKE_CXX_FLAGS_RELEASE        "-O2 -DNDEBUG -DQT_NO_DEBUG")     # Use CMake default
 162 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g -DNDEBUG -DQT_NO_DEBUG")  # Use CMake default
 163   set(CMAKE_CXX_FLAGS_DEBUG          "-g -O2 -fno-inline")
 164   set(CMAKE_CXX_FLAGS_DEBUGFULL      "-g3 -fno-inline")
 165   set(CMAKE_CXX_FLAGS_PROFILE        "-g3 -fno-inline -ftest-coverage -fprofile-arcs")
 166
 167   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-unused-function -Wno-undef -fno-strict-aliasing")
 168 endif()
 169
 170 # Mac build stuff
 171 if(APPLE AND DEPLOY)
 172   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 173   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 174   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 175   add_definitions(-DMAC_10_6_SDK)
 176 endif(APPLE AND DEPLOY)
 177
 178 # Simplify checks
 179 if(WANT_MONO OR WANT_QTCLIENT)
 180   set(BUILD_GUI true)
 181 endif(WANT_MONO OR WANT_QTCLIENT)
 182 if(WANT_MONO OR WANT_CORE)
 183   set(BUILD_CORE true)
 184 endif(WANT_MONO OR WANT_CORE)
 185
 186
 187 # Version checks
 188 ################
 189
 190 if(WITH_QT5)
 191   set(QT_MIN_VERSION "5.0.0")
 192   add_definitions(-DHAVE_QT5)
 193
 194   # Qt5 needs a new enough cmake...
 195   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 196
 197   # ... for automoc
 198   set(CMAKE_AUTOMOC ON)
 199 else(WITH_QT5)
 200
 201   # GUI stuff needs some new features
 202   if(BUILD_GUI)
 203     set(QT_MIN_VERSION "4.6.0")
 204   else(BUILD_GUI)
 205     set(QT_MIN_VERSION "4.4.0")
 206   endif(BUILD_GUI)
 207 endif(WITH_QT5)
 208
 209
 210 # Dependencies
 211 ##############
 212
 213 if(WITH_QT5)
 214   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 215   # We need QtWidgets
 216   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 217
 218   # Setup the i18n-related variables
 219   find_package(Qt5LinguistTools)
 220
 221 else(WITH_QT5)
 222   # Select a Qt installation here, if you don't want to use system Qt
 223   if(QT)
 224     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 225     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 226   endif(QT)
 227
 228   # Now that we have the correct $PATH, lets find Qt!
 229   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 230 endif(WITH_QT5)
 231
 232
 233 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 234 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 235 if(QT_LRELEASE_EXECUTABLE)
 236   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 237   if(WITH_QT5)
 238     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 239   else(WITH_QT5)
 240     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 241   endif(WITH_QT5)
 242 endif(QT_LRELEASE_EXECUTABLE)
 243
 244
 245 # zlib for compression, however we can always fall back to miniz
 246 find_package(ZLIB)
 247 if(ZLIB_FOUND)
 248   message(STATUS "Using system zlib for compression")
 249   add_definitions(-DHAVE_ZLIB)
 250   include_directories(${ZLIB_INCLUDE_DIRS})
 251   set(COMMON_LIBRARIES ${COMMON_LIBRARIES} ${ZLIB_LIBRARIES})
 252 else()
 253   message(STATUS "zlib NOT found, using bundled miniz for compression")
 254   if(${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 255     message(STATUS "WARNING: This may be slow on 32 bit systems!")
 256   endif()
 257 endif()
 258
 259
 260 # Execinfo is needed for generating backtraces
 261 find_package(ExecInfo)
 262 if(EXECINFO_FOUND)
 263   add_definitions(-DHAVE_EXECINFO)
 264   include_directories(${EXECINFO_INCLUDES})
 265   link_libraries(${EXECINFO_LIBRARIES})
 266 endif(EXECINFO_FOUND)
 267
 268
 269 # PkgConfig isn't strictly required.
 270 # However, some optional deps might not be found if it's not present, so warn!
 271 find_package(PkgConfig)
 272 if(NOT PKG_CONFIG_FOUND)
 273   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 274   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 275 endif(NOT PKG_CONFIG_FOUND)
 276
 277
 278 # Setup OpenSSL
 279 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 280 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 281 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 282 if(WITH_OPENSSL)
 283   if(QT_QCONFIG MATCHES "openssl")
 284     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 285     add_definitions(-DHAVE_SSL)
 286     set(HAVE_SSL true)
 287   else(QT_QCONFIG MATCHES "openssl")
 288     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 289     add_definitions(-DQT_NO_OPENSSL)
 290   endif(QT_QCONFIG MATCHES "openssl")
 291 else(WITH_OPENSSL)
 292   message(STATUS "Not enabling OpenSSL support")
 293 endif(WITH_OPENSSL)
 294
 295
 296 # Check for GUI specific stuff
 297 if(BUILD_GUI)
 298
 299   # Setup D-Bus support
 300   if(WITH_DBUS)
 301     if(WITH_QT5)
 302       find_package(Qt5DBus ${QT_MIN_VERSION})
 303       find_package(Qt5DBusTools)
 304     endif(WITH_QT5)
 305
 306     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 307       message(STATUS "Found QtDBus, enabling D-Bus support")
 308       add_definitions(-DHAVE_DBUS)
 309       set(HAVE_DBUS true)
 310       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 311
 312       # check if we have dbusmenu as well
 313       if(NOT WITH_QT5)
 314         find_package(DBusMenuQt)
 315         if(DBUSMENUQT_FOUND)
 316           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 317           add_definitions(-DHAVE_DBUSMENU)
 318           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 319           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 320           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 321         else(DBUSMENUQT_FOUND)
 322           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 323         endif(DBUSMENUQT_FOUND)
 324       endif(NOT WITH_QT5)
 325
 326     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 327       message(STATUS "QtDBus not found, disabling D-Bus support")
 328     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 329   else(WITH_DBUS)
 330     message(STATUS "Not enabling D-Bus support")
 331   endif(WITH_DBUS)
 332
 333   # Setup QtWebkit support
 334   if(WITH_WEBKIT)
 335     if(WITH_QT5)
 336       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 337     endif(WITH_QT5)
 338     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 339       message(STATUS "Found QtWebKit, enabling WebKit support")
 340       add_definitions(-DHAVE_WEBKIT)
 341       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 342       set(HAVE_WEBKIT true)
 343     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 344       message(STATUS "QtWebkit not found, disabling Webkit support")
 345     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 346   else(WITH_WEBKIT)
 347     message(STATUS "Not enabling Webkit support")
 348   endif(WITH_WEBKIT)
 349
 350   # Setup KDE4 support
 351   if(WITH_KDE AND NOT WITH_QT5)
 352     # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 353     set(_cflags ${CMAKE_C_FLAGS})
 354     find_package(KDE4)
 355     if(KDE4_FOUND)
 356       message(STATUS "Enabling KDE4 integration")
 357       include_directories(${KDE4_INCLUDES})
 358       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 359       set(HAVE_KDE 1)
 360       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
 361       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 362       set(EMBED_DATA OFF)
 363       # Restore our old CFLAGS
 364       set(CMAKE_C_FLAGS ${_cflags})
 365     else(KDE4_FOUND)
 366       message(STATUS "KDE4 not found, disabling KDE integration")
 367     endif(KDE4_FOUND)
 368   else(WITH_KDE AND NOT WITH_QT5)
 369     message(STATUS "Not enabling KDE4 integration")
 370   endif(WITH_KDE AND NOT WITH_QT5)
 371
 372   # Setup Phonon support - we only need this if we don't have or want KDE4
 373   if(NOT HAVE_KDE)
 374     if(WITH_PHONON)
 375       if(WITH_QT5)
 376         find_package(Qt5phonon)
 377         if(Qt5phonon_FOUND)
 378           message(STATUS "Enabling Phonon support")
 379           add_definitions(-DHAVE_PHONON)
 380           set(HAVE_PHONON true)
 381           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 382         else(Qt5phonon_FOUND)
 383           message(STATUS "Phonon not found, disabling audio notifications")
 384         endif(Qt5phonon_FOUND)
 385       else(WITH_QT5)
 386         find_package(Phonon)
 387         if(PHONON_FOUND)
 388           message(STATUS "Enabling Phonon support")
 389           add_definitions(-DHAVE_PHONON)
 390           include_directories(${PHONON_INCLUDES})
 391           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 392           set(HAVE_PHONON true)
 393         else(PHONON_FOUND)
 394           message(STATUS "Phonon not found, disabling audio notifications")
 395         endif(PHONON_FOUND)
 396       endif(WITH_QT5)
 397     else(WITH_PHONON)
 398       message(STATUS "Not enabling Phonon support")
 399     endif(WITH_PHONON)
 400
 401     find_package(Libsnore)
 402     if(LIBSNORE_FOUND)
 403         add_definitions(-DHAVE_LIBSNORE)
 404         set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
 405         set(HAVE_SNORENOTIFY true)
 406     endif(LIBSNORE_FOUND)
 407   endif(NOT HAVE_KDE)
 408
 409   # Setup libindicate-qt support
 410   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 411     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 412     if(INDICATEQT_FOUND)
 413       message(STATUS "Enabling Ayatana notification support")
 414       set(HAVE_INDICATEQT true)
 415       add_definitions(-DHAVE_INDICATEQT)
 416       link_directories(${INDICATEQT_LIBRARY_DIRS})
 417       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 418     else(INDICATEQT_FOUND)
 419       message(STATUS "Disabling Ayatana notification support")
 420     endif(INDICATEQT_FOUND)
 421   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 422     message(STATUS "Not enabling Ayatana notification support")
 423     # We don't want to link against it even if another package has found it
 424     set(INDICATEQT_LIBRARIES "")
 425   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 426
 427   # Setup OS X notification center support
 428   if(WITH_NOTIFICATION_CENTER AND APPLE)
 429     set(HAVE_NOTIFICATION_CENTER true)
 430     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 431     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 432       /System/Library/Frameworks/Foundation.framework
 433     )
 434   endif()
 435 endif(BUILD_GUI)
 436
 437 # Core-only deps
 438 if(BUILD_CORE)
 439
 440   # Setup encryption support
 441   if(WITH_CRYPT AND NOT WITH_QT5)
 442     find_package(QCA2)
 443     if(QCA2_FOUND)
 444       message(STATUS "Enabling encryption support")
 445       add_definitions(-DHAVE_QCA2)
 446       set(LINK_QCA2 QCA2)
 447       set(HAVE_QCA2 true)
 448       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 449     else(QCA2_FOUND)
 450       message(STATUS "Disabling encryption support")
 451     endif(QCA2_FOUND)
 452   else(WITH_CRYPT AND NOT WITH_QT5)
 453     message(STATUS "Not enabling encryption support")
 454   endif(WITH_CRYPT AND NOT WITH_QT5)
 455
 456   # Setup syslog support
 457   if(WITH_SYSLOG)
 458     check_include_file(syslog.h HAVE_SYSLOG_H)
 459     if(HAVE_SYSLOG_H)
 460       message(STATUS "Enabling syslog support")
 461       set(HAVE_SYSLOG true)
 462       add_definitions(-DHAVE_SYSLOG)
 463     else(HAVE_SYSLOG_H)
 464       message(STATUS "Disabling syslog support")
 465     endif(HAVE_SYSLOG_H)
 466   else(WITH_SYSLOG)
 467     message(STATUS "Not enabling syslog support")
 468   endif(WITH_SYSLOG)
 469
 470 endif(BUILD_CORE)
 471
 472
 473 # Various settings
 474 ##################
 475
 476 # needed to compile with mingw without kde
 477 if(MINGW AND NOT HAVE_KDE)
 478     add_definitions(-D_WIN32_WINNT=0x0500)
 479     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 480 # workaround for bug in mingw gcc 4.0
 481     add_definitions(-U__STRICT_ANSI__)
 482 endif(MINGW AND NOT HAVE_KDE)
 483
 484 # Now set up install locations; those are set by KDE if integration is enabled
 485 if(NOT HAVE_KDE)
 486   if(WIN32)
 487     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 488     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 489     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 490     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 491   else(WIN32)
 492     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 493     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 494     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 495     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 496   endif(WIN32)
 497 endif(NOT HAVE_KDE)
 498
 499 if(EMBED_DATA)
 500   message(STATUS "Embedding data files into the binary")
 501 else(EMBED_DATA)
 502   message(STATUS "Installing data files separately")
 503 endif(EMBED_DATA)
 504
 505 # RPATH needs to be set correctly
 506 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 507 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 508 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 509
 510 # Set global buildflags
 511 # This is very much non-portable, so don't use -DSTATIC until you know what
 512 # you do.
 513 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 514   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 515   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 516   if(HAVE_SSL)
 517     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 518   endif(HAVE_SSL)
 519 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 520
 521 if(WIN32)
 522   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 523   if(MSVC)
 524     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 525     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 526     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 527     link_libraries(Version dwmapi shlwapi)
 528   endif(MSVC)
 529   if(HAVE_SSL AND STATIC)
 530      find_package(OpenSSL REQUIRED)
 531      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 532   endif(HAVE_SSL AND STATIC)
 533 endif(WIN32)
 534
 535 if(HAVE_INDICATEQT)
 536   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 537 endif(HAVE_INDICATEQT)
 538
 539 if(NOT WIN32)
 540   check_function_exists(umask HAVE_UMASK)
 541   if(HAVE_UMASK)
 542     add_definitions(-DHAVE_UMASK)
 543   endif(HAVE_UMASK)
 544 endif(NOT WIN32)
 545
 546 # We need to create a version.gen
 547 # For this, we create our genversion binary and make sure it is run every time.
 548
 549 setup_qt_variables()
 550 include_directories(${QUASSEL_QT_INCLUDES})
 551
 552 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 553 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 554 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 555
 556 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 557 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 558                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 559 add_dependencies(genversion_run genversion)
 560
 561 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 562 set(COMMON_DEPS ${RC_WIN32})
 563 set(CORE_DEPS )
 564 set(CLIENT_DEPS )
 565
 566 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 567 add_subdirectory(data)
 568 add_subdirectory(icons)
 569 add_subdirectory(pics)
 570 add_subdirectory(po)
 571 add_subdirectory(src)