X-Git-Url: https://git.quassel-irc.org/?p=quassel.git;a=blobdiff_plain;f=CMakeLists.txt;h=9037c89b42840c35a93bf25fb87b65979c28c377;hp=76889d81a2bb259f7488f43cd7f4b1301a5de873;hb=fad08c0bc53514b43fdf44e5a792a019b1414367;hpb=60013b8987abc643a31fecf185d463973e009915

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 76889d81..9037c89b 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -6,106 +6,140 @@
 # General setup
 #####################################################################
 
-cmake_minimum_required(VERSION 2.8.9)
-project(QuasselIRC)
+cmake_minimum_required(VERSION 3.5)
 
+# Tell CMake about or own modules
+set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
 
-# Versions
-set(QUASSEL_MAJOR  0)
-set(QUASSEL_MINOR 11)
-set(QUASSEL_PATCH  0)
-set(QUASSEL_VERSION_STRING "0.11-pre")
+include(QuasselVersion)
 
+message(STATUS "Using CMake ${CMAKE_VERSION}")
 
-# Tell CMake about or own modules
-set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
+# Set up build type rather early
+include(BuildType)
 
-# General conveniences
+# Support ccache if found
+# This should happen before calling project(), so compiler settings are validated.
+option(USE_CCACHE "Enable support for ccache if available" ON)
+if (USE_CCACHE)
+    message(STATUS "Checking for ccache")
+    find_program(CCACHE_PROGRAM ccache)
+    if (CCACHE_PROGRAM)
+        set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
+        message(STATUS "Checking for ccache - enabled")
+    else()
+        message(STATUS "Checking for ccache - not found")
+    endif()
+endif()
+
+# Set up project
+project(Quassel CXX)
+
+# Let CMake handle file generation for Qt
 set(CMAKE_AUTOMOC ON)
-set(CMAKE_INCLUDE_CURRENT_DIR ON)
+set(CMAKE_AUTORCC ON)
+set(CMAKE_AUTOUIC ON)
 
+# Needed, otherwise some .moc files won't be found with older CMake versions
+set(CMAKE_INCLUDE_CURRENT_DIR ON)
 
-# Moar stuff
+# Include various CMake modules...
+include(CMakePushCheckState)
 include(CheckFunctionExists)
-include(CheckIncludeFile)
+include(CheckIncludeFileCXX)
+include(CheckCXXSourceCompiles)
+include(CMakeDependentOption)
+include(FeatureSummary)
 
+# ... and our own
 include(QuasselCompileSettings)
 include(QuasselMacros)
 
-include(CMakeDependentOption)
-
-
 # Options and variables that can be set on the command line
 #####################################################################
 
-
-# First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
-option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
-if (USE_QT4) # takes precedence
-    set(USE_QT5 OFF)
-else()
-    if (NOT USE_QT5)
-        set(USE_QT4 ON)
-    endif()
-endif()
-
 # Select the binaries to build
 option(WANT_CORE     "Build the core (server) binary"           ON)
-option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
+option(WANT_QTCLIENT "Build the client-only binary"             ON)
 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
+add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
+add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
+add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
 
+# Whether to enable integration with higher-tier KDE frameworks that require runtime support.
+# We still optionally make use of certain Tier 1 frameworks even if WITH_KDE is disabled.
+option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
+add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
 
-# Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
-cmake_dependent_option(WITH_KDE      "KDE4 integration" OFF "USE_QT4" OFF)
+# Icon theme support. By default, install the Breeze icon theme (may be disabled if a system installation is present)
+option(WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme" ON)
+add_feature_info(WITH_BUNDLED_ICONS WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme")
 
-# Some options don't make sense with KDE
-cmake_dependent_option(WITH_PHONON   "Phonon support (for audio notifications)"           ON "NOT WITH_KDE" OFF)
-cmake_dependent_option(WITH_SNORE    "Snore notification support"                        OFF "NOT WITH_KDE" OFF)
-cmake_dependent_option(WITH_OXYGEN   "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
+option(WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)" OFF)
+add_feature_info(WITH_OXYGEN_ICONS WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)")
 
-# Misc features
-option(WITH_OPENSSL     "OpenSSL support (secure networking)"             ON)
-option(WITH_DBUS        "Use D-Bus for the tray icon (StatusNotifier)"    ON)
-option(WITH_WEBKIT      "WebKit support (for link previews)"              ON)
-option(WITH_CRYPT       "Encryption support (QCA)"                        ON)
-option(WITH_LIBINDICATE "Ayatana (libindicate) notification support"      ON)
-cmake_dependent_option(WITH_SYSLOG   "Support logging to syslog"          ON "NOT WIN32" OFF)
+# For this, the feature info is added after we know if QtWebkit is installed
+option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
+
+# For this, the feature info is added after we know if QtWebEngine is installed
+option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
 
 if (APPLE)
     # Notification Center is only available in > 10.8, which is Darwin v12
-    if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
+    if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
+        add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
     endif()
+    find_library(CARBON_LIBRARY Carbon)
+    mark_as_advanced(CARBON_LIBRARY)
+    link_libraries(${CARBON_LIBRARY})
 endif()
 
-# Always embed on Windows or for a static build; never embed when enabling KDE integration
+# Always embed on Windows or OSX; never embed when enabling KDE integration
 set(EMBED_DEFAULT OFF)
-if (STATIC OR WIN32)
+if (WIN32 OR APPLE)
     set(EMBED_DEFAULT ON)
 endif()
-cmake_dependent_option(EMBED_DATA "Embed icons and translations in the binaries instead of installing them" ${EMBED_DEFAULT}
-                                   "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
+cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
+                                   "NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
+if (NOT EMBED_DEFAULT)
+    add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
+endif()
 
-cmake_dependent_option(DEPLOY      "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
+# The following options are not for end-user consumption, so don't list them in the feature summary
+option(FATAL_WARNINGS "Make compile warnings fatal (most useful for CI builds)" OFF)
+cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg" OFF "APPLE" OFF)
 
-# Handle with care
-set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
+# List of authenticators and the cmake flags to build them
+# (currently that's just LDAP, but more can be added here).
+####################################################################
+option(WITH_LDAP "Enable LDAP authentication support if present on system" ON)
 
+# Setup CMake
+#####################################################################
 
-# Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
-cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
+# Visibility settings apply to all targets
+if (POLICY CMP0063)
+    cmake_policy(SET CMP0063 NEW)
+endif()
 
-# For static builds, arbitrary extra libs might need to be linked
-# Define a comma-separated list here
-# e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
-set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
-if (LINK_EXTRA)
-    string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
-    link_libraries(${LINK_EXTRA})
+# Let automoc/autouic process generated files
+if (POLICY CMP0071)
+    cmake_policy(SET CMP0071 NEW)
 endif()
 
+set(BUILD_SHARED_LIBS TRUE CACHE BOOL "" FORCE)
+
+# Don't use X11 on OSX
+if (APPLE)
+    set(CMAKE_DISABLE_FIND_PACKAGE_X11 true)
+    set(CMAKE_DISABLE_FIND_PACKAGE_XCB true)
+    set(CMAKE_DISABLE_FIND_PACKAGE_Qt5X11Extras true)
+endif()
 
 # Simplify later checks
+#####################################################################
+
 if (WANT_MONO OR WANT_QTCLIENT)
     set(BUILD_GUI true)
 endif()
@@ -113,382 +147,357 @@ if (WANT_MONO OR WANT_CORE)
     set(BUILD_CORE true)
 endif()
 
-
 # Set up Qt
 #####################################################################
 
+# Find package dependencies
+#
+# Note that you can forcefully disable optional packages
+# using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
+#####################################################################
 
-if (USE_QT5)
-    message(STATUS "Building with the Qt5 libraries...")
-    set(QT_MIN_VERSION "5.2.0")
-    add_definitions(-DHAVE_QT5)
-else()
-    message(STATUS "Building with the Qt4 libraries...")
-    if (BUILD_GUI)
-        set(QT_MIN_VERSION "4.6.0")
-    else()
-        set(QT_MIN_VERSION "4.4.0")
-    endif()
+set(QT_MIN_VERSION "5.5.0")
+
+# Required Qt components
+set(qt_components Core Network)
+if (BUILD_GUI)
+    list(APPEND qt_components Gui Widgets)
+endif()
+if (BUILD_CORE)
+    list(APPEND qt_components Script Sql)
 endif()
 
+find_package(Qt5 ${QT_MIN_VERSION} REQUIRED COMPONENTS ${qt_components})
+set_package_properties(Qt5 PROPERTIES TYPE REQUIRED
+    URL "https://www.qt.io/"
+    DESCRIPTION "the Qt libraries"
+)
+message(STATUS "Found Qt ${Qt5Core_VERSION}")
+
+# Optional Qt components
+
+find_package(Qt5LinguistTools QUIET)
+set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
+    DESCRIPTION "contains tools for handling translation files"
+    PURPOSE "Required for having translations"
+)
+
+if (BUILD_GUI)
+    if (NOT WIN32)
+        find_package(Qt5DBus QUIET)
+        set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
+            URL "https://www.qt.io/"
+            DESCRIPTION "D-Bus support for Qt5"
+            PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
+        )
+        if (Qt5DBus_FOUND)
+            find_package(dbusmenu-qt5 QUIET CONFIG)
+            set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
+                URL "https://launchpad.net/libdbusmenu-qt"
+                DESCRIPTION "a library implementing the DBusMenu specification"
+                PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
+            )
+        endif()
+    endif()
 
-if (USE_QT5)
-    find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
-    # We need QtWidgets
-    set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
+    find_package(Qt5Multimedia QUIET)
+    set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
+        URL "https://www.qt.io/"
+        DESCRIPTION "Multimedia support for Qt5"
+        PURPOSE     "Required for audio notifications"
+    )
 
-    # Setup the i18n-related variables
-    find_package(Qt5LinguistTools)
+    find_package(LibsnoreQt5 0.7.0 QUIET)
+    set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
+        URL "https://projects.kde.org/projects/playground/libs/snorenotify"
+        DESCRIPTION "a cross-platform notification framework"
+        PURPOSE     "Enable support for the snorenotify framework"
+    )
+    if (LibsnoreQt5_FOUND)
+        find_package(LibsnoreSettingsQt5 QUIET)
+        set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE OPTIONAL
+            URL "https://projects.kde.org/projects/playground/libs/snorenotify"
+            DESCRIPTION "a cross-platform notification framework"
+            PURPOSE     "Enable support for the snorenotify framework"
+        )
+    endif()
 
