src/qtui/qtui.pri

   1 DEPMOD = client common uisupport
   2 QT_MOD = core gui network
   3
   4 SRCS += aboutdlg.cpp bufferwidget.cpp chatline-old.cpp chatwidget.cpp \
   5         coreconfigwizard.cpp coreconnectdlg.cpp configwizard.cpp debugconsole.cpp inputwidget.cpp \
   6         mainwin.cpp nicklistwidget.cpp qtui.cpp qtuisettings.cpp qtuistyle.cpp settingsdlg.cpp settingspagedlg.cpp \
   7         titlesetter.cpp topicbutton.cpp topicwidget.cpp verticaldock.cpp jumpkeyhandler.cpp
   8
   9 HDRS += aboutdlg.h bufferwidget.h chatline-old.h chatwidget.h \
  10         coreconfigwizard.h configwizard.h debugconsole.h inputwidget.h \
  11         coreconnectdlg.h mainwin.h nicklistwidget.h qtui.h qtuisettings.h qtuistyle.h settingsdlg.h settingspagedlg.h \
  12         titlesetter.h topicbutton.h topicwidget.h verticaldock.h jumpkeyhandler.h
  13
  14 # new chatline model stuff
  15 sputdev {
  16   SRCS += chatitem.cpp chatline.cpp chatlinemodelitem.cpp chatlinemodel.cpp chatscene.cpp chatview.cpp
  17   HDRS += chatitem.h chatline.h chatlinemodelitem.h chatlinemodel.h chatscene.h chatview.h
  18   SRCS -= chatline-old.cpp chatwidget.cpp
  19   HDRS -= chatline-old.h chatwidget.h
  20 }
  21
  22 FORMNAMES = aboutdlg.ui mainwin.ui coreaccounteditdlg.ui coreconnectdlg.ui bufferviewwidget.ui bufferwidget.ui nicklistwidget.ui settingsdlg.ui \
  23             settingspagedlg.ui topicwidget.ui debugconsole.ui inputwidget.ui \
  24             coreconfigwizardintropage.ui coreconfigwizardadminuserpage.ui coreconfigwizardstorageselectionpage.ui coreconfigwizardsyncpage.ui
  25
  26 for(ui, FORMNAMES) {
  27   FRMS += ui/$${ui}
  28 }
  29
  30 # Include settingspages
  31 include(settingspages/settingspages.pri)
  32 for(page, SETTINGSPAGES) {
  33   SRCS += settingspages/$${page}settingspage.cpp
  34   HDRS += settingspages/$${page}settingspage.h
  35   FRMS += settingspages/$${page}settingspage.ui
  36 }
  37
  38 # Include additional files
  39 for(src, SP_SRCS) {
  40   SRCS += settingspages/$${src}
  41 }
  42 for(hdr, SP_HDRS) {
  43   HDRS += settingspages/$${hdr}
  44 }
  45 for(frm, SP_FRMS) {
  46   FRMS += settingspages/$${frm}
  47 }