CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 12)
  14 set(QUASSEL_PATCH  2)
  15 set(QUASSEL_VERSION_STRING "0.12.2")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  44 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  45 if (USE_QT4) # takes precedence
  46     set(USE_QT5 OFF)
  47 else()
  48     if (NOT USE_QT5)
  49         set(USE_QT4 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 if (NOT WITH_KDE)
  75     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  76 endif()
  77
  78 # For this, the feature info is added after we know if QtWebkit is installed
  79 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  80
  81 if (APPLE)
  82     # Notification Center is only available in > 10.8, which is Darwin v12
  83     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  84         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  85         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  86     endif()
  87 endif()
  88
  89 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  90 set(EMBED_DEFAULT OFF)
  91 if (STATIC OR WIN32 OR APPLE)
  92     set(EMBED_DEFAULT ON)
  93 endif()
  94 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  95                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  96 if (NOT EMBED_DEFAULT)
  97     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  98 endif()
  99
 100 # The following options are not for end-user consumption, so don't list them in the feature summary
 101 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 102
 103 # Handle with care
 104 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 105
 106 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 107 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 108
 109 # For static builds, arbitrary extra libs might need to be linked
 110 # Define a comma-separated list here
 111 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 112 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 113 if (LINK_EXTRA)
 114     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 115     link_libraries(${LINK_EXTRA})
 116 endif()
 117
 118
 119 # Setup CMake
 120 #####################################################################
 121
 122 if (USE_QT5 AND WITH_KDE)
 123     cmake_minimum_required(VERSION 2.8.12)
 124 else()
 125     cmake_minimum_required(VERSION 2.8.9)
 126 endif()
 127
 128 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 129 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 130 if (CMAKE_MAJOR_VERSION GREATER 2)
 131     cmake_policy(SET CMP0043 OLD)
 132 endif()
 133
 134
 135 # Simplify later checks
 136 #####################################################################
 137
 138 if (WANT_MONO OR WANT_QTCLIENT)
 139     set(BUILD_GUI true)
 140 endif()
 141 if (WANT_MONO OR WANT_CORE)
 142     set(BUILD_CORE true)
 143 endif()
 144
 145
 146 # Set up Qt
 147 #####################################################################
 148
 149 if (USE_QT5)
 150     message(STATUS "Building for Qt5...")
 151     set(QT_MIN_VERSION "5.2.0")
 152     add_definitions(-DHAVE_QT5)
 153 else()
 154     message(STATUS "Building for Qt4...")
 155     set(QT_MIN_VERSION "4.8.0")
 156
 157     # Select a Qt installation here, if you don't want to use system Qt
 158     if(QT_PATH)
 159         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 160         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 161     endif()
 162 endif()
 163
 164
 165 # Find package dependencies
 166 #
 167 # Note that you can forcefully disable optional packages
 168 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 169 #####################################################################
 170
 171 if (USE_QT5)
 172     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 173     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 174         URL "http://qt.digia.com"
 175         DESCRIPTION "contains core functionality for Qt"
 176     )
 177     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 178     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 179     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 180         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 181     endif()
 182
 183     find_package(Qt5Network QUIET)
 184     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 185         DESCRIPTION "the network module for Qt5"
 186     )
 187
 188     if (BUILD_GUI)
 189         find_package(Qt5Gui QUIET)
 190         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 191             DESCRIPTION "the GUI module for Qt5"
 192         )
 193         find_package(Qt5Widgets QUIET)
 194         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 195             DESCRIPTION "the widgets module for Qt5"
 196         )
 197
 198         find_package(Qt5DBus QUIET)
 199         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 200             URL "http://qt.digia.com"
 201             DESCRIPTION "D-Bus support for Qt5"
 202             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 203         )
 204         if (Qt5DBus_FOUND)
 205             find_package(dbusmenu-qt5 QUIET CONFIG)
 206             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 207                 URL "https://launchpad.net/libdbusmenu-qt"
 208                 DESCRIPTION "a library implementing the DBusMenu specification"
 209                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 210             )
 211         endif()
 212
 213         find_package(Phonon4Qt5 QUIET)
 214         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 215             URL "https://projects.kde.org/projects/kdesupport/phonon"
 216             DESCRIPTION "a multimedia abstraction library"
 217             PURPOSE     "Required for audio notifications"
 218         )
 219
 220         find_package(LibsnoreQt5 QUIET)
 221         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 222             URL "https://github.com/TheOneRing/Snorenotify"
 223             DESCRIPTION "a cross-platform notification framework"
 224             PURPOSE     "Enable support for the snorenotify framework"
 225         )
 226
 227         if (WITH_WEBKIT)
 228             find_package(Qt5WebKit QUIET)
 229             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 230                 URL "http://qt.digia.com"
 231                 DESCRIPTION "a WebKit implementation for Qt"
 232                 PURPOSE     "Needed for displaying previews for URLs in chat"
 233             )
 234             if (Qt5WebKit_FOUND)
 235                 find_package(Qt5WebKitWidgets QUIET)
 236                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 237                     URL "http://qt.digia.com"
 238                     DESCRIPTION "widgets for Qt's WebKit implementation"
 239                     PURPOSE     "Needed for displaying previews for URLs in chat"
 240                 )
 241             endif()
 242         endif()
 243
 244         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 245             set(HAVE_WEBKIT true)
 246         endif()
 247         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat")
 248
 249         # KDE Frameworks
 250         ################
 251
 252         if (WITH_KDE)
 253             set(ecm_find_type "REQUIRED")
 254         else()
 255             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 256             set(ecm_find_type "RECOMMENDED")
 257         endif()
 258
 259         # extra-cmake-modules
 260         find_package(ECM NO_MODULE QUIET)
 261         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 262             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 263             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 264             PURPOSE     "Required to find KDE Frameworks components"
 265         )
 266
 267         if (ECM_FOUND)
 268             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 269         endif()
 270
 271         if (WITH_KDE)
 272             find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 273             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 274                 URL "http://www.kde.org"
 275                 DESCRIPTION "KDE Frameworks"
 276                 PURPOSE     "Required for integration into the Plasma desktop"
 277             )
 278
 279         endif()
 280
 281     endif(BUILD_GUI)
 282
 283     if (BUILD_CORE)
 284         find_package(Qt5Script QUIET)
 285         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 286             DESCRIPTION "provides scripting support for Qt5"
 287         )
 288         find_package(Qt5Sql QUIET)
 289         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 290             DESCRIPTION "the database support module for Qt5"
 291         )
 292
 293         find_package(QCA2-QT5)
 294         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 295             URL "https://projects.kde.org/projects/kdesupport/qca"
 296             DESCRIPTION "Qt Cryptographic Architecture"
 297             PURPOSE "Required for encryption support"
 298         )
 299
 300     endif(BUILD_CORE)
 301
 302     find_package(Qt5LinguistTools QUIET)
 303     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 304                            DESCRIPTION "contains tools for handling translation files"
 305                            PURPOSE "Required for having translations"
 306     )
 307
 308     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 309     if (Qt5LinguistTools_FOUND)
 310         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 311             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 312             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 313             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 314         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 315             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 316             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 317         endif()
 318
 319         # Compatibility with the Qt4 variables
 320         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 321         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 322         if (Qt5_LCONVERT_EXECUTABLE)
 323             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 324         endif()
 325     endif()
 326
 327 else(USE_QT5)
 328     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 329
 330     if (BUILD_GUI)
 331         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 332         if (QT_QTDBUS_FOUND)
 333             find_package(dbusmenu-qt QUIET CONFIG)
 334             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 335                 URL "https://launchpad.net/libdbusmenu-qt"
 336                 DESCRIPTION "a library implementing the DBusMenu specification"
 337                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 338             )
 339         endif()
 340
 341         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 342             set(HAVE_WEBKIT true)
 343         endif()
 344         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 345
 346         if (WITH_KDE)
 347             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 348             set(_cflags ${CMAKE_C_FLAGS})
 349             find_package(KDE4 4.4 QUIET)
 350             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 351                 URL "http://www.kde.org"
 352                 DESCRIPTION "a world-class desktop environment"
 353                 PURPOSE "Enables various bits for improving integration with KDE"
 354             )
 355             set(CMAKE_C_FLAGS ${_cflags})
 356
 357         else(WITH_KDE)
 358             find_package(Phonon QUIET)
 359             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 360                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 361                 DESCRIPTION "a multimedia abstraction library"
 362                 PURPOSE     "Required for audio notifications"
 363             )
 364
 365             find_package(Libsnore QUIET)
 366             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 367                 URL "https://github.com/TheOneRing/Snorenotify"
 368                 DESCRIPTION "a cross-platform notification framework"
 369                 PURPOSE     "Enable support for the snorenotify framework"
 370             )
 371         endif(WITH_KDE)
 372
 373         find_package(IndicateQt QUIET)
 374         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 375             URL "https://launchpad.net/libindicate-qt/"
 376             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 377             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 378         )
 379
 380     endif(BUILD_GUI)
 381
 382     if (BUILD_CORE)
 383
 384         find_package(QCA2 QUIET)
 385         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 386             URL "https://projects.kde.org/projects/kdesupport/qca"
 387             DESCRIPTION "Qt Cryptographic Architecture"
 388             PURPOSE     "Required for encryption support"
 389         )
 390
 391
 392     endif()
 393
 394     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 395     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 396     if (QT_LRELEASE_EXECUTABLE)
 397         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 398         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 399     endif()
 400 endif()
 401
 402
 403 # Non-Qt-based packages
 404
 405 # zlib for compression, however we can always fall back to miniz
 406 find_package(ZLIB QUIET)
 407 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 408     URL "http://www.zlib.net"
 409     DESCRIPTION "a popular compression library"
 410     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 411 )
 412
 413
 414 if (NOT WIN32)
 415     # Execinfo is needed for generating backtraces
 416     find_package(ExecInfo QUIET)
 417     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 418         DESCRIPTION "a library for inspecting backtraces"
 419         PURPOSE "Used for generating backtraces in case of a crash"
 420     )
 421 endif()
 422
 423 # Check for SSL support in Qt
 424 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 425 # a small test program checking the defines. This works for both Qt4 and Qt5.
 426 cmake_push_check_state(RESET)
 427 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 428 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 429 check_cxx_source_compiles("
 430     #include \"qglobal.h\"
 431     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 432     #  error \"No SSL support\"
 433     #endif
 434     int main() {}"
 435     HAVE_SSL)
 436 cmake_pop_check_state()
 437
 438 # Additional compile settings
 439 #####################################################################
 440
 441 # This sets -fPIC and friends if required by the installed Qt5 library
 442 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 443     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 444 endif()
 445
 446 # Needed to compile with mingw without kde
 447 if (MINGW AND NOT KDE4_FOUND)
 448     add_definitions(-D_WIN32_WINNT=0x0500)
 449     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 450     # workaround for bug in mingw gcc 4.0
 451     add_definitions(-U__STRICT_ANSI__)
 452 endif()
 453
 454 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 455 if (CMAKE_COMPILER_IS_GNUCXX)
 456     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 457 endif()
 458
 459
 460 # Setup KDE / KDE Frameworks
 461 #####################################################################
 462
 463 # We want to do this up here, so we have the necessary variables and defines set before
 464 # compiling anything
 465
 466 if (KDE4_FOUND)
 467     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 468     set(EMBED_DATA OFF)
 469
 470     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 471     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 472     set(WITH_KDE4 TRUE)
 473 endif()
 474
 475 if (USE_QT5 AND WITH_KDE)
 476     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 477     set(EMBED_DATA OFF)
 478
 479     include(KDEInstallDirs)
 480     include(KDECompilerSettings)
 481     include(KDECMakeSettings)
 482
 483     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 484     set(WITH_KF5 TRUE)
 485 endif()
 486
 487 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 488 include(QuasselInstallDirs)
 489
 490 # Various config-dependent checks and settings
 491 #####################################################################
 492
 493 if (NOT ZLIB_FOUND)
 494     message(STATUS "zlib NOT found, using bundled miniz for compression")
 495     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 496         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 497     endif()
 498 endif()
 499
 500 if (HAVE_SSL)
 501     add_definitions(-DHAVE_SSL)
 502 endif()
 503 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 504
 505 # Check for syslog support
 506 if (NOT WIN32)
 507     check_include_file(syslog.h HAVE_SYSLOG)
 508     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 509 endif()
 510
 511 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 512
 513 if (EMBED_DATA)
 514     message(STATUS "Embedding data files into the binary")
 515 else()
 516     message(STATUS "Installing data files separately")
 517 endif()
 518
 519 if (INDICATEQT_FOUND)
 520     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 521 endif()
 522
 523 if (NOT WIN32)
 524     check_function_exists(umask HAVE_UMASK)
 525     if(HAVE_UMASK)
 526         add_definitions(-DHAVE_UMASK)
 527     endif(HAVE_UMASK)
 528 endif()
 529
 530
 531 # Windows-specific stuff
 532 #####################################################################
 533
 534 if (WIN32)
 535     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 536     if (MSVC)
 537         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 538         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 539         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 540         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 541         link_libraries(Version dwmapi shlwapi)
 542         if (USE_QT5)
 543             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 544         endif()
 545     endif()
 546     if(HAVE_SSL AND STATIC)
 547         find_package(OpenSSL REQUIRED)
 548         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 549     endif()
 550 endif()
 551
 552
 553 # Static builds (very much non-portable, so don't use -DSTATIC
 554 # unless you know what you do!)
 555 #####################################################################
 556
 557 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 558     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 559     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 560     if (HAVE_SSL)
 561         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 562     endif()
 563 endif()
 564
 565
 566 # Generate version information from Git
 567 #####################################################################
 568
 569 include(GetGitRevisionDescription)
 570 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 571 git_describe(GIT_DESCRIBE --long)
 572
 573 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 574 # enviroment
 575 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 576   if (DEFINED ENV{GIT_HEAD})
 577       set(GIT_HEAD $ENV{GIT_HEAD})
 578   endif ()
 579   if (DEFINED ENV{GIT_DESCRIBE})
 580      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 581   endif()
 582 endif()
 583
 584 # Sanitize things if we're not in a Git repo
 585 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 586     set(GIT_HEAD "")
 587     set(GIT_DESCRIBE "")
 588 endif()
 589
 590 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 591
 592 # Prepare the build
 593 #####################################################################
 594
 595 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 596 set(COMMON_DEPS ${RC_WIN32})
 597 set(CORE_DEPS )
 598 set(CLIENT_DEPS )
 599
 600 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 601 add_subdirectory(data)
 602 add_subdirectory(icons)
 603 add_subdirectory(pics)
 604 add_subdirectory(po)
 605
 606
 607 # Set up and display feature summary
 608 #####################################################################
 609
 610 feature_summary(WHAT ALL
 611                 INCLUDE_QUIET_PACKAGES
 612                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 613 )
 614
 615 # Finally, compile the sources
 616 # We want this after displaying the feature summary to avoid ugly
 617 # CMake backtraces in case a required Qt5 module is missing
 618 #####################################################################
 619
 620 add_subdirectory(src)