src/main/CMakeLists.txt

   1 # Convenience function to avoid boilerplate
   2 function(setup_executable _target _define)
   3     set_target_properties(${_target} PROPERTIES
   4         COMPILE_FLAGS ${_define}
   5         RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}
   6     )
   7     target_link_libraries(${_target} PRIVATE ${ARGN})
   8     install(TARGETS ${_target} RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
   9 endfunction()
  10
  11 # We need to initialize the appropriate resources, so let's give our main.cpp some hints
  12 if (EMBED_DATA)
  13     set_property(SOURCE main.cpp APPEND PROPERTY COMPILE_DEFINITIONS EMBED_DATA)
  14 endif()
  15
  16 if (HAVE_UMASK)
  17     set_property(SOURCE main.cpp APPEND PROPERTY COMPILE_DEFINITIONS HAVE_UMASK)
  18 endif()
  19
  20 if (WITH_BUNDLED_ICONS)
  21     set_property(SOURCE main.cpp APPEND PROPERTY COMPILE_DEFINITIONS WITH_BUNDLED_ICONS)
  22 endif()
  23
  24 # Build the executables
  25 if (WANT_CORE)
  26     add_executable(quasselcore main.cpp)
  27     setup_executable(quasselcore -DBUILD_CORE Qt5::Core Quassel::Core)
  28 endif()
  29
  30 if (WANT_CLIENT OR WANT_QTCLIENT)
  31     add_executable(quasselclient WIN32 main.cpp)
  32     setup_executable(quasselclient -DBUILD_QTUI Qt5::Core Qt5::Gui Quassel::QtUi)
  33     if (WITH_KDE)
  34         target_link_libraries(quasselclient PRIVATE KF5::CoreAddons)
  35     endif()
  36 endif()
  37
  38 if (WANT_MONO)
  39     add_executable(quassel WIN32 main.cpp monoapplication.cpp)
  40     setup_executable(quassel -DBUILD_MONO Qt5::Core Qt5::Gui Quassel::Core Quassel::QtUi)
  41     if (WITH_KDE)
  42         target_link_libraries(quassel PRIVATE KF5::CoreAddons)
  43     endif()
  44 endif()
  45
  46 # Build bundles for MacOSX
  47 if (APPLE)
  48     add_custom_command(TARGET quasselclient POST_BUILD
  49                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
  50                                ${CMAKE_SOURCE_DIR} "Quassel Client" ${CMAKE_BINARY_DIR}/quasselclient)
  51
  52     add_custom_command(TARGET quassel POST_BUILD
  53                        COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makebundle.py
  54                                ${CMAKE_SOURCE_DIR} "Quassel" ${CMAKE_BINARY_DIR}/quassel)
  55     if (DEPLOY)
  56         add_custom_command(TARGET quasselclient POST_BUILD WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  57                            COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Client ${CMAKE_BINARY_DIR} qsvgicon)
  58         add_custom_command(TARGET quasselcore POST_BUILD WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  59                            COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Core ${CMAKE_BINARY_DIR})
  60         add_custom_command(TARGET quassel POST_BUILD WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  61                            COMMAND ${CMAKE_SOURCE_DIR}/scripts/build/macosx_makePackage.sh Mono ${CMAKE_BINARY_DIR} qsvgicon)
  62     endif()
  63 endif()