-else()
-    # Select a Qt installation here, if you don't want to use system Qt
-    if(QT_PATH)
-        # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
-        set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
+    if (WITH_WEBENGINE)
+        find_package(Qt5WebEngine QUIET)
+        set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
+            URL "https://www.qt.io/"
+            DESCRIPTION "a WebEngine implementation for Qt"
+            PURPOSE     "Needed for displaying previews for URLs in chat"
+        )
+        if (Qt5WebEngine_FOUND)
+            find_package(Qt5WebEngineWidgets QUIET)
+            set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
+                URL "https://www.qt.io/"
+                DESCRIPTION "widgets for Qt's WebEngine implementation"
+                PURPOSE     "Needed for displaying previews for URLs in chat"
+            )
+        endif()
     endif()
 
-    # Now that we have the correct $PATH, lets find Qt!
-    find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
-endif()
+    if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
+        set(HAVE_WEBENGINE true)
+    endif()
+    add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
+
+    if (NOT HAVE_WEBENGINE)
+        if (WITH_WEBKIT)
+            find_package(Qt5WebKit QUIET)
+            set_package_properties(Qt5WebKit PROPERTIES TYPE OPTIONAL
+                URL "https://www.qt.io/"
+                DESCRIPTION "a WebKit implementation for Qt"
+                PURPOSE     "Needed for displaying previews for URLs in chat"
+                )
+            if (Qt5WebKit_FOUND)
+                find_package(Qt5WebKitWidgets QUIET)
+                set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE OPTIONAL
+                    URL "https://www.qt.io/"
+                    DESCRIPTION "widgets for Qt's WebKit implementation"
+                    PURPOSE     "Needed for displaying previews for URLs in chat"
+                    )
+            endif()
+        endif()
+
+        if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
+            set(HAVE_WEBKIT true)
+        endif()
+        add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
+    endif()
 
