CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 # You may pass various options to cmake:
   3 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   4 #                  : select binaries to build
   5 # -DQT=/path/to/qt : Choose a Qt4 installation to use instead of the system Qt4
   6 # -DSTATIC=ON      : Enable static building of Quassel. Use with care.
   7 # -DSPUTDEV=ON     : Do not use.
   8 # -DDEPLOY=ON      : Mac OS X only. Use only fore redistribution Quassel Packages!!
   9 #
  10 # NOTE: You need to remove CMakeCache.txt if you plan to change any of these values!
  11
  12 project(QuasselIRC)
  13
  14 # Target scopes don't work in older versions
  15 cmake_minimum_required(VERSION 2.4.7 FATAL_ERROR)
  16
  17 if(COMMAND cmake_policy)
  18    cmake_policy(SET CMP0003 OLD)  # suppress linker warnings
  19 endif(COMMAND cmake_policy)
  20
  21 # Use our own (well, KDE's) version of some modules
  22 # In particular cmake's FindQt4 and FindOpenSSL are quite buggy
  23 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  24
  25 # Various options and variables that can be set on the command line
  26 option(WANT_CORE     "Build the core (server) binary"           ON)
  27 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  28 option(WANT_MONO     "Build the monolithic (all-in-one) binary" OFF)
  29
  30 option(STATIC        "Enable static building (might not be portable)" OFF)
  31 option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  32 option(SPUTDEV       "Do not use!" OFF)
  33
  34 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt")
  35 set(LINGUAS "" CACHE STRING "Space-separated List of locales specifying languages that should be compiled")
  36
  37 if(STATIC)
  38   set(CMAKE_BUILD_TYPE Release)
  39 endif(STATIC)
  40
  41 # Enable various flags on gcc
  42 if(CMAKE_COMPILER_IS_GNUCXX)
  43   include(CheckCXXCompilerFlag)
  44   check_cxx_compiler_flag(-Wall HAVE_WALL)
  45   if(HAVE_WALL)
  46     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
  47   endif(HAVE_WALL)
  48   check_cxx_compiler_flag(-Wextra HAVE_WEXTRA)
  49   if(HAVE_WEXTRA)
  50     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wextra")
  51   endif(HAVE_WEXTRA)
  52   check_cxx_compiler_flag(-ansi HAVE_ANSI)
  53   if(HAVE_ANSI)
  54     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi")
  55   endif(HAVE_ANSI)
  56 endif(CMAKE_COMPILER_IS_GNUCXX)
  57
  58 set(QT_MIN_VERSION "4.3.0")
  59
  60 if(APPLE AND DEPLOY)
  61   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
  62   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
  63   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
  64 endif(APPLE AND DEPLOY)
  65
  66 # Enable mostly b0rked stuff (new ChatView), do not enable this unless you know what you do...
  67 if(SPUTDEV)
  68   add_definitions(-DSPUTDEV)
  69 endif(SPUTDEV)
  70
  71 # Set up OpenSSL
  72 find_package(OpenSSL)
  73 if(NOT OPENSSL_FOUND)
  74   add_definitions(-DQT_NO_OPENSSL)
  75 endif(NOT OPENSSL_FOUND)
  76
  77 # Select a Qt installation here, if you don't want to use system Qt
  78 if(QT)
  79   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
  80   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
  81 endif(QT)
  82
  83 # Now that we have the correct $PATH, lets find Qt!
  84 find_package(Qt4 REQUIRED)
  85
  86 set(QT_DONT_USE_QTGUI 1)
  87 include(${QT_USE_FILE})
  88 include_directories(${QT_INCLUDES})
  89
  90 # We need to create a version.gen
  91 # For this, we create our genversion binary and make sure it is run every time.
  92 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
  93 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
  94
  95 add_custom_target(genversion_run ALL ${CMAKE_BINARY_DIR}/genversion
  96                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/common/version.gen)
  97 add_dependencies(genversion_run genversion)
  98
  99 # Add needed subdirs
 100 add_subdirectory(src/common)
 101 include_directories(src/common)
 102 if(WANT_CORE OR WANT_MONO)
 103   add_subdirectory(src/core)
 104   include_directories(src/core)
 105 endif(WANT_CORE OR WANT_MONO)
 106 if(WANT_QTCLIENT OR WANT_MONO)
 107   add_subdirectory(src/client)
 108   add_subdirectory(src/uisupport)
 109   add_subdirectory(src/qtui)
 110   include_directories(src/client)
 111   include_directories(src/uisupport)
 112   include_directories(src/qtui)
 113 endif(WANT_QTCLIENT OR WANT_MONO)
 114
 115 # Make sure version.gen exists before building mod_common
 116 add_dependencies(mod_common genversion_run)
 117
 118 # Generate binary translation files
 119 include(QuasselGenerateTranslations)
 120 quassel_generate_i18n_resource(RC_I18N ${LINGUAS})
 121
 122 # Add resources
 123 qt4_add_resources(RC_ICONS src/icons/icons.qrc)
 124 qt4_add_resources(RC_QUASSEL_ICONS src/icons/quassel-icons.qrc)
 125 qt4_add_resources(RC_SQL src/core/sql.qrc)
 126
 127 # Set global buildflags
 128 # This is very much non-portable, so don't use -DSTATICGCC until you know what
 129 # you do.
 130 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 131   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 132   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 133   if(OPENSSL_FOUND)
 134     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 135   endif(OPENSSL_FOUND)
 136 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 137
 138 if(STATIC AND WIN32)
 139   link_libraries(imm32 winmm)  # missing by default :/
 140    if(OPENSSL_FOUND)
 141      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 142    endif(OPENSSL_FOUND)
 143 endif(STATIC AND WIN32)
 144
 145 if(WIN32)
 146   set(WIN32_RC src/icons/win32.rc)  # for app icons on windows
 147 endif(WIN32)
 148
 149 # Here comes the dirty part. Our targets need different Qt4 modules, i.e. different libs
 150 # and defines. We can't simply include UseQt4 several times, since definitions add up.
 151 # We workaround this by using our own macro to figure out what to add.
 152
 153 # This macro sets variables for additional Qt modules.
 154 macro(setup_qt4_variables)
 155   set(QUASSEL_QT_LIBRARIES )
 156   IF(WIN32)
 157     set(MAIN MAIN)
 158   ENDIF(WIN32)
 159   foreach(qtmod CORE ${ARGV} ${MAIN})
 160     set(QUASSEL_QT_LIBRARIES ${QUASSEL_QT_LIBRARIES} ${QT_QT${qtmod}_LIBRARY} ${QT_${qtmod}_LIB_DEPENDENCIES})
 161   endforeach(qtmod ${ARGV})
 162   set(QUASSEL_QT_LIBRARIES ${QUASSEL_QT_LIBRARIES} ${QT_LIBRARIES})
 163 endmacro(setup_qt4_variables)
 164
 165 # Now we have everything, so just glue the right pieces together :)
 166 if(WANT_CORE)
 167   setup_qt4_variables(NETWORK SCRIPT SQL)
 168   add_executable(quasselcore ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 169                              ${RC_SQL} ${RC_I18N} ${WIN32_RC})
 170   set_target_properties(quasselcore PROPERTIES
 171                                     COMPILE_FLAGS "-DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_CORE")
 172   target_link_libraries(quasselcore mod_core mod_common
 173                                     ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 174 endif(WANT_CORE)
 175
 176 if(WANT_QTCLIENT)
 177   setup_qt4_variables(GUI NETWORK)
 178   add_executable(quasselclient WIN32 ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 179                                      ${RC_ICONS} ${RC_QUASSEL_ICONS} ${RC_I18N} ${WIN32_RC})
 180   set_target_properties(quasselclient PROPERTIES
 181                                       COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DBUILD_QTUI")
 182   target_link_libraries(quasselclient mod_qtui mod_uisupport mod_client mod_common
 183                                       ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 184 endif(WANT_QTCLIENT)
 185
 186 if(WANT_MONO)
 187   setup_qt4_variables(GUI NETWORK SCRIPT SQL)
 188   add_executable(quassel WIN32 ${CMAKE_SOURCE_DIR}/src/common/main.cpp
 189                                ${RC_ICONS} ${RC_QUASSEL_ICONS} ${RC_SQL} ${RC_I18N} ${WIN32_RC})
 190   set_target_properties(quassel PROPERTIES
 191                                 COMPILE_FLAGS "-DQT_GUI_LIB -DQT_NETWORK_LIB -DQT_SCRIPT_LIB -DQT_SQL_LIB -DBUILD_MONO")
 192   target_link_libraries(quassel mod_qtui mod_uisupport mod_client mod_core mod_common
 193                                 ${QUASSEL_QT_LIBRARIES} ${QUASSEL_SSL_LIBRARIES})
 194 endif(WANT_MONO)
 195
 196 # Build bundles for MacOSX
 197 if(APPLE)
 198   add_custom_command(TARGET quasselclient POST_BUILD
 199                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
 200                              ${CMAKE_SOURCE_DIR} "Quassel Client" quasselclient)
 201   add_custom_command(TARGET quassel POST_BUILD
 202                      COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
 203                              ${CMAKE_SOURCE_DIR} "Quassel" quassel)
 204   if(DEPLOY)
 205     add_custom_command(TARGET quasselclient POST_BUILD
 206                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Client)
 207     add_custom_command(TARGET quasselcore POST_BUILD
 208                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Core)
 209   endif(DEPLOY)
 210 endif(APPLE)
 211
 212 # Install rules
 213 if(WANT_CORE)
 214   install(TARGETS quasselcore
 215           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 216 endif(WANT_CORE)
 217
 218 if(WANT_QTCLIENT)
 219   install(TARGETS quasselclient
 220           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 221
 222   install(FILES quasselclient.desktop
 223           DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications)
 224 endif(WANT_QTCLIENT)
 225
 226 if(WANT_MONO)
 227   install(TARGETS quassel
 228           RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
 229
 230   install(FILES quassel.desktop
 231           DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications)
 232 endif(WANT_MONO)