src/contrib/libqxt-2007-10-24/libqxt.pro

   1 #
   2 # Qxt main project file
   3 #
   4 # Do not edit this file.
   5 # Use config.pri to specify compile options.
   6 #
   7 unix:!macx:include(features/unix/qxtbuild.prf)
   8 win32:include(features/win32/qxtbuild.prf)
   9 macx:include(features/macx/qxtbuild.prf)
  10
  11 TEMPLATE = subdirs
  12 DESTDIR      = deploy/libs
  13
  14
  15 docs.files = deploy/docs/*
  16 #docs.commands = assistant -addContentFile $${docs.path}/index.dcf
  17
  18
  19 includes.path = $${include.path}/
  20 includes.files= deploy/include/*
  21
  22 #write the paths to prf file
  23 unix:system((echo QXTbase=$${QXTINSTALLDIR}; echo QXTinclude=$${include.path}; echo QXTbin=$${bin.path}; echo QXTlib=$${lib.path}; cat deploy/qt/qxt.prf.m) > deploy/qt/qxt.prf)
  24
  25 #windows supports similar syntax
  26 win32:system((echo QXTbase=$${QXTINSTALLDIR}& echo QXTinclude=$${include.path} & echo QXTbin=$${bin.path} & echo QXTlib=$${lib.path} & type deploy\qt\qxt.prf.m) > deploy\qt\qxt.prf)
  27
  28 features.path = $$[QT_INSTALL_DATA]/mkspecs/features
  29 features.files = deploy/qt/qxt.prf
  30
  31 INSTALLS = docs includes features
  32
  33
  34
  35 contains( QXT_BUILD, core ){
  36     message( building the core )
  37     SUBDIRS += src/core
  38 }
  39
  40
  41 contains( QXT_BUILD, gui ){
  42     message( building gui module )
  43     SUBDIRS += src/gui
  44     contains( QXT_BUILD, designer ): SUBDIRS += src/designer
  45 }
  46
  47 contains( QXT_BUILD, network ){
  48     message( building network module )
  49     SUBDIRS += src/network
  50 }
  51
  52 contains( QXT_BUILD, sql ){
  53     message( building sql module )
  54     SUBDIRS += src/sql
  55 }
  56
  57 contains(DEFINES,HAVE_CURSES){
  58 contains( QXT_BUILD, curses ){
  59     message( building curses module )
  60     SUBDIRS += src/curses
  61 }
  62 }
  63
  64
  65 contains( QXT_BUILD, web ){
  66     message( building web module )
  67     SUBDIRS += src/web
  68 }
  69 contains( QXT_BUILD, crypto ){
  70     message( building crypto module )
  71     SUBDIRS += src/crypto
  72 }
  73