+    # KDE Frameworks
+    ################
 
-# Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
-# Rather than shipping hacked buildsys files, let's just infer the path from lrelease
-if (QT_LRELEASE_EXECUTABLE)
-    get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
-    if (USE_QT5)
-        find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
+    # extra-cmake-modules
+    if (WITH_KDE)
+        set(ecm_find_type "REQUIRED")
+        find_package(ECM NO_MODULE REQUIRED)
     else()
-        find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
+        # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
+        set(ecm_find_type "RECOMMENDED")
+        find_package(ECM NO_MODULE QUIET)
+    endif()
+
+    set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
+        URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
+        DESCRIPTION "extra modules for CMake, maintained by the KDE project"
+        PURPOSE     "Required to find KDE Frameworks components"
+    )
+
+    if (ECM_FOUND)
+        list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
+        if (WITH_KDE)
+            find_package(KF5 REQUIRED COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig Sonnet TextWidgets WidgetsAddons XmlGui)
+            set_package_properties(KF5 PROPERTIES TYPE REQUIRED
+                URL "http://www.kde.org"
+                DESCRIPTION "KDE Frameworks"
+                PURPOSE     "Required for integration into the Plasma desktop"
+            )
+            message(STATUS "Found KDE Frameworks ${KF5_VERSION}")
+        endif()
+
+        # Optional KF5 tier1 components
+        find_package(KF5Sonnet QUIET)
+        set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
+            URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
+            DESCRIPTION "framework for providing spell-checking capabilities"
+            PURPOSE "Enables spell-checking support in input widgets"
+        )
     endif()
 endif()
 
+if (BUILD_CORE)
+    find_package(Qca-qt5 2.0 QUIET)
+    set_package_properties(Qca-qt5 PROPERTIES TYPE RECOMMENDED
+        URL "https://projects.kde.org/projects/kdesupport/qca"
+        DESCRIPTION "Qt Cryptographic Architecture"
+        PURPOSE "Required for encryption support"
+    )
 
-# Dependencies
+    if (WITH_LDAP)
+        find_package(Ldap QUIET)
+        set_package_properties(Ldap PROPERTIES TYPE OPTIONAL
+            URL "http://www.openldap.org/"
+            DESCRIPTION "LDAP (Lightweight Directory Access Protocol) libraries"
+            PURPOSE "Enables core user authentication via LDAP"
+        )
+    endif()
+endif()
+
+# Non-Qt-based packages
 #####################################################################
 
