CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 12)
  14 set(QUASSEL_PATCH  5)
  15 set(QUASSEL_VERSION_STRING "0.12.5")
  16
  17 # Output CMake version and build type for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19 message(STATUS "CMake build type: ${CMAKE_BUILD_TYPE}")
  20
  21 # Tell CMake about or own modules
  22 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  23
  24 # General conveniences
  25 set(CMAKE_AUTOMOC ON)
  26 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  27
  28 # Include various CMake modules...
  29 include(CMakePushCheckState)
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32 include(CheckCXXSourceCompiles)
  33 include(CMakeDependentOption)
  34 include(FeatureSummary)
  35
  36 # ... and our own stuff
  37 include(QuasselCompileSettings)
  38 include(QuasselMacros)
  39
  40
  41 # Options and variables that can be set on the command line
  42 #####################################################################
  43
  44 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  45 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  46 if (USE_QT4) # takes precedence
  47     set(USE_QT5 OFF)
  48 else()
  49     if (NOT USE_QT5)
  50         set(USE_QT4 ON)
  51     endif()
  52 endif()
  53
  54 # Select the binaries to build
  55 option(WANT_CORE     "Build the core (server) binary"           ON)
  56 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  57 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  58 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  59 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  60 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  61
  62 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  63 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  64 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  65 # is disabled.
  66 if (USE_QT4)
  67     option(WITH_KDE "KDE4 integration" OFF)
  68     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  69 else()
  70     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  71     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  72 endif()
  73
  74 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  75 if (NOT WITH_KDE)
  76     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  77 endif()
  78
  79 # For this, the feature info is added after we know if QtWebkit is installed
  80 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  81
  82 # For this, the feature info is added after we know if QtWebEngine is installed
  83 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  84
  85 if (APPLE)
  86     # Notification Center is only available in > 10.8, which is Darwin v12
  87     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
  88         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  89         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  90     endif()
  91     find_library(CARBON_LIBRARY Carbon)
  92     mark_as_advanced(CARBON_LIBRARY)
  93     link_libraries(${CARBON_LIBRARY})
  94 endif()
  95
  96 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  97 set(EMBED_DEFAULT OFF)
  98 if (STATIC OR WIN32 OR APPLE)
  99     set(EMBED_DEFAULT ON)
 100 endif()
 101 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 102                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 103 if (NOT EMBED_DEFAULT)
 104     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 105 endif()
 106
 107 # The following options are not for end-user consumption, so don't list them in the feature summary
 108 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 109
 110 # Handle with care
 111 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 112
 113 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 114 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 115
 116 # For static builds, arbitrary extra libs might need to be linked
 117 # Define a comma-separated list here
 118 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 119 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 120 if (LINK_EXTRA)
 121     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 122     link_libraries(${LINK_EXTRA})
 123 endif()
 124
 125
 126 # Setup CMake
 127 #####################################################################
 128
 129 if (USE_QT5 AND WITH_KDE)
 130     cmake_minimum_required(VERSION 2.8.12)
 131 else()
 132     cmake_minimum_required(VERSION 2.8.9)
 133 endif()
 134
 135 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 136 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 137 if (POLICY CMP0043)
 138     cmake_policy(SET CMP0043 OLD)
 139 endif()
 140
 141 # Honor visibility settings for all target types
 142 if (POLICY CMP0063)
 143     cmake_policy(SET CMP0063 NEW)
 144 endif()
 145
 146 # Don't automoc generated files
 147 if (POLICY CMP0071)
 148     cmake_policy(SET CMP0071 OLD)
 149 endif()
 150
 151
 152 # Simplify later checks
 153 #####################################################################
 154
 155 if (WANT_MONO OR WANT_QTCLIENT)
 156     set(BUILD_GUI true)
 157 endif()
 158 if (WANT_MONO OR WANT_CORE)
 159     set(BUILD_CORE true)
 160 endif()
 161
 162
 163 # Set up Qt
 164 #####################################################################
 165
 166 # Find package dependencies
 167 #
 168 # Note that you can forcefully disable optional packages
 169 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 170 #####################################################################
 171
 172 if (USE_QT5)
 173     message(STATUS "Building for Qt5...")
 174     set(QT_MIN_VERSION "5.2.0")
 175     add_definitions(-DHAVE_QT5)
 176
 177     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 178     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 179         URL "http://qt.digia.com"
 180         DESCRIPTION "contains core functionality for Qt"
 181     )
 182     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 183     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 184     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 185         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 186     endif()
 187
 188     find_package(Qt5Network QUIET)
 189     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 190         DESCRIPTION "the network module for Qt5"
 191     )
 192
 193     if (BUILD_GUI)
 194         find_package(Qt5Gui QUIET)
 195         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 196             DESCRIPTION "the GUI module for Qt5"
 197         )
 198         find_package(Qt5Widgets QUIET)
 199         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 200             DESCRIPTION "the widgets module for Qt5"
 201         )
 202
 203         if (NOT WIN32)
 204             find_package(Qt5DBus QUIET)
 205             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 206                 URL "http://qt.digia.com"
 207                 DESCRIPTION "D-Bus support for Qt5"
 208                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 209             )
 210             if (Qt5DBus_FOUND)
 211                 find_package(dbusmenu-qt5 QUIET CONFIG)
 212                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 213                     URL "https://launchpad.net/libdbusmenu-qt"
 214                     DESCRIPTION "a library implementing the DBusMenu specification"
 215                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 216                 )
 217             endif()
 218         endif()
 219
 220         find_package(Phonon4Qt5 QUIET)
 221         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 222             URL "https://projects.kde.org/projects/kdesupport/phonon"
 223             DESCRIPTION "a multimedia abstraction library"
 224             PURPOSE     "Required for audio notifications"
 225         )
 226
 227         find_package(LibsnoreQt5 0.7.0 QUIET)
 228         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 229             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 230             DESCRIPTION "a cross-platform notification framework"
 231             PURPOSE     "Enable support for the snorenotify framework"
 232         )
 233         if(LibsnoreQt5_FOUND)
 234             find_package(LibsnoreSettingsQt5)
 235             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 236                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 237                 DESCRIPTION "a cross-platform notification framework"
 238                 PURPOSE     "Enable support for the snorenotify framework"
 239             )
 240         endif()
 241
 242
 243         if (WITH_WEBKIT)
 244             find_package(Qt5WebKit QUIET)
 245             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 246                 URL "http://qt.digia.com"
 247                 DESCRIPTION "a WebKit implementation for Qt"
 248                 PURPOSE     "Needed for displaying previews for URLs in chat"
 249             )
 250             if (Qt5WebKit_FOUND)
 251                 find_package(Qt5WebKitWidgets QUIET)
 252                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 253                     URL "http://qt.digia.com"
 254                     DESCRIPTION "widgets for Qt's WebKit implementation"
 255                     PURPOSE     "Needed for displaying previews for URLs in chat"
 256                 )
 257             endif()
 258         endif()
 259
 260         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 261             set(HAVE_WEBKIT true)
 262         endif()
 263         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 264
 265         if (WITH_WEBENGINE)
 266             find_package(Qt5WebEngine QUIET)
 267             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 268                 URL "http://qt.digia.com"
 269                 DESCRIPTION "a WebEngine implementation for Qt"
 270                 PURPOSE     "Needed for displaying previews for URLs in chat"
 271             )
 272             if (Qt5WebEngine_FOUND)
 273                 find_package(Qt5WebEngineWidgets QUIET)
 274                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 275                     URL "http://qt.digia.com"
 276                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 277                     PURPOSE     "Needed for displaying previews for URLs in chat"
 278                 )
 279             endif()
 280         endif()
 281
 282         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 283             set(HAVE_WEBENGINE true)
 284         endif()
 285         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 286
 287         # KDE Frameworks
 288         ################
 289
 290         if (WITH_KDE)
 291             set(ecm_find_type "REQUIRED")
 292         else()
 293             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 294             set(ecm_find_type "RECOMMENDED")
 295         endif()
 296
 297         # extra-cmake-modules
 298         find_package(ECM NO_MODULE QUIET)
 299         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 300             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 301             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 302             PURPOSE     "Required to find KDE Frameworks components"
 303         )
 304
 305         if (ECM_FOUND)
 306             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 307         endif()
 308
 309         if (WITH_KDE)
 310             find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 311             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 312                 URL "http://www.kde.org"
 313                 DESCRIPTION "KDE Frameworks"
 314                 PURPOSE     "Required for integration into the Plasma desktop"
 315             )
 316
 317         endif()
 318
 319     endif(BUILD_GUI)
 320
 321     if (BUILD_CORE)
 322         find_package(Qt5Script QUIET)
 323         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 324             DESCRIPTION "provides scripting support for Qt5"
 325         )
 326         find_package(Qt5Sql QUIET)
 327         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 328             DESCRIPTION "the database support module for Qt5"
 329         )
 330
 331         find_package(QCA2-QT5)
 332         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 333             URL "https://projects.kde.org/projects/kdesupport/qca"
 334             DESCRIPTION "Qt Cryptographic Architecture"
 335             PURPOSE "Required for encryption support"
 336         )
 337
 338     endif(BUILD_CORE)
 339
 340     find_package(Qt5LinguistTools QUIET)
 341     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 342                            DESCRIPTION "contains tools for handling translation files"
 343                            PURPOSE "Required for having translations"
 344     )
 345
 346     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 347     if (Qt5LinguistTools_FOUND)
 348         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 349             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 350             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 351             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 352         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 353             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 354             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 355         endif()
 356
 357         # Compatibility with the Qt4 variables
 358         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 359         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 360         if (Qt5_LCONVERT_EXECUTABLE)
 361             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 362         endif()
 363     endif()
 364
 365 else(USE_QT5)
 366     message(STATUS "Building for Qt4...")
 367     set(QT_MIN_VERSION "4.8.0")
 368
 369     # Select a Qt installation here, if you don't want to use system Qt
 370     if(QT_PATH)
 371         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 372         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 373     endif()
 374
 375     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 376
 377     if (BUILD_GUI)
 378         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 379         if (QT_QTDBUS_FOUND)
 380             find_package(dbusmenu-qt QUIET CONFIG)
 381             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 382                 URL "https://launchpad.net/libdbusmenu-qt"
 383                 DESCRIPTION "a library implementing the DBusMenu specification"
 384                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 385             )
 386         endif()
 387
 388         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 389             set(HAVE_WEBKIT true)
 390         endif()
 391         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 392
 393         if (WITH_KDE)
 394             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 395             set(_cflags ${CMAKE_C_FLAGS})
 396             find_package(KDE4 4.4 QUIET)
 397             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 398                 URL "http://www.kde.org"
 399                 DESCRIPTION "a world-class desktop environment"
 400                 PURPOSE "Enables various bits for improving integration with KDE"
 401             )
 402             set(CMAKE_C_FLAGS ${_cflags})
 403
 404         else(WITH_KDE)
 405             find_package(Phonon QUIET)
 406             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 407                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 408                 DESCRIPTION "a multimedia abstraction library"
 409                 PURPOSE     "Required for audio notifications"
 410             )
 411         endif(WITH_KDE)
 412
 413         find_package(IndicateQt QUIET)
 414         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 415             URL "https://launchpad.net/libindicate-qt/"
 416             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 417             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 418         )
 419
 420     endif(BUILD_GUI)
 421
 422     if (BUILD_CORE)
 423
 424         find_package(QCA2 QUIET)
 425         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 426             URL "https://projects.kde.org/projects/kdesupport/qca"
 427             DESCRIPTION "Qt Cryptographic Architecture"
 428             PURPOSE     "Required for encryption support"
 429         )
 430
 431
 432     endif()
 433
 434     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 435     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 436     if (QT_LRELEASE_EXECUTABLE)
 437         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 438         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 439     endif()
 440 endif()
 441
 442
 443 # Non-Qt-based packages
 444
 445 # zlib for compression, however we can always fall back to miniz
 446 find_package(ZLIB QUIET)
 447 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 448     URL "http://www.zlib.net"
 449     DESCRIPTION "a popular compression library"
 450     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 451 )
 452
 453
 454 if (NOT WIN32)
 455     # Execinfo is needed for generating backtraces
 456     find_package(ExecInfo QUIET)
 457     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 458         DESCRIPTION "a library for inspecting backtraces"
 459         PURPOSE "Used for generating backtraces in case of a crash"
 460     )
 461 endif()
 462
 463 # Check for SSL support in Qt
 464 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 465 # a small test program checking the defines. This works for both Qt4 and Qt5.
 466 cmake_push_check_state(RESET)
 467 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 468 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 469
 470 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 471     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 472 endif()
 473
 474 check_cxx_source_compiles("
 475     #include \"qglobal.h\"
 476     #if defined QT_NO_SSL
 477     #  error \"No SSL support\"
 478     #endif
 479     int main() {}"
 480     HAVE_SSL)
 481 cmake_pop_check_state()
 482
 483 # Additional compile settings
 484 #####################################################################
 485
 486 # This sets -fPIC and friends if required by the installed Qt5 library
 487 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 488     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 489 endif()
 490
 491 # Needed to compile with mingw without kde
 492 if (MINGW AND NOT KDE4_FOUND)
 493     add_definitions(-D_WIN32_WINNT=0x0500)
 494     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 495     # workaround for bug in mingw gcc 4.0
 496     add_definitions(-U__STRICT_ANSI__)
 497 endif()
 498
 499 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 500 if (CMAKE_COMPILER_IS_GNUCXX)
 501     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 502 endif()
 503
 504
 505 # Setup KDE / KDE Frameworks
 506 #####################################################################
 507
 508 # We want to do this up here, so we have the necessary variables and defines set before
 509 # compiling anything
 510
 511 if (KDE4_FOUND)
 512     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 513     set(EMBED_DATA OFF)
 514
 515     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 516     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 517     set(WITH_KDE4 TRUE)
 518 endif()
 519
 520 if (USE_QT5 AND WITH_KDE)
 521     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 522     set(EMBED_DATA OFF)
 523
 524     include(KDEInstallDirs)
 525     include(KDECompilerSettings)
 526     include(KDECMakeSettings)
 527
 528     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 529     set(WITH_KF5 TRUE)
 530 endif()
 531
 532 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 533 include(QuasselInstallDirs)
 534
 535 # Various config-dependent checks and settings
 536 #####################################################################
 537
 538 if (NOT ZLIB_FOUND)
 539     message(STATUS "zlib NOT found, using bundled miniz for compression")
 540     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 541         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 542     endif()
 543 endif()
 544
 545 if (HAVE_SSL)
 546     add_definitions(-DHAVE_SSL)
 547 endif()
 548 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 549
 550 # Check for syslog support
 551 if (NOT WIN32)
 552     check_include_file(syslog.h HAVE_SYSLOG)
 553     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 554 endif()
 555
 556 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 557
 558 if (EMBED_DATA)
 559     message(STATUS "Embedding data files into the binary")
 560 else()
 561     message(STATUS "Installing data files separately")
 562 endif()
 563
 564 if (INDICATEQT_FOUND)
 565     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 566 endif()
 567
 568 if (NOT WIN32)
 569     check_function_exists(umask HAVE_UMASK)
 570     if(HAVE_UMASK)
 571         add_definitions(-DHAVE_UMASK)
 572     endif(HAVE_UMASK)
 573 endif()
 574
 575
 576 # Windows-specific stuff
 577 #####################################################################
 578
 579 if (WIN32)
 580     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 581     if (MSVC)
 582         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 583         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 584         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 585         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 586         link_libraries(Version dwmapi shlwapi)
 587         if (USE_QT5)
 588             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 589         endif()
 590     endif()
 591     if(HAVE_SSL AND STATIC)
 592         find_package(OpenSSL REQUIRED)
 593         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 594     endif()
 595 endif()
 596
 597
 598 # Static builds (very much non-portable, so don't use -DSTATIC
 599 # unless you know what you do!)
 600 #####################################################################
 601
 602 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 603     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 604     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 605     if (HAVE_SSL)
 606         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 607     endif()
 608 endif()
 609
 610
 611 # Generate version information from Git
 612 #####################################################################
 613
 614 include(GetGitRevisionDescription)
 615 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 616 git_describe(GIT_DESCRIBE --long)
 617
 618 # If in a Git repo we can get the commit-date from a git command
 619 if (GIT_HEAD)
 620     execute_process(
 621         COMMAND git -c log.showsignature=false show -s --format=%ct
 622         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 623         OUTPUT_VARIABLE GIT_COMMIT_DATE
 624         OUTPUT_STRIP_TRAILING_WHITESPACE
 625     )
 626 endif()
 627
 628 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 629 # enviroment
 630 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 631   if (DEFINED ENV{GIT_HEAD})
 632       set(GIT_HEAD $ENV{GIT_HEAD})
 633   endif ()
 634   if (DEFINED ENV{GIT_DESCRIBE})
 635      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 636   endif()
 637 endif()
 638
 639 # Sanitize things if we're not in a Git repo
 640 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 641     set(GIT_HEAD "")
 642     set(GIT_DESCRIBE "")
 643     set(GIT_COMMIT_DATE 0)
 644 endif()
 645
 646 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 647
 648 # Prepare the build
 649 #####################################################################
 650
 651 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 652 set(COMMON_DEPS ${RC_WIN32})
 653 set(CORE_DEPS )
 654 set(CLIENT_DEPS )
 655
 656 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 657 add_subdirectory(data)
 658 add_subdirectory(icons)
 659 add_subdirectory(pics)
 660 add_subdirectory(po)
 661
 662
 663 # Set up and display feature summary
 664 #####################################################################
 665
 666 feature_summary(WHAT ALL
 667                 INCLUDE_QUIET_PACKAGES
 668                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 669 )
 670
 671 # Finally, compile the sources
 672 # We want this after displaying the feature summary to avoid ugly
 673 # CMake backtraces in case a required Qt5 module is missing
 674 #####################################################################
 675
 676 add_subdirectory(src)