src/qtui/qtui.pri

   1 DEPMOD = client common uisupport
   2 QT_MOD = core gui network
   3
   4 SRCS += aboutdlg.cpp bufferwidget.cpp chatitem.cpp chatline.cpp chatline-old.cpp chatscene.cpp chatview.cpp chatwidget.cpp \
   5         coreconfigwizard.cpp coreconnectdlg.cpp configwizard.cpp debugconsole.cpp inputwidget.cpp \
   6         mainwin.cpp nicklistwidget.cpp qtui.cpp qtuisettings.cpp qtuistyle.cpp settingsdlg.cpp settingspagedlg.cpp \
   7         titlesetter.cpp topicbutton.cpp topicwidget.cpp verticaldock.cpp jumpkeyhandler.cpp
   8
   9 HDRS += aboutdlg.h bufferwidget.h chatitem.h chatline.h chatline-old.h chatscene.h chatview.h chatwidget.h \
  10         coreconfigwizard.h configwizard.h debugconsole.h inputwidget.h \
  11         coreconnectdlg.h mainwin.h nicklistwidget.h qtui.h qtuisettings.h qtuistyle.h settingsdlg.h settingspagedlg.h \
  12         titlesetter.h topicbutton.h topicwidget.h verticaldock.h jumpkeyhandler.h
  13
  14 FORMNAMES = aboutdlg.ui mainwin.ui coreaccounteditdlg.ui coreconnectdlg.ui bufferviewwidget.ui bufferwidget.ui nicklistwidget.ui settingsdlg.ui \
  15             settingspagedlg.ui topicwidget.ui debugconsole.ui inputwidget.ui \
  16             coreconfigwizardintropage.ui coreconfigwizardadminuserpage.ui coreconfigwizardstorageselectionpage.ui coreconfigwizardsyncpage.ui
  17
  18 for(ui, FORMNAMES) {
  19   FRMS += ui/$${ui}
  20 }
  21
  22 # Include settingspages
  23 include(settingspages/settingspages.pri)
  24 for(page, SETTINGSPAGES) {
  25   SRCS += settingspages/$${page}settingspage.cpp
  26   HDRS += settingspages/$${page}settingspage.h
  27   FRMS += settingspages/$${page}settingspage.ui
  28 }
  29
  30 # Include additional files
  31 for(src, SP_SRCS) {
  32   SRCS += settingspages/$${src}
  33 }
  34 for(hdr, SP_HDRS) {
  35   HDRS += settingspages/$${hdr}
  36 }
  37 for(frm, SP_FRMS) {
  38   FRMS += settingspages/$${frm}
  39 }