-# zlib for compression, however we can always fall back to miniz
-find_package(ZLIB)
-if(ZLIB_FOUND)
-  message(STATUS "Using system zlib for compression")
-  add_definitions(-DHAVE_ZLIB)
-  include_directories(${ZLIB_INCLUDE_DIRS})
-  set(COMMON_LIBRARIES ${COMMON_LIBRARIES} ${ZLIB_LIBRARIES})
-else()
-  message(STATUS "zlib NOT found, using bundled miniz for compression")
-  if(${CMAKE_SIZEOF_VOID_P} EQUAL 4)
-    message(STATUS "WARNING: This may be slow on 32 bit systems!")
-  endif()
+find_package(Boost 1.56 REQUIRED)
+set_package_properties(Boost PROPERTIES TYPE REQUIRED
+    URL "https://www.boost.org/"
+    DESCRIPTION "Boost libraries for C++"
+)
+# Older versions don't define the imported target
+if (NOT TARGET Boost::boost)
+    add_library(Boost::boost INTERFACE IMPORTED GLOBAL)
+    if (Boost_INCLUDE_DIRS)
+        set_target_properties(Boost::boost PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${Boost_INCLUDE_DIRS}")
+    endif()
 endif()
 
+find_package(ZLIB REQUIRED)
+set_package_properties(ZLIB PROPERTIES TYPE REQUIRED
+    URL "http://www.zlib.net"
+    DESCRIPTION "a popular compression library"
+    PURPOSE     "Used for protocol compression"
+)
+
+if (NOT WIN32)
+    # Needed for generating backtraces
+    find_package(Backtrace QUIET)
+    set_package_properties(Backtrace PROPERTIES TYPE RECOMMENDED
+        DESCRIPTION "a header (and possibly library) for inspecting backtraces"
+        PURPOSE "Used for generating backtraces in case of a crash"
+    )
+endif()
 
-# Execinfo is needed for generating backtraces
-find_package(ExecInfo)
-if(EXECINFO_FOUND)
-  add_definitions(-DHAVE_EXECINFO)
-  include_directories(${EXECINFO_INCLUDES})
-  link_libraries(${EXECINFO_LIBRARIES})
-endif(EXECINFO_FOUND)
+# Setup unit testing
+#####################################################################
 
+option(BUILD_TESTING "Enable unit tests" OFF)
+add_feature_info(BUILD_TESTING BUILD_TESTING "Build unit tests")
 
-# PkgConfig isn't strictly required.
-# However, some optional deps might not be found if it's not present, so warn!
-find_package(PkgConfig)
-if(NOT PKG_CONFIG_FOUND)
-  message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
-  message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
-endif(NOT PKG_CONFIG_FOUND)
+if (BUILD_TESTING)
+    find_package(GTest QUIET)
+    set_package_properties(GTest PROPERTIES TYPE REQUIRED
+        DESCRIPTION "Google's unit testing framework"
+        PURPOSE "Required for building unit tests"
+    )
 
+    find_package(Qt5Test QUIET)
+    set_package_properties(Qt5Test PROPERTIES TYPE REQUIRED
+        DESCRIPTION "unit testing library for the Qt5 framework"
+        PURPOSE "Required for building unit tests"
+    )
+    enable_testing()
+
+    # GTest messes with CMAKE_CXX_FLAGS, so process them again
+    process_cmake_cxx_flags()
+endif()
 
-# Setup OpenSSL
-# We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
-# Thus, we simply check if OpenSSL support is present in Qt's config and enable our
-# own SSL stuff in this case. Qt should care for adding what it needs itself.
-if(WITH_OPENSSL)
-  if(QT_QCONFIG MATCHES "openssl")
-    message(STATUS "Found OpenSSL support in Qt, enabling SSL")
+# Check for SSL support in Qt
+#####################################################################
+
+cmake_push_check_state(RESET)
+set(CMAKE_REQUIRED_LIBRARIES Qt5::Core)
+check_cxx_source_compiles("
+    #include \"qglobal.h\"
+    #if defined QT_NO_SSL
+    #  error \"No SSL support\"
+    #endif
+    int main() {}"
+    HAVE_SSL)
+cmake_pop_check_state()
+
+if (HAVE_SSL)
     add_definitions(-DHAVE_SSL)
-    set(HAVE_SSL true)
-  else(QT_QCONFIG MATCHES "openssl")
-    message(STATUS "No OpenSSL support found in Qt, disabling SSL")
-    add_definitions(-DQT_NO_OPENSSL)
-  endif(QT_QCONFIG MATCHES "openssl")
-else(WITH_OPENSSL)
-  message(STATUS "Not enabling OpenSSL support")
-endif(WITH_OPENSSL)
-
-
-# Check for GUI specific stuff
-if(BUILD_GUI)
-
-  # Setup D-Bus support
-  if(WITH_DBUS)
-    if (USE_QT5)
-      find_package(Qt5DBus ${QT_MIN_VERSION})
-      find_package(Qt5DBusTools)
-    endif()
+endif()
+add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 
-    if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
-      message(STATUS "Found QtDBus, enabling D-Bus support")
-      add_definitions(-DHAVE_DBUS)
-      set(HAVE_DBUS true)
-      set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
-
-      # check if we have dbusmenu as well
-      if (NOT USE_QT5)
-        find_package(DBusMenuQt)
-        if(DBUSMENUQT_FOUND)
-          message(STATUS "Enabling support for exporting the tray menu via D-Bus")
-          add_definitions(-DHAVE_DBUSMENU)
-          include_directories(${DBUSMENUQT_INCLUDE_DIR})
-          set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
-          set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
-        else(DBUSMENUQT_FOUND)
-          message(STATUS "Disabling support for exporting the tray menu via D-Bus")
-        endif(DBUSMENUQT_FOUND)
-      endif()
-
-    else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
-      message(STATUS "QtDBus not found, disabling D-Bus support")
-    endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
-  else(WITH_DBUS)
-    message(STATUS "Not enabling D-Bus support")
-  endif(WITH_DBUS)
-
-  # Setup QtWebkit support
-  if(WITH_WEBKIT)
-    if (USE_QT5)
-      find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
-    endif()
-    if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
-      message(STATUS "Found QtWebKit, enabling WebKit support")
-      add_definitions(-DHAVE_WEBKIT)
-      set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
-      set(HAVE_WEBKIT true)
-    else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
-      message(STATUS "QtWebkit not found, disabling Webkit support")
-    endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
-  else(WITH_WEBKIT)
-    message(STATUS "Not enabling Webkit support")
-  endif(WITH_WEBKIT)
-
-  # Setup KDE4 support
-  if(WITH_KDE AND NOT USE_QT5)
-    # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
-    set(_cflags ${CMAKE_C_FLAGS})
-    find_package(KDE4)
-    if(KDE4_FOUND)
-      message(STATUS "Enabling KDE4 integration")
-      include_directories(${KDE4_INCLUDES})
-      add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
-      set(HAVE_KDE 1)
-      set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
-      # We always use external icons for KDE4 support, since we use its iconloader rather than our own
-      set(EMBED_DATA OFF)
-      # Restore our old CFLAGS
-      set(CMAKE_C_FLAGS ${_cflags})
-    else(KDE4_FOUND)
-      message(STATUS "KDE4 not found, disabling KDE integration")
-    endif(KDE4_FOUND)
-  else(WITH_KDE AND NOT USE_QT5)
-    message(STATUS "Not enabling KDE4 integration")
-  endif(WITH_KDE AND NOT USE_QT5)
-
-  # Setup Phonon support - we only need this if we don't have or want KDE4
-  if(NOT HAVE_KDE)
-    if(WITH_PHONON)
-      if(USE_QT5)
-        find_package(Qt5phonon)
-        if(Qt5phonon_FOUND)
-          message(STATUS "Enabling Phonon support")
-          add_definitions(-DHAVE_PHONON)
-          set(HAVE_PHONON true)
-          set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
-        else(Qt5phonon_FOUND)
-          message(STATUS "Phonon not found, disabling audio notifications")
-        endif(Qt5phonon_FOUND)
-      else(USE_QT5)
-        find_package(Phonon)
-        if(PHONON_FOUND)
-          message(STATUS "Enabling Phonon support")
-          add_definitions(-DHAVE_PHONON)
-          include_directories(${PHONON_INCLUDES})
-          set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
-          set(HAVE_PHONON true)
-        else(PHONON_FOUND)
-          message(STATUS "Phonon not found, disabling audio notifications")
-        endif(PHONON_FOUND)
-      endif(USE_QT5)
-    else(WITH_PHONON)
-      message(STATUS "Not enabling Phonon support")
-    endif(WITH_PHONON)
-
-    find_package(Libsnore)
-    if(LIBSNORE_FOUND)
-        add_definitions(-DHAVE_LIBSNORE)
-        set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
-        set(HAVE_SNORENOTIFY true)
-    endif(LIBSNORE_FOUND)
-  endif(NOT HAVE_KDE)
-
-  # Setup libindicate-qt support
-  if(WITH_LIBINDICATE AND NOT USE_QT5)
-    pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
-    if(INDICATEQT_FOUND)
-      message(STATUS "Enabling Ayatana notification support")
-      set(HAVE_INDICATEQT true)
-      add_definitions(-DHAVE_INDICATEQT)
-      link_directories(${INDICATEQT_LIBRARY_DIRS})
-      set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
-    else(INDICATEQT_FOUND)
-      message(STATUS "Disabling Ayatana notification support")
-    endif(INDICATEQT_FOUND)
-  else(WITH_LIBINDICATE AND NOT USE_QT5)
-    message(STATUS "Not enabling Ayatana notification support")
-    # We don't want to link against it even if another package has found it
-    set(INDICATEQT_LIBRARIES "")
-  endif(WITH_LIBINDICATE AND NOT USE_QT5)
-
-  # Setup OS X notification center support
-  if(WITH_NOTIFICATION_CENTER AND APPLE)
-    set(HAVE_NOTIFICATION_CENTER true)
-    add_definitions(-DHAVE_NOTIFICATION_CENTER)
-    set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
-      /System/Library/Frameworks/Foundation.framework
-    )
-  endif()
-endif(BUILD_GUI)
-
-# Core-only deps
-if(BUILD_CORE)
-
-  # Setup encryption support
-  if(WITH_CRYPT AND NOT USE_QT5)
-    find_package(QCA2)
-    if(QCA2_FOUND)
-      message(STATUS "Enabling encryption support")
-      add_definitions(-DHAVE_QCA2)
-      set(LINK_QCA2 QCA2)
-      set(HAVE_QCA2 true)
-      set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
-    else(QCA2_FOUND)
-      message(STATUS "Disabling encryption support")
-    endif(QCA2_FOUND)
-  else(WITH_CRYPT AND NOT USE_QT5)
-    message(STATUS "Not enabling encryption support")
-  endif(WITH_CRYPT AND NOT USE_QT5)
-
-  # Setup syslog support
-  if(WITH_SYSLOG)
-    check_include_file(syslog.h HAVE_SYSLOG_H)
-    if(HAVE_SYSLOG_H)
-      message(STATUS "Enabling syslog support")
-      set(HAVE_SYSLOG true)
-      add_definitions(-DHAVE_SYSLOG)
-    else(HAVE_SYSLOG_H)
-      message(STATUS "Disabling syslog support")
-    endif(HAVE_SYSLOG_H)
-  else(WITH_SYSLOG)
-    message(STATUS "Not enabling syslog support")
-  endif(WITH_SYSLOG)
-
-endif(BUILD_CORE)
-
-
-# Various settings
-##################
-
-# needed to compile with mingw without kde
-if(MINGW AND NOT HAVE_KDE)
-    add_definitions(-D_WIN32_WINNT=0x0500)
-    message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
-# workaround for bug in mingw gcc 4.0
-    add_definitions(-U__STRICT_ANSI__)
-endif(MINGW AND NOT HAVE_KDE)
-
-# Now set up install locations; those are set by KDE if integration is enabled
-if(NOT HAVE_KDE)
-  if(WIN32)
-    set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
-    set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
-    set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
-    set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
-  else(WIN32)
-    set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
-    set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
-    set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
-    set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
-  endif(WIN32)
-endif(NOT HAVE_KDE)
-
-if(EMBED_DATA)
-  message(STATUS "Embedding data files into the binary")
-else(EMBED_DATA)
-  message(STATUS "Installing data files separately")
-endif(EMBED_DATA)
-
-# RPATH needs to be set correctly
-# Do this down here, since otherwise KDE wants to handle it itself, and fails
-set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
-set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
-
-# Set global buildflags
-# This is very much non-portable, so don't use -DSTATIC until you know what
-# you do.
-if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
-  set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
-  link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
-  if(HAVE_SSL)
-    set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
-  endif(HAVE_SSL)
-endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
-
-if(WIN32)
-  link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
-  if(MSVC)
-    set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
-    set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
-    set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
-    link_libraries(Version dwmapi shlwapi)
-  endif(MSVC)
-  if(HAVE_SSL AND STATIC)
-     find_package(OpenSSL REQUIRED)
-     link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
-  endif(HAVE_SSL AND STATIC)
-endif(WIN32)
-
-if(HAVE_INDICATEQT)
-  add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
-endif(HAVE_INDICATEQT)
-
-if(NOT WIN32)
-  check_function_exists(umask HAVE_UMASK)
-  if(HAVE_UMASK)
-    add_definitions(-DHAVE_UMASK)
-  endif(HAVE_UMASK)
-endif(NOT WIN32)
-
-# Generate version information from Git
-include(GetGitRevisionDescription)
-get_git_head_revision(GIT_REFSPEC GIT_HEAD)
-git_describe(GIT_DESCRIBE --long)
-
-# Sanitize things if we're not in a Git repo
-if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
-    set(GIT_HEAD "")
-    set(GIT_DESCRIBE "")
+# Setup support for KDE Frameworks
+#####################################################################
+
+if (WITH_KDE)
+    add_definitions(-DHAVE_KDE -DHAVE_KF5)
+    set(WITH_KF5 TRUE)
+
+    # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
+    set(EMBED_DATA OFF)
+
+    include(KDEInstallDirs)
 endif()
 
-configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
+# This needs to come after setting up KDE integration, so we can use KDE-specific paths
+include(QuasselInstallDirs)
 
-# These variables will be added to the main targets (CORE, QTCLIENT, MONO)
-set(COMMON_DEPS ${RC_WIN32})
-set(CORE_DEPS )
-set(CLIENT_DEPS )
+# RPATH and output settings
+#####################################################################
+
+# Build artifacts in a well-known location; especially important for Windows DLLs
+# (which go into RUNTIME_OUTPUT_DIRECTORY and can thus be found by executables)
+set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
+set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
+set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
+
+# These RPATH settings allow for running directly from the build dir
+set(CMAKE_SKIP_BUILD_RPATH            FALSE)
+set(CMAKE_BUILD_WITH_INSTALL_RPATH    FALSE)
+set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE )
+
+# Set install RPATH only if libdir isn't a system directory
+if (IS_ABSOLUTE "${CMAKE_INSTALL_LIBDIR}")
+    set(libdir "${CMAKE_INSTALL_LIBDIR}")
+else()
+    set(libdir "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}")
+endif()
+list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${libdir}" is_systemdir)
+if ("${is_systemdir}" STREQUAL "-1")
+   set(CMAKE_INSTALL_RPATH "${libdir}")
+endif()
+
+# Various config-dependent checks and settings
+#####################################################################
+
+# Check for syslog support
+if (NOT WIN32)
+    check_include_file_cxx(syslog.h HAVE_SYSLOG)
+    add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
+endif()
+
+if (NOT WIN32)
+    check_function_exists(umask HAVE_UMASK)
+endif()
+
+if (EMBED_DATA)
+    message(STATUS "Embedding data files into the binary")
+else()
+    message(STATUS "Installing data files separately")
+endif()
+
+# Windows-specific stuff
+#####################################################################
+
+if (WIN32)
+    link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
+    if (MSVC)
+        link_libraries(Version dwmapi shlwapi)
+    endif()
+endif()
+
+# Prepare the build
+#####################################################################
 
 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 add_subdirectory(data)
 add_subdirectory(icons)
 add_subdirectory(pics)
 add_subdirectory(po)
+
+# Set up and display feature summary
+#####################################################################
+
+feature_summary(WHAT ALL
+                INCLUDE_QUIET_PACKAGES
+                FATAL_ON_MISSING_REQUIRED_PACKAGES
+)
+
+# Finally, compile the sources
+# We want this after displaying the feature summary to avoid ugly
+# CMake backtraces in case a required Qt5 module is missing
+#####################################################################
+
 add_subdirectory(src)
+
+# Build tests if so desired
+if (BUILD_TESTING)
+    add_subdirectory(tests)
+